[已解决]批处理调用mkvmerge.exe把MKV换成新字幕,播放器打开不显示字幕如何解决

1139054012 · 发表于 2025-7-1 23:53:38

本帖最后由 1139054012 于 2025-7-4 14:55 编辑

代码
https://download.gg/file-18901546_f060ac239bab6651

文件生成成功,但是PotPlayer打开就是不显示字幕?外挂字幕可以正常显示

PS: 换了PotPlayer版本好了

Five66 · 发表于 2025-7-2 00:47:34

播放时 ,界面右键-->字幕-->选择字幕
看看是否真的有字幕

1139054012 · 发表于 2025-7-2 07:55:20

本帖最后由 1139054012 于 2025-7-2 08:05 编辑

回复 2# Five66

右键选择字幕是默认选中状态,但就是不显示,奇怪
https://download.gg/zh/file-18901314_79
c2a908b45bc0ea

播放器测试
https://download.gg/file-18901315_777b1df258c7bf8d

flashercs · 发表于 2025-7-2 13:23:47

本帖最后由 flashercs 于 2025-7-2 19:10 编辑

脚本保存为ANSI编码

@echo off
setlocal enabledelayedexpansion
REM 名称: 智能MKV字幕打包工具
REM 版本: v1.3
REM 功能:
REM 1. 查找MKV视频文件
REM 2. 查找对应ASS字幕
REM 3. 封装进 new\ 文件夹下
REM 4. 设置字幕为默认显示轨道
REM 参数: 拖放或手动输入文件夹路径
REM 使用示例: 把含 video.mkv 和 video.ass 的文件夹拖进来
REM 设置mkvmerge路径
set "MKVMERGE=E:\新建文件夹\濡以沫o\MKV\MKVToolNix\mkvmerge.exe"
REM 显示欢迎信息
echo.
echo ████ 智能 MKV 字幕打包工具 v1.3 █████
echo.
echo === 请把包含 MKV 视频的文件夹拖放到此处 ===
echo [注意] 如果路径中含 ^& 或 ) 等特殊字符，请手动清理后再拖放!
REM 获取用户输入路径
set /p "ROOT=请输入路径: "
REM 检查路径是否存在
if not exist "!ROOT!" (
echo 错误：路径不存在，请重新输入。
pause>nul
exit /b
)
REM 检查是否有mkv文件
dir "!ROOT!\*.mkv" /b >nul 2>&1
if %errorlevel% neq 0 (
echo 错误：未找到任何 .mkv 文件，请确认路径是否正确。
pause>nul
exit /b
)
REM 显示即将处理的文件列表
echo.
echo === 即将处理以下 MKV 视频 ===
dir "!ROOT!\*.mkv" /b
echo ==============================
echo 如确认无误请按任意键继续...
pause >nul
REM 创建输出文件夹 new\
set "OUTPUT_DIR=!ROOT!\new"
if not exist "!OUTPUT_DIR!" mkdir "!OUTPUT_DIR!"
REM 遍历每个mkv文件
for %%F in ("!ROOT!\*.mkv") do (
REM 设置当前视频路径
set "VIDEO_FILE=%%~fF"
REM 获取视频所在目录
set "VIDEO_DIR=%%~dpF"
REM 获取视频文件名（不含扩展名）
set "VIDEO_NAME=%%~nF"
REM 构造对应的字幕文件路径
set "SUBTITLE_FILE=!VIDEO_DIR!!VIDEO_NAME!.srt"
REM 显示当前处理的视频
echo.
echo 正在处理视频: !VIDEO_FILE!
REM 检查字幕文件是否存在
if exist "!SUBTITLE_FILE!" (
REM 显示找到的字幕文件
echo 找到字幕文件: !SUBTITLE_FILE!
REM 构造输出文件路径（保存在 new\ 下，保留原文件名）
set "OUTPUT_FILE=!OUTPUT_DIR!\!VIDEO_NAME!.mkv"
REM 调用mkvmerge添加字幕并设置默认轨道和字幕名
"!MKVMERGE!" ^
-o "!OUTPUT_FILE!" ^
--no-subtitles "!VIDEO_FILE!" ^
--language 0:und ^
--track-name 0:"中文" ^
--default-track 0 ^
"!SUBTITLE_FILE!"
REM 显示完成信息
echo 完成处理: !OUTPUT_FILE!
) else (
REM 显示未找到字幕文件
echo 未找到字幕文件: !SUBTITLE_FILE!
)
)
REM 显示全部处理完成
echo.
echo 所有文件处理完成！输出位于：!OUTPUT_DIR!
pause >nul

复制代码

aloha20200628 · 发表于 2025-7-2 14:25:15

回复 1# 1139054012

用一楼代码批量生成的 *.mkv 用 potplayer 都看不到其中封装的字幕吗？还是有些可以看到？看不到的 *.mkv 用手动载入其对应的 *.ass 字幕文件能否看到？

1139054012 · 发表于 2025-7-2 16:21:36

本帖最后由 1139054012 于 2025-7-2 16:29 编辑

回复 4# flashercs

测试了下,直接复制1楼代码不全,直接粘贴有问题,直接网盘放一份
https://download.gg/file-18901546_f060ac239bab6651

1139054012 · 发表于 2025-7-2 16:35:59

回复 5# aloha20200628

PotPlayer设置版无法正常显示字幕,原来MKV可以显示,外挂字幕也可以显示,说明就是封装失败的问题,换srt字幕还是不行

但是PotPlayer重置设置,可以显示字幕,但音轨又失效了

MPC也是,可以显示字幕,音轨失效

flashercs · 发表于 2025-7-2 19:13:41

本帖最后由 flashercs 于 2025-7-2 19:50 编辑

4楼代码修改了;
注意:1 注释符号不要用::,必须用REM,很多AI的代码都是错误的;2 不要遍历子文件夹;
potplayer播放器有问题,你的视频用其他播放器可以有字幕

Five66 · 发表于 2025-7-3 00:04:12

本帖最后由 Five66 于 2025-7-3 01:26 编辑

回复 3# 1139054012

保存为ansi或gbk或gb2312编码的bat

@echo off&goto :begin
:: 名称: 智能MKV字幕打包工具
:: 版本: v1.3
:: 功能:
:: 1. 查找MKV视频文件
:: 2. 查找对应ASS字幕
:: 3. 封装进 new\ 文件夹下
:: 4. 设置字幕为默认显示轨道
:: 参数: 拖放或手动输入文件夹路径
:: 使用示例: 把含 video.mkv 和 video.ass 的文件夹拖进来
:begin
rem 设置mkvmerge路径
set "MKVMERGE=E:\新建文件夹\濡以沫o\MKV\MKVToolNix\mkvmerge.exe"
rem 显示欢迎信息
echo.
echo ████ 智能 MKV 字幕打包工具 v1.3 █████
echo.
echo === 请把包含 MKV 视频的文件夹拖放到此处 ===
echo [注意] 不包括子目录及其文件
rem 获取用户输入路径
set /p "ROOT=请输入路径: "
set "ROOT=%ROOT:"=%"
rem 检查路径是否存在
if not exist "%ROOT%" (
echo 错误：路径不存在，请重新输入。
pause&exit /b
)
rem 检查是否有mkv文件
dir "%ROOT%\*.mkv" /b >nul 2>&1
if %errorlevel% neq 0 (
echo 错误：未找到任何 .mkv 文件，请确认路径是否正确。
pause&exit /b
)
rem 显示即将处理的文件列表
echo.
echo === 即将处理以下 MKV 视频 ===
dir "%ROOT%\*.mkv" /b
echo ==============================
echo 如确认无误请按任意键继续...
pause >nul
rem 创建输出文件夹 new\
set "OUTPUT_DIR=%ROOT%\new"
if not exist "%OUTPUT_DIR%" mkdir "%OUTPUT_DIR%"
rem 遍历每个mkv文件
for %%F in ("%ROOT%\*.mkv") do (
rem 设置当前视频路径
set "VIDEO_FILE=%%~fF"
rem 获取视频所在目录
set "VIDEO_DIR=%%~dpF"
rem 获取视频文件名（不含扩展名）
set "VIDEO_NAME=%%~nF"
setlocal enabledelayedexpansion
rem 构造对应的字幕文件路径
set "SUBTITLE_FILE=!VIDEO_DIR!!VIDEO_NAME!.ass"
rem 显示当前处理的视频
echo,&echo 正在处理视频: !VIDEO_FILE!
rem 检查字幕文件是否存在
if exist "!SUBTITLE_FILE!" (
rem 显示找到的字幕文件
echo 找到字幕文件: !SUBTITLE_FILE!
rem 构造输出文件路径（保存在 new\ 下，保留原文件名）
set "OUTPUT_FILE=!OUTPUT_DIR!\!VIDEO_NAME!.mkv"
rem 调用mkvmerge添加字幕并设置默认轨道和字幕名
"!MKVMERGE!" ^
-o "!OUTPUT_FILE!" ^
--language 0:und ^
--no-subtitles ^
-T ^
"!VIDEO_FILE!" ^
--track-name 0:defsub ^
--language 0:und ^
--default-track 0:1 ^
"!SUBTITLE_FILE!"
rem 显示完成信息
echo 完成处理: !OUTPUT_FILE!
) else (
rem 显示未找到字幕文件
echo 未找到字幕文件: !SUBTITLE_FILE!
)
endlocal
)
rem 显示全部处理完成
echo,
echo 所有文件处理完成！输出位于："%OUTPUT_DIR%"
pause&exit/b

复制代码

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件操作] [已解决]批处理调用mkvmerge.exe把MKV换成新字幕,播放器打开不显示字幕如何解决

浏览过的版块