批处理如何获取网卡状态（以解决）

qq3475534 · 发表于 2025-5-5 00:46:46

本帖最后由 qq3475534 于 2025-5-6 02:46 编辑

批处理如何获取网卡状态，比如电脑，网卡百兆，就记录当前机器编号，以及当前系统时间，并写入当前客户机网卡百兆，请处理。写入信息后则自动退出。

就自动上传到服务器共享目录，\\192.168.0.250\LOG$

如果千兆则自动退出，

以解决，非常感谢二楼三楼热心帮助。

flashercs · 发表于 2025-5-5 15:18:30

@echo off
net use "\\192.168.0.250\LOG$"
(
for /f "delims=" %%A in ('wmic nic where "Speed<1000000000" get Name^,NetConnectionID^,NetEnabled^,Speed /value^|findstr "="') do (
for /f "tokens=1* delims==" %%B in ("%%A") do (
set "%%B=%%C"
if /i %%B==Speed (
setlocal enabledelayedexpansion
echo 计算机名:!ComputerName! 时间:!date! !time! 网卡:!Name! 网络连接:!NetConnectionID! 启用:!NetEnabled! 速率: !Speed:~0,-6!mb 当前客户机网卡百兆
endlocal
)
)
)
)>>"\\192.168.0.250\LOG$\nic.log"

复制代码

aloha20200628 · 发表于 2025-5-5 17:35:16

本帖最后由 aloha20200628 于 2025-5-6 13:32 编辑

回复 1# qq3475534

千兆有线网卡可能被设为百兆连接速度，故采用注册表对应项数据判断也许更为可靠...
存入服务器共享目录中的检测结果文件预设名为 xxx.txt（可在以下代码中第4行自定义）

@echo off &chcp 936>nul
for /f "delims=" %%a in ('reg query "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Class\{4d36e972-e325-11ce-bfc1-08002be10318}" /s ^|find /i " gbps " ') do (echo,发现千兆网卡...退出&pause&exit/b)
for /f "tokens=2 delims==" %%a in ('wmic csproduct get name /value ^| find "=" ') do (set "v=电脑名称：%computername% 电脑型号：%%a %date% %time% 当前客户机网卡百兆，请处理")
net use "\\192.168.0.250\LOG$"
echo,%v%>"\\192.168.0.250\LOG$\xxx.txt"
pause&exit/b

复制代码

以上代码已先强制当前码页转为 936 编码（即简中编码），故代码存盘为批处文件时须选择 ansi 编码（或 gb2312 编码）

qq3475534 · 发表于 2025-5-6 02:31:23

本帖最后由 qq3475534 于 2025-5-6 02:33 编辑

回复 2# flashercs

测试可以了，默认好像编码有点问题，手动改一下格式可以了。非常感谢

qq3475534 · 发表于 2025-5-6 02:31:43

回复 3# aloha20200628

谢谢测试执行出来是一堆乱码，好像哪里应该有点问题

aloha20200628 · 发表于 2025-5-6 10:53:56

本帖最后由 aloha20200628 于 2025-5-6 13:58 编辑

回复 5# qq3475534

当前系统采用的码页须与代码存盘选用的编码一致。可试以下方法》
在代码首行前加一行 @chcp 936>nul 再用ansi编码存盘批处理文件即可。
反言之，若用 utf-8 编码存盘批处理文件，则须将首行代码中的 936 改为 65001
3楼代码已订正为强制采用 936 码页的版本，故其代码存盘为批处理文件时须选用 ansi 编码...

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[系统相关] 批处理如何获取网卡状态（以解决）