[已解决]批处理怎样把wmic命令的值保存到变量？

zhaosiyu2010 · 发表于 2018-12-3 11:37:09

如题，
wmic path win32_diskdrive get size>aa
这样输出的文档的时候在命令提示符里没问题
但是在bat里不知道怎么就不行了。会不停的往AA里写下面这句话
C:\Users\Admin\Desktop>wmic DISKDRIVE get deviceid,Caption,size,InterfaceType

for /f %i in ('wmic path win32_diskdrive get size^| findstr ^^[0-9]') do set a=%i
这个也不行，在bat里打不开

以下语句可以直接获取到磁盘0的大小
for /f %%a in ('wmic DiskDrive where "DeviceID like '%%PHYSICALDRIVE0'" get Size /value^|find "="') do set "%%a"
echo;磁盘0的大小为：=%Size%

flashercs · 发表于 2018-12-3 12:13:39

wmic path win32_diskdrive get deviceid,serialnumber,size

复制代码

zhaosiyu2010 · 发表于 2018-12-3 13:58:41

回复 2# flashercs

怎么把得到的结果保存到变量。。。

jiavip · 发表于 2018-12-7 05:19:07

for /f "tokens=1,2,3" %%i in ('wmic path win32_diskdrive get deviceid^,serialnumber^,size^|find /i"\\."') do echo %%k

复制代码

%%K 就是变量

zhaosiyu2010 · 发表于 2019-2-18 11:24:14

回复 4# jiavip

这个%%K 怎么用啊？

怎么能传给 set a 啊

zhaosiyu2010 · 发表于 2019-2-18 12:35:09

有没有高手麻烦解答下

lanfogz · 发表于 2019-2-18 13:33:22

for /f %i in ('wmic path win32_diskdrive get size^| findstr ^^[0-9]') do set a=%i

zhaosiyu2010 · 发表于 2019-2-18 13:37:52

[b]回复 [url=http://www.bathome.net/redirect.php?goto=findpost

zhaosiyu2010 · 发表于 2019-2-18 19:44:49

回复 7# lanfogz

不行啊在命令提示符里可以在BAT里就打不开啊

1332019995 · 发表于 2019-2-18 21:33:11

回复 9# zhaosiyu2010

把%i换成%%i,cmd下用%i,bat下用%%i

zhaosiyu2010 · 发表于 2019-2-19 12:20:43

本帖最后由 zhaosiyu2010 于 2019-2-19 12:28 编辑

回复 10# 1332019995

谢谢。。。可以用
wmic path win32_diskdrive get deviceid,serialnumber,size>a.txt 这句在bat里应该怎么改可以使用呢

for /f %%i in ('wmic path win32_diskdrive get size^| findstr ^^[0-9]') do set a=%%i
然后这句怎么判断哪个值是磁盘0的或者只获取磁盘0的大小。。。
感谢。。。

lanfogz · 发表于 2019-2-20 09:29:07

本帖最后由 lanfogz 于 2019-2-25 09:40 编辑

@echo off
:: 保存磁盘信息到文件
wmic path win32_diskdrive get deviceid,serialnumber,size>a.txt
type a.txt
:: 保存磁盘0的大小到变量
set disk0_size=
for /f %%i in ('wmic path win32_diskdrive where "deviceid like '%%0'" get size^| findstr ^^[0-9]') do set disk0_size=%%i &goto :break
:break
echo 磁盘0大小：%disk0_size%

复制代码

lanfogz · 发表于 2019-2-20 09:50:25

本帖最后由 lanfogz 于 2019-2-25 09:45 编辑

获取磁盘的数量、所有磁盘的大小

@echo off & setlocal enabledelayedexpansion
set disk_count=0
for /f "tokens=2" %%i in ('wmic path win32_diskdrive get deviceid^,size^| findstr ^^[0-9] ^|sort') do (
set disk!disk_count!_size=%%i
set/a disk_count+=1
)
echo 磁盘数量：%disk_count%
for /l %%i in (0, 1, %disk_count%) do if %%i lss %disk_count% (echo 磁盘%%i大小：!disk%%i_size!)

复制代码

zhaosiyu2010 · 发表于 2019-2-20 17:45:19

回复 13# lanfogz

这个不错。。。。再帮个忙呗我只要磁盘0的值就行了
怎么能把值传给 set a
在for里面好像不一样

lanfogz · 发表于 2019-2-21 09:24:54

回复 14# zhaosiyu2010

见12楼

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[其他] [已解决]批处理怎样把wmic命令的值保存到变量？

RE: 批处理中怎么分别获取每个硬盘的容量？