请高人改一下批处理在文本头部增加内容

yjqrsyg · 发表于 2018-12-12 12:41:15

这个命令是本论坛上找到的,原本是为批量文本在尾部增加内容的,我想把它改成在文本头部增加内容,请高人改一下,本人小白,谢谢了!

大概意思如下:
大致是这样的，
有101个TXT文件，其中有一个all.txt里有1000行，其它100个1.txt, 2.txt,...,100.txt，每个里面都是一篇小短文。
现在我想
每次随机从all.txt这1000行里取10行，添加到其它100个TXT文件中的某一个，直到这100个TXT文件每个都被添加过一次。
（每次随机抽取的10行数据可以有重复的行）

下面的这个命令是增加在尾部的,我试过了,好用,现在想把内容增加在头部,请高人改一下,谢谢

@echo off&setlocal enabledelayedexpansion
set m=1000
for /f "delims=" %%i in (all.txt) do set /an+=1&set #!n!=%%i
for /f "delims=" %%i in ('dir /b /a-d *.txt ^| findstr /ivx "all\.txt"') do (
(for /l %%a in (1 1 10) do (
set /a n=!random!%%m+1
for %%b in (!n!) do echo !#%%b!
))>>"%%i"
)
pause

复制代码

flashercs · 发表于 2018-12-12 13:12:21

本帖最后由 flashercs 于 2018-12-12 13:48 编辑

@echo off&setlocal enabledelayedexpansion
set m=1000
set "tmpFile=%temp%\$%random%.tmp"
for /f "delims=" %%i in (all.txt) do set /a n+=1&set #!n!=%%i
for /f "delims=" %%i in ('dir /b /a-d *.txt ^| findstr /ivx "all\.txt"') do (
copy /y nul "%tmpFile%"
(for /l %%a in (1 1 10) do (
set /a n=!random!%%m+1
for %%b in (!n!) do echo !#%%b!
))>>"%tmpFile%"
copy /y /b "%tmpFile%"+"%%i" "%tmpFile%"
copy /y "%tmpFile%" "%%i"
)
del /f /q "%tmpFile%"
pause

复制代码

yjqrsyg · 发表于 2018-12-12 13:27:06

回复 2# flashercs

谢谢,我刚才用了一下,出现一个问题:原文本中的内容全被删掉了,这个不是我想要的呀

flashercs · 发表于 2018-12-12 13:51:03

回复 3# yjqrsyg

改了

yjqrsyg · 发表于 2018-12-12 14:07:16

回复 4# flashercs

果然好用,谢谢,太感谢了,高人就是高人,

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文本处理] 请高人改一下批处理在文本头部增加内容

评分