[已解决]批处理根据注册表判断系统版本号

zhoubin

写了一个读取注册表项，判断系统版本号的批处理，win7下测试：假如没有HKEY_LOCAL_MACHINE\SYSTEM\Setup\Service Reporting API\Components\CoreOS，Version值，以下脚本得到的结果是：

1. C: │本地系统│Windows 7 Ultimate│x64│(.7601)

复制代码

，而我想要的结果是：

1. C: │本地系统│Windows 7 Ultimate│x64│(6.1.7601)

复制代码

，以下脚本不知错在哪里了，请各位高手指导一下，谢谢了！

1. @echo off
   
2. ::以下内容，PE下无效
   
3. if /i not "%systemdrive%"=="X:" set LoadrV=C:
   
4. if /i "%systemdrive%"=="X:" set LoadrV=X:
   
5. rem 查询系统类型
   
6. if exist %Windir%\SysWOW64 (set LoaOsarch=x64) else if not exist %Windir%\SysWOW64 (set LoaOsarch=x86) else set "LoaOsarch=???"
   
7. )
   
8. rem 查询系统版本号，
   
9. for /f "tokens=3" %%c in ('reg query "HKLM\SYSTEM\Setup\Service Reporting API\Components\CoreOS" /v Version 2^>nul ^| findstr /i "REG_SZ"') do set LoaVer=%%c
   
10. rem 如果上面未查询到版本号，则在此处查询
    
11. if not defined LoaVer (
    
12. for /f "tokens=3" %%f in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v CurrentVersion 2^>nul ^| findstr /i "REG_SZ"') do set LoaVer=%%f
    
13. for /f "tokens=3" %%g in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v CurrentBuildNumber 2^>nul ^| findstr /i "REG_SZ"') do set LoaVer=%LoaVer%.%%g
    
14. )
    
15. rem 查询系统名称
    
16. for /f "tokens=3*" %%d in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v ProductName 2^>nul ^| findstr /i "REG_SZ"') do set LoaName=%%d %%e
    
17. echo;%LoadrV%│本地系统│%LoaName%│%LoaOsarch%│^(%LoaVer%^)
    
18. )
    
19. @echo on
    
20. pause&&goto :eof
    

复制代码

自己解决了，分享给大家，谢谢大伙的帮助

1. @echo off
   
2. ::以下内容，PE下无效
   
3. if /i not "%systemdrive%"=="X:" set LoadrV=C:
   
4. if /i "%systemdrive%"=="X:" set LoadrV=X:
   
5. setlocal enabledelayedexpansion
   
6. rem 查询系统类型
   
7. if exist %Windir%\SysWOW64 (set LoaOsarch=x64) else if not exist %Windir%\SysWOW64 (set LoaOsarch=x86) else set "LoaOsarch=???"
   
8. )
   
9. rem 查询系统版本号
   
10. for /f "tokens=3" %%c in ('reg query "HKLM\SYSTEM\Setup\Service Reporting API\Components\CoreOS" /v Version 2^>nul ^| findstr /i "REG_SZ"') do set LoaVer=%%c
    
11. rem 如果上面未查询到版本号，则在此处查询
    
12. if not defined LoaVer (
    
13. for /f "tokens=3" %%f in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v CurrentVersion 2^>nul ^| findstr /i "REG_SZ"') do set LoaVer=%%f
    
14. for /f "tokens=3" %%g in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v CurrentBuildNumber 2^>nul ^| findstr /i "REG_SZ"') do set LoaVer=!LoaVer!.%%g
    
15. )
    
16. rem 查询系统名称
    
17. for /f "tokens=3*" %%d in ('reg query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v ProductName 2^>nul ^| findstr /i "REG_SZ"') do set LoaName=%%d %%e
    
18. echo;%LoadrV%│本地系统│%LoaName%│%LoaOsarch%│^(%LoaVer%^)
    
19. )
    
20. endlocal
    
21. @echo on
    
22. pause&&goto :eof

复制代码

aloha20200628

回复 1# zhoubin

其实从 wmic os get ... 即可抓取全部所需参数，如下版本...

1. 
   
2. @echo off &setlocal &for /f "tokens=1-2* delims== " %%a in ('wmic os get caption^,OSArchitecture^,version /value^|find "=" ') do if not defined c (set "c=%%c") else if not defined a (set "a=%%b") else if not defined v (set "v=%%b")
   
3. set/p="%systemDrive% |本地系统|%c%|x%a%|(%v%)"<nul
   
4. echo,&pause&exit/b
   

复制代码

flashercs

win7测试正常.
可能是你机器注册表的问题:
注册表HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion缺少了CurrentVersion

1. rem 如果上面未查询到版本号，则在此处查询
   
2. if not defined LoaVer (
   
3. for /f "tokens=4 delims=[] " %%g in ('ver') do set LoaVer=%%g
   
4. )

复制代码

flashercs

自己制作PE系统可以使用ADK添加组件wmi,powershell,vbscript,hta

zhoubin

HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion有CurrentVersion，我再看看，谢谢

zhoubin

测试的1楼批处理时，剪切HKEY_LOCAL_MACHINE\SYSTEM\Setup\Service Reporting API\Components\CoreOS，Version值，到记事本保存，
测试完成后，再粘贴恢复Version值。