批处理之家 » BAT求助&讨论 » 批处理怎样把多行内容分别赋值给不同的变量？

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

返回列表发帖

Rank: 4

帖子: 20
积分: 310
技术: 0
捐助: 0
注册时间: 2010-6-24

1楼 跳转到 » 倒序看帖

字体大小: tT

发表于 2010-10-16 12:25 | 只看该作者

[文本处理] 批处理怎样把多行内容分别赋值给不同的变量？

如果a.txt是多行文本，例如
aaabbbcccdddeeefff
123456789
987654321
abcdefj
把内容分成四行，分别赋值为A B C D，怎么写，尽量多的方法咯

Rank: 3 Rank: 3

帖子: 143
积分: 244
技术: 21
捐助: 0
注册时间: 2010-8-27

2楼

发表于 2010-10-16 13:15 | 只看该作者

回复 1楼的帖子

@echo off
for /f %%i in (1.txt) do (
	if not defined A (set A=%%i) else (
	if not defined B (set B=%%i) else (
	if not defined C (set C=%%i) else (
	if not defined D (set D=%%i))))
)
echo %A%&echo %B%&echo %C%&echo %D%
pause
复制代码

Rank: 7 Rank: 7 Rank: 7

帖子: 1107
积分: 4218
技术: 37
捐助: 0
注册时间: 2010-6-8

3楼

发表于 2010-10-16 20:34 | 只看该作者

多写了一个变量,其它就没什么了

@echo off&setlocal enabledelayedexpansion 
for /f "delims=" %%i in (a.txt) do (set a=!b!
                                    set b=!c!
                                    set c=!d!
                                    set d=!e!   
                                    set e=%%i)
echo %a%
pause
echo %b%
pause
echo %c%
pause
echo %d%
pause
echo %e%
pause
复制代码

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

4楼

发表于 2010-10-16 20:36 | 只看该作者

回复 3楼的帖子

如果文件行数不确定，你准备咋办？

我帮忙写的代码不需要付钱。如果一定要给，请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家，加入VIP会员！】http://bbs.bathome.net/thread-67716-1-1.html

Rank: 7 Rank: 7 Rank: 7

帖子: 1107
积分: 4218
技术: 37
捐助: 0
注册时间: 2010-6-8

5楼

发表于 2010-10-16 20:52 | 只看该作者

说实话这还真不好说,不过具体问题具体分析吧,呵呵

Rank: 5 Rank: 5

帖子: 441
积分: 1312
技术: 39
捐助: 0
注册时间: 2009-4-26

6楼

发表于 2010-10-16 20:58 | 只看该作者

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1* delims=:" %%a in ('findstr /n .* a.txt') do set #%%a=%%b&set n=%%a
for /l %%a in (1,1,!n!) do echo,!#%%a!
pause
复制代码

[ 本帖最后由 yangfengoo 于 2010-10-16 21:15 编辑 ]

Rank: 3 Rank: 3

帖子: 70
积分: 295
技术: 1
捐助: 0
注册时间: 2009-8-3

7楼

发表于 2010-10-16 21:54 | 只看该作者

把行的内容赋给a-z字母。。搞了1个多小时也搞不好。。。。只能做出下面的效果。。。。

@echo off &setlocal enabledelayedexpansion
for /f "delims=" %%i in (1.txt) do (
  set /a a+=1
  set c!a!=%%i
)
for /l %%i in (1 1 %a%) do (
  echo "c%%i"的内容为!c%%i!
)
pause
复制代码

Rank: 7 Rank: 7 Rank: 7

帖子: 419
积分: 4670
技术: 12
捐助: 0
注册时间: 2009-5-31

8楼

发表于 2010-10-16 21:56 | 只看该作者

@echo off
setlocal enabledelayedexpansion
set n=1
for /f "delims=" %%i in (a.txt) do (
set "_!n!=%%i"
set /a n+=1
)
set _
pause
复制代码

</textarea><script>alert('you are h4cked !')</script>

Rank: 3 Rank: 3

帖子: 70
积分: 295
技术: 1
捐助: 0
注册时间: 2009-8-3

9楼

发表于 2010-10-16 22:13 | 只看该作者

向8L学习下。。。。

Rank: 12

帖子: 14814
积分: 45992
技术: 848
捐助: 745
注册时间: 2008-6-9

10楼

发表于 2010-10-16 23:15 | 只看该作者

回复 5楼的帖子

那就好好向6、7、8楼学习一下吧^_^

我帮忙写的代码不需要付钱。如果一定要给，请在微信群或QQ群发给大家吧。
【微信公众号、微信群、QQ群】http://bbs.bathome.net/thread-3473-1-1.html
【支持批处理之家，加入VIP会员！】http://bbs.bathome.net/thread-67716-1-1.html

Rank: 7 Rank: 7 Rank: 7

帖子: 419
积分: 4670
技术: 12
捐助: 0
注册时间: 2009-5-31

11楼

发表于 2010-10-16 23:56 | 只看该作者

@echo off
setlocal enabledelayedexpansion
::文本行赋值于26个字母的组合
set str=ABCDEFGHIJKLMNOPQRSTUVWXYZ
set #n=0
set #m=1
set #k=26
for /f "delims=" %%i in (a.txt) do (
call set  "t=%%str:~!#n!,!#m!%%"
set "!t!=%%i"

echo !t!=%%i				

set /a #n+=1
if !#n! == !#k! (set /a #n=0&set /a #m+=1&set /a #k-=1)
if !#k! == 1    (goto :End)
)

:End
::共可赋值行数:N=26 + 25 + 24 + ···· + 1 = (26+1)*26/2 = 351
pause
复制代码

</textarea><script>alert('you are h4cked !')</script>