随风

第一、标题于主题内容无关，以属 违规标题，请尽快修改。
第二、不要随便把问题发到  高手挑战区
第三、不要在论坛打广告。
第四、主题内容描述不清，请仔细描述。

随风

你的意识是这样吗？
生成一个 字典.txt 的文本
其中的内容是每行6个数字，分别代表年月日。
需要生成多少个？
可以重复吗？
必须是从小到大的顺序吗？
必须是递增的方式吗？

随风

需要生成多少个？
需要这个年限之间的每一天吗？
不用按顺序也行，也就是说按顺序也行咯？

楼主对问题能一次描述清楚吗？
你看，还没解答问题，就为了搞清楚你的意识就一问一答这么多回合了，（还不包括短信交流）并不是每个人都有这个耐心的，也许有人早就能解决你的问题，但就因搞不清楚你的意识，而没心思再看你的帖了。

随风

明白了，应该可以做到，
现在有个最主要的问题是，如何判断平年和闰年，正在发帖求助。
或者楼主知道如何判断么？不是用批处理，关键是我不知道怎么计算。用计算器也不会算。

随风

对平年、闰年进行了判断。

@echo off&setlocal enabledelayedexpansion
echo 请输入起始日期 格式：2006-1-20
set /p kai= &cls
echo 请输入结束日期 格式：2008-3-12
set /p wei= &cls
call :lis %kai% xiao
call :lis %wei% da
for /l %%a in (%xiao% 1 %da%) do (
  set sy=%%a
  set /a leap="^!(sy %% 4) & ^!(^!(sy %% 100)) | ^!(sy %% 400)"
  set /a max=28+leap
  if "%%a"=="%wei:~0,4%" (set yuem=!dam!) else set yuem=12
  call :sss
)
echo.&echo 完成。。。
echo.&pause&exit
:sss
for /l %%i in (!xiaom! 1 !yuem!) do (
  call :loop %%i
  for /l %%a in (!xiaod! 1 !ssd!) do (
    set nm=0%%i&set nd=0%%a
    >>字典.txt echo !sy:~-2!!nm:~-2!!nd:~-2!
  )
  set /a xiaod=1
)
set /a xiaom=1
goto :eof
:loop
for /f "tokens=%1" %%i in ("31 !max! 31 30 31 30 31 31 30 31 30 31") do (
   set ssd=%%i
)
if "!sy!-%1"=="%wei:~0,4%-!dam!" (set ssd=!dad!)
goto :eof
:lis
for /f "tokens=1-3 delims=-./ " %%a in ("%~1") do (
  set /a %~2=%%a,%2m=100%%b%%100,%2d=100%%c%%100
)
goto :eof
复制代码

[ 本帖最后由 随风 于 2008-4-19 07:04 编辑 ]