netbenton

注意：先把[tab]改成[Tab]键
          该代码放在你要处理的目录的上一级目录里

@echo off&setlocal enabledelayedexpansion

::把[Tab] 改成[Tab]键，因为论坛发不了[Tab]键
set "tab=[Tab]"

::取日期格式，我的系统是这样的“2010-07-15 星期四”，你可以根据你的情况改改吧
for /f "tokens=1-3 delims=- " %%a in ("!date!")  do set dire=%%a%%b%%c

for %%a in (!dire!\*.txt) do (

rem 首先根据第一行判断是何种符号
  set /p var=<"%%a"
  set fh=
  for %%b in ("," "&&" "|") do (
    if "!var:%%~b=!" neq "!var!" set fh=%%b
  )

rem 符合规则的话，进行替换，并存到临时文件*-new.tmp
  for %%b in (!fh!) do (

(    for /f "tokens=*" %%c in ('type "%%a"') do (
        set str=%%c
        echo;!str:%%~b=%tab%!
    )
)>"%%~dpna-new.tmp"

  )
)

rem 把临时文件.tmp，改成.txt，
if exist !dire!\*-new.txt del !dire!\*-new.txt
ren !dire!\*.tmp *.txt 2>nul

echo;新文件在原文件名后面加了-new
echo;OK~~
pause
复制代码

[ 本帖最后由 netbenton 于 2010-7-15 07:55 编辑 ]

netbenton

把这段代码：

(    for /f "tokens=*" %%c in ('type "%%a"') do (
        set str=%%c
        echo;!str:%%~b=%tab%!
    )
)>"%%~dpna-new.tmp"

改成下面的，可以提点速度，还要更快的话，请用三方吧~~

 
(     for /f "usebackq tokens=*" %%c in ("%%a") do (
        set str=%%c
        echo;!str:%%~b=%tab%!
    )
)>"%%~dpna-new.tmp"
复制代码

[ 本帖最后由 netbenton 于 2010-7-16 18:57 编辑 ]