zqz0012005

这个题倒是让我想起了如何用bat操作数组。本想模拟几个数组处理函数，还没设计好。

@echo off
setlocal enableDelayedExpansion
set num=100
set class_num=10
for %%a in (A B C D) do (
	call :getRanArr %%a 1 %num%
	set %%a=!%%a:#=%%a!
)
set backdoor1=B60
set backdoor2=C49
set target1=3
set target2=8
set /a cnt = num / class_num
for /l %%a in (1 1 %class_num%) do (
	for %%x in (A B C D) do (
		for /l %%i in (1 1 %cnt%) do (
			for /f %%A in ("!%%x!") do set class_%%a=!class_%%a! %%A& set %%x=!%%x:*%%A =!
		)
	)
	echo class %%a:
	echo !class_%%a:~1!
	echo;
	if /i "!class_%%a:%backdoor1%=!" neq "!class_%%a!" set postion1=%%a
	if /i "!class_%%a:%backdoor2%=!" neq "!class_%%a!" set postion2=%%a
)
echo yesterday: %backdoor1%=%postion1%, %backdoor2%=%postion2%
echo;
call :go_backdoor 1 //后来加的
call :go_backdoor 2
echo;
pause
exit /b

:go_backdoor //^_^//
set backdoor=!backdoor%1!
set postion=!postion%1!
set target=!target%1!
set class_%postion%=!class_%postion%:%backdoor%=...!
set class_%target%=!class_%target%! %backdoor%
rem catch a scape-goat
set level=%backdoor:~0,1%
set str=!class_%target%:*%level%=!
for /f %%a in ("!str!") do set scape-goat=%level%%%a
set class_%target%=!class_%target%:%scape-goat% =!
set class_%postion%=!class_%postion%:...=%scape-goat%!
echo new class %postion%:
echo !class_%postion%!
echo new class %target%:
echo !class_%target%!
echo;
goto :eof


:getRanArr arrName start end [step] //不对参数作合法性检查，coder自己保证参数的正确性
setlocal enableDelayedExpansion
set /a "start=%2, end=%3, step=(^!(%40/10))|(%40/10)"
set "_ret="
for /l %%a in (%start% %step% %end%) do set #_!random!_%%a=1
for /f "tokens=2 delims=#_=" %%a in ('set #_') do set _ret=!_ret! #%%a
endlocal & set %1=%_ret:~1%
goto :eof

rem ToDo: find time to implement these function
rem How about letting bat operate array? Crazy or not?

:shuffle arrName len cnt //洗牌

:slice arrName start [end] //返回一个数组的一段（指定起停）

:sliceLen arrName start length //返回一个数组的一段（指定长度）

:splice arrName start deleteCount //从一个数组中移除一个或多个元素，如果必要，在所移除元素的位置上插入新元素，返回所移除的元素
复制代码

zqz0012005

我的思路竟然和随风基本上是一样的！

代码有点啰嗦，最近在学习编程规范。

zqz0012005

@echo off
setlocal enableDelayedExpansion
set amount=100
set types=A B C D
set slices=10
set special=B-60-3 C-49-8

for /l %%a in (1 1 %amount%) do set arr=!arr! #-%%a
for %%i in (%types%) do (
    set "%%i=!arr:#=%%i! " 后面特意加了空格
    set /a amount_%%i=amount
    for /l %%a in (1 1 %slices%) do set /a num_%%i_%%a = amount / slices
)

for %%a in (%special%) do (
    for /f "tokens=1,2,3 delims=-" %%i in ("%%a") do (
        set %%i=!%%i: %%i-%%j = !
        set /a amount_%%i -= 1
        set /a num_%%i_%%k -= 1
    )
)

for %%i in (%types%) do (
    set #=!%%i!
    set /a left = amount_%%i
    for /l %%a in (1 1 %slices%) do (
        for /l %%n in (1 1 !num_%%i_%%a!) do (
            set /a ran = !random! %% left + 1
            set $=!#!
            for /l %%x in (1 1 !ran!) do set $=!$:* =!
            for /f %%x in ("!$!") do set item=%%x
            set slices_%%a=!slices_%%a! !item!
            for %%x in (!item!) do set #=!#: %%x = !
            set /a left -= 1
        )
    )
)

for %%a in (%special%) do (
    for /f "tokens=1,2,3 delims=-" %%i in ("%%a") do set slices_%%k=!slices_%%k! %%i-%%j
)

for /l %%a in (1 1 %slices%) do echo class %%a:& echo !slices_%%a!& echo;

echo;
pause
exit /b

:shuffle arrName len cnt //洗牌
复制代码

适应每个数组元素名字未知（开始生成一个数组是当没有给出时手动生成）、长度不定（当然总长度必须小于单个变量最大长度8k）

zqz0012005

为什么大家都觉得我是计算机专业的呢？

编程规范要求一行上最好只放一条语句（其实大家都懂的）

set /a 后面加空格是可以的而且是应该的，以突出运算逻辑和提高可读性。它和set进行字符串赋值有所不同，对于后者多余的空格也会成为变量名/值的一部分。

变量命名应该尽量做到短小而又有所含义（能做到见名知义就更好了），不要全用毫无意义的a、b、c之类的，当然有一些习惯性用法，比如n表示数量，i用于for循环变量等。

语句对齐问题：我发现做到并坚持这一原则的人真的很少。批处理就算再简单，基本的结构还是有的，不要一味为了简洁就无视它。
复合语句收尾的括号应与关键字在同一列上对齐（主要就是if、for，因为开始的括号不能另起一行放在行首，否则就与它对齐了），内部子语句应该适量缩进（一般4个空格，多数编辑器都是这个默认值，不用你多敲）。当子语句只有一两个且较简单，也可以省去括号（在bat中不反对大家这么做）。

正确、高效、易读，最容易做到的就是易读，却往往最难被人做到，悲乎哀哉！就算代码功能上不怎么样，变量名称、基本意思、流程结构应该写清楚呀，起码能让人看得懂。（terse的代码一向高效，但我一般都没怎么看过，感觉太“难看”了^_^）

zqz0012005

看36楼的代码，你觉得哪里头疼呢？

代码功能和技巧原理可能不大懂，需要相当的基础和积累才行。但代码格式、基本结构应该容易看懂吧（少数风格迥异的牛人除外，只看三两遍和没看一样）
比如一行句子是什么结构、怎么断句、主体命令是什么，for循环是哪一种、循环体里面有哪些子句，if语句的条件分支是怎样的，从哪里到哪里、是什么逻辑关系；总之大体框架应该读能出来。

试比较35楼的
set /a n=!random!%%_%%a*4
和36楼的
set /a ran = !random! %% left + 1

新手对上面那句，可能很难明白（当然结合代码是必须的，可是对新手还是很难）；但下面那句就不一样了（当然本身就简单一点）

zqz0012005

那就不是易读性的问题，而是技巧性的问题。
我说过，需要相当的基础和积累才行。

set的这个用法你不会，说明你的基本功还不够，对常用命令都不熟。
set /?
    SET P
会显示所有以字母 P 打头的变量

而set /a进行数学运算时，“您可以使用环境变量值做计算而不用键入那些 % 符号来得到它们的值”
据此分析set /a n=!random!%%_%%a*4
断句一下就是set /a n = !random! %% _%%a * 4
前面的%%是求余运算符（在bat中要写成两个，预处理机制，原理和理论知识），!random!加了!符号，因为它是一个特殊的变量，不是我们手动定义的，而是系统提供的动态环境变量，所以要使用!!来得到其值。而_%%a就是的!_%%a!省去!的形式，只是这个展开过程稍微多一步：先由for展开%%a的值，与_拼接后整个成为一个变量名，再由set得到该变量对应的值。