[文本处理] [已解决]批处理如何对含科学计数数字的txt批量修改？

alexwxcong

我有如下内容的大量txt文件
2.0000000000000001e-001
0.0000000000000000e+000
0.0000000000000000e+000
-2.0000000000000001e-001
1.6695009999999998e+005
2.8049900000000001e+004
需要对科学计数改为正常数字，即如下
0.2
0
0
-0.2
166950.09999999998
28049.900000000001

[ 本帖最后由 alexwxcong 于 2010-5-2 20:30 编辑 ]

alexwxcong

诚请高手帮忙，俺琢磨了一天了，实在水平太低

cjiabing

不懂数学，哈哈，不懂科学计数！~不过应该不难，只是麻烦点

alexwxcong

e-001就是前面的2.0000000000000001乘以0.1
e+000数字不变
e+005就是前面的1.6695009999999998乘以100000
e+004就是前面的2.8049900000000001乘以10000

yangfengoo

关键是P难以处理小数

hanyeguxing

1，“大量txt文件”是否指多个txt文本？
2，“含科学计数数字”，那么文本中是否还含有其他内容？
如果有，区分规则是什么？
3，“含科学计数数字”的构成规则是什么？
-2.0000000000000001e-001都是这样的模式？

sgaizxt001

我的漏洞好多，编辑掉。看看我师傅的代码先

[ 本帖最后由 sgaizxt001 于 2010-5-2 04:26 编辑 ]

namejm

　　1、小数点后的位数是否只保留有16位？
　　2、是否所有的正数都没有前缀+而只有负数才有前缀-？
　　4、e后的004、005之类的是否有可能会达到999？请给出它的范围。

hanyeguxing

1，代码没有优化，所以速度。。。100行转换实测耗时2.46妙，汗一个先
2，要求所有文本内只存在科学记数的内容，不含其他内容。
3，批处理放在同一目录下，新生成的文本将放到test子目录中。
4，e后的数字允许范围为000到999
5，小数部分最多保留16位（按楼主的要求）
6，数字小于0.0000000000000001时将被近似为0.0000000000000001

@echo off&setlocal enabledelayedexpansion
if not exist "test\" md test
for %%z in (*.txt) do (
for /f "usebackq tokens=1,2* delims=e." %%a in ("%%z") do (
set a=%%a&set b=%%b&set c=%%c
set d=!c:~1!
for %%d in (0 0) do if !d:~0^,1!==0 set d=!d:~1!
if !a:~0^,1!==- set n=-&set a=!a:~1!
if !a:~0^,1!==0 (echo.0) else (
set m=!a!!b!
if !c:~0^,1!==+ (
if !d! lss 16 (
set/a d+=1
for %%d in (!d!) do set m=!m:~0,%%d!.!m:~%%d!
) else (
set/a a=d-16
for /l %%d in (1,1,!a!) do set z=!z!0
set m=!m!!z!
)
) else (
set/a a=d-1
for /l %%d in (1,1,!a!) do set z=!z!0
set m=0.!z!!m!&set m=!m:~0,18!
)
echo.!m!|find ".">nul 2>nul&&call:f !m!
echo.!n!!m!
)
set n=&set z=))>test\%%z
exit
:f
set f=%1
if %f%==0.0000000000000000 set f=0.0000000000000001
for /f "tokens=1,2 delims=." %%a in ("%f%") do set a=%%a&set b=.%%b
:g
if not "!b:~%g%,1!"=="" set/a g+=1&goto:g
for /l %%a in (1,1,%g%) do if not !b:~-%%a^,1!==0 (
set/a h=%%a-1
if not !h!==0 for %%b in (!h!) do set "b=!b:~0,-%%b!"
goto:e)
:e
set m=%a%%b%&set g=
if %m:~-1%==. set m=%m:~0,-1%
复制代码

[ 本帖最后由 hanyeguxing 于 2010-5-2 03:37 编辑 ]

namejm

　　大致的思路应当是这样的：
　　把数值的正负号、整数部分、分数部分、指数部分和指数的正负号分别保存为变量，然后，把指定长度的纯0字符串拼接起来，拼接的规律为：若指数符号为负，则把纯0字符串放到整数部分之前；若指数符号为正，则把纯0字符串放到小数部分之后。把纯0字符串拼接之后，再根据指数部分把小数点位置做相应的移动，最后，把所有部分拼接起来，去掉整数部分之前和小数部分之后的纯0字符串即可。

　　虽然思路比较简单，但是我居然发现在for语句中使用如下代码的时候出错了，如果把其中截取字符串的负号去掉，则该语句正常，百思不得其解：

set num=!str_int:~0,-%num_point%!.!str_int:~%num_point%!!dec!
复制代码

　　9楼的代码之所以慢，是因为使用了管道符号，频繁的I/O操作势必会拖慢速度。

hanyeguxing

1，本批处理使用%%~fd扩展删除0,所以批处理所在路径中最好别用敏感字符
2，本批处理直接修改原文件，所以运行前推荐先将所有原文件备份分：

@echo off
for %%z in (*.txt) do (
      (for /f "usebackq tokens=1,2* delims=e." %%a in ("%%z") do (
            setlocal enabledelayedexpansion
            set a=%%a&set b=%%b&set c=%%c&set d=!c:~1!
            for %%d in (0 0) do if !d:~0^,1!==0 set d=!d:~1!
            if !a:~0^,1!==- set n=-&set a=!a:~1!
            if !a:~0^,1!==0 (echo.0) else (
            set m=!a!!b!
            if !c:~0^,1!==+ (
            if !d! lss 16 (set/a d+=1&for %%d in (!d!) do set m=!m:~0,%%d!.!m:~%%d!) else (
            set/a a=d-16&for /l %%d in (1,1,!a!) do set z=!z!0
            set m=!m!!z!
            )
            ) else (
            set/a a=d-1&for /l %%d in (1,1,!a!) do set z=!z!0
            set m=0.!z!!m!&set m=!m:~0,18!
            if !m!==0.0000000000000000 set m=0.0000000000000001
            )
            if not "!m:.=!"=="!m!" set "m=!m:0= !"&for /f "delims=" %%d in ("!m!") do set m=%%~fd&set "m=!m:%cd%\=!"&set "m=!m: =0!"
            echo.!n!!m!)
      endlocal))>"%%z_"
      del /q "%%z"
      ren "%%z_" "%%z"
)
复制代码

至于：

原帖由 namejm 于 2010-5-2 03:35 发表
虽然思路比较简单，但是我居然发现在for语句中使用如下代码的时候出错了，如果把其中截取字符串的负号去掉，则该语句正常，百思不得其解：
代码:set num=!str_int:~0,-%num_point%!.!str_int:~%num_point%!!dec!

因为没有看到完整代码，个人猜测是这个原因：http://bbs.bathome.net/thread-7629-4-1.html的46楼

[ 本帖最后由 hanyeguxing 于 2010-5-2 09:02 编辑 ]

alexwxcong

谢谢hanyeguxing ，我先备份一个试过了，按你的方法好像是可以，谢谢啊

alexwxcong

原帖由 namejm 于 2010-5-2 01:54 发表
　　1、小数点后的位数是否只保留有16位？
　　2、是否所有的正数都没有前缀+而只有负数才有前缀-？
　　4、e后的004、005之类的是否有可能会达到999？请给出它的范围。

1，小数点后的位数可以不用太多，8位就够了
2，前缀可以不用考虑，可以直接删除E前的那个数字
3，E后面的004/005这种不会超过010

terse

004/005 是否根据+-确定小数点前移或后移4位或5位？如是这样可否移动这个点呢

alexwxcong

恩，其实科学计数就是移动小数点