[文件操作] [已解决]为何批处理将文件写入文件夹时出错？

jcy0307

本想在 当前目录下 以小说名称建立个文件夹 用来存放分割后的小说
但却提示 找不到文件夹
还有就是 在计算分割后的文本有多少行的时候 如果除不整 会和你想分割的数量有差距 如何精确到 小数呢？

@echo off
setlocal EnableDelayedExpansion
color 0a
title 小说分割器 ****JCY0307****
:loop
cls
echo.
echo.
echo     注意:在路径包含空格的目录里，本程序不支持拖放，请将要分割的文本置于本程序同
echo.
echo          级目录，手动输入文件名！
echo.
echo.
echo.
set a=
set/p a=请将文件拖放到此处:
for %%i in (%a%) do if exist %%i set wjm=%%~ni & set kzm=%%~xi
if not "%kzm%"==".txt" echo 耍我呢？你分割的文件不是文本文档！& pause>nul & goto loop
cls
echo 正在计算文本，请稍等.....
set hs=0
for /f "delims=" %%i in (%a%) do set /a hs=!hs!+1 
cls
set b=
set/p b=你想将文本分为几部分:
cls
md !wjm!
set /a c=!hs!/%b%
set d=1
set e=0
for /f "delims=" %%j in (!a!) do (
cls
echo 正在分割第!d!部分，请稍等.....
echo %%j >>!wjm!\!wjm!!d!.txt
set /a e=!e!+1
if "!e!"=="!c!" set /a d=!d!+1 & set e=0
)
cls
echo 分割完毕，按任意键退出！
pause>nul & exit
复制代码

[ 本帖最后由 jcy0307 于 2010-4-19 20:41 编辑 ]

GNU

把@echo off删掉

hanyeguxing

你的第一个问题:
for %%i in (%a%) do if exist %%i set wjm=%%~ni & set kzm=%%~xi
这一句里，&前的空格去了,否则变量wjm会带着这个空格的,下面就会找不到这个路径

for %%i in (%a%) do if exist "%%i" set wjm=%%~ni&set kzm=%%~xi
复制代码

.
你的第二个问题:
set /a c=!hs!/%b%改成

set/a "c=(^!^!(hs%%b))+hs/b"
复制代码

.
顺便说一下:
if not "%kzm%"==".txt" echo 耍我呢？你分割的文件不是文本文档！& pause>nul & goto
对if使用/i参数以忽略大小写

if /i not "%kzm%"==".txt" echo 耍我呢？你分割的文件不是文本文档！& pause>nul & goto
复制代码

[ 本帖最后由 hanyeguxing 于 2010-4-19 00:14 编辑 ]

x9tiancmd

原帖由 hanyeguxing 于 2010-4-18 23:58 发表
set/a "c=(^!^!(hs%%b))+hs/b"

   老兄  能解答下这句 的含意吗,    不怕兄台您笑话,  这句我不懂○(￣﹏￣)○