[其他] [已解决]如何用批处理批量移动文件或文件夹？

smallbear

小弟想用一批处理批量移动文件或文件夹。例如：我在桌面上选中一大堆文件拖到该批处理文件上，则自动将这一大堆文件移动到d:\123文件夹中

请高手不吝赐教。谢谢。

[ 本帖最后由 smallbear 于 2010-4-5 19:49 编辑 ]

smallbear

我自己写了一个

move %1 d:\123
复制代码

我把文件拖动到该批处理上发现它一次只能移动一个文件，而且不能移动文件夹。请高手写个更好的代码。谢谢。

hanyeguxing

@echo off
if not exist "d:\123" md "d:\123"
move "%*" "d:\123"

如果确认"d:\123" 存在，可以不用if not exist "d:\123" md "d:\123"

[ 本帖最后由 hanyeguxing 于 2010-4-5 13:24 编辑 ]

smallbear

谢谢楼上的兄弟，我先试试。

smallbear

不行啊，还是只能移动一个文件，同样不能移动文件夹

hy55310

move不能跨分区移动文件夹

hanyeguxing

原帖由 smallbear 于 2010-4-5 13:31 发表
不行啊，还是只能移动一个文件，同样不能移动文件夹

move在移动目录时，只能在同分区内操作

smallbear

那有没有其它办法？既能移动文件又能移动文件夹，而且能批量移动？

hanyeguxing

原帖由 smallbear 于 2010-4-5 14:15 发表
那有没有其它办法？既能移动文件又能移动文件夹，而且能批量移动？

移动不是问题，麻烦的是你要支持拖放，还得支持路径及名称中有空格

smallbear

这里有一个，哪位高手帮我改一下

@echo off
if exist "%~1\" (echo d|xcopy %1 /e /r /k "d:\123\%~n1" && rd /s /q %1) else (move /y %1 "d:\123\")
pause 
复制代码

这个代码可以移动文件及文件夹，可惜一次只能移动一个，希望哪位高手给我改成一次移动多个文件。谢谢。

FOR

http://www.bathome.net/viewthrea ... hlight=%D2%C6%B6%AF

smallbear

楼上给我的这个链接我试了一下，这个代码不能拖放。不知道别人试过没有，反正我的vista上不能拖放。

hanyeguxing

@echo off&setlocal enabledelayedexpansion
set "d=d:\123"
if not exist "%d%" md "%d%"
for /F "delims=" %%a in ("%*") do (set a=%%a
set a=!a:"=/!
set a=!a:/ /=/!
call:han "!a!")
for /F "delims=" %%i in (temp.h) do if exist "%%~i\" (
xcopy "%%i" /q /e /h /k /i "%d%\%%~ni\">nul
rd /s /q "%%i"
) else move "%%i" "%d%"
del /q temp.h
goto :eof
:han
set "i=%~1"&set n=0
:ye
if "!i:~%n%,1!"=="" goto :eof
if "!i:~%n%,1!"=="/" (echo.>>temp.h)else set/p=!i:~%n%,1!<nul>>temp.h
set/a n+=1&goto :ye
复制代码

在xp sp3下：
多目录拖放操作测试通过
多文件拖放操作测试通过
多目录及文件混合拖放操作测试通过
路径中含空格测试通过
批处理在运行中会产生临时文件temp.h并在结束前删除

smallbear

先谢谢了。我试了一下，在vista中文件夹只能移动一个，文件可以移动多个。再到XP下试试。

FOR

文件名不能含 & 符号
代码未测试，运行前请先做好备份！！！
:

@echo off
set "var=%*"
cls
for %%i in (%var%) do (
   if not exist "%%~i\" (
      if not exist "%%~i" (
         echo 没有 %%~i 文件（夹），请检查文件名是否含 ^& 符号
       ) else (move "%%~i" "d:\123\")
     ) else (
       if /i "%%~di"=="d:" (move "%%~i" "d:\123\") else (
          rem 移动文件夹
          for /f "delims=" %%j in ('dir/b/s/a-d "%%~i\*.*"') do (
              set "num=%%~dpj"
              setlocal enabledelayedexpansion
              set "num=d:\123!num:*%%~i=!\"
              if not exist "!num!" md "!num!"
              move "%%~i\%%~nxj" "!num!"
              endlocal
          )
          rd /s /q "%%~i"
        )
     )
)
pause
复制代码

[ 本帖最后由 FOR 于 2010-4-5 17:22 编辑 ]