[系统增强] 批处理添加IE工具栏按钮

neorobin

IE 默认工具栏上有 前进, 后退, 收藏, 历史等按钮, 这些按钮带来一些方便, MS 也给我们提供了在 IE 工具栏上I添加 自定义 按钮的途径, 而且操作不是很繁琐, 这里用 批处理来实现这种目的. 按钮的目标文件可以是 EXE 文件, BAT, CMD 批处理文件, 以及普通的任何一个有关联程序的文档, 如文本, 音乐, 视频, 图片等等. 不同的按钮可采用不同的图标.

@echo off&setlocal enabledelayedexpansion
:begin
if not exist "%windir%\UUIDGEN.EXE" (call :downloadUUIDGEN
  copy /y !UUIDGENPath! "%windir%\UUIDGEN.EXE")
for /f %%d in ('"%windir%\UUIDGEN.EXE" -n1') do (set GUID=%%d)
if "!GUID!"=="" (echo "%windir%\UUIDGEN.EXE" 无效, 重新下载)& del /f /q "%windir%\UUIDGEN.EXE" & goto begin
echo GUID:%GUID%
set /p scptPath=请输入要添加IE工具栏按钮的执行文件全路径(可将文件直接拖入此窗口再回车):
for %%f in (!scptPath!) do (set scptPath=%%~f)
echo {!scptPath!}
set /p Icon=请输入按钮的图标文件(.ICO)全路径(可将文件直接拖入此窗口再回车, 直接回车=使用默认齿轮图标):
if "!Icon!"=="" (
  set Icon=%windir%\system32\SHELL32.dll,274
  set HotIcon=%windir%\system32\SHELL32.dll,274
) else (
  for %%f in (!Icon!) do (set Icon=%%~f)
  echo {!Icon!}
  (set HotIcon=!Icon!)
)
for %%f in ("%scptPath%") do (set bttnText="%%~nf")
(set keyPath=HKLM\Software\Microsoft\Internet Explorer\Extensions\{%GUID%})
reg add "!keyPath!"
reg add "!keyPath!" /v ButtonText /t reg_sz /d %bttnText%
reg add "!keyPath!" /v HotIcon /t reg_sz /d "%HotIcon%"
reg add "!keyPath!" /v Icon /t reg_sz /d "%Icon%"
reg add "!keyPath!" /v "Default Visible" /t reg_sz /d Yes
reg add "!keyPath!" /v ToolTip /t reg_sz /d %bttnText%
reg add "!keyPath!" /v CLSID /t reg_sz /d {1FBA04EE-3024-11D2-8F1F-0000F87ABD16}
reg add "!keyPath!" /v Exec /t reg_sz /d "%scptPath%"
echo 新工具栏按钮注册表设置已完成, 请手工自定义 IE 工具栏添加 %bttnText% 按钮.
start iexplore about:blank
pause
exit /b

:downloadUUIDGEN
for /r %SystemDrive% %%b in (UUIDGEN.EXE) do (
  if exist "%%~fb" (set UUIDGENPath="%%~fb")&(echo !UUIDGENPath!)&goto stopSch
)
:stopSch
if not defined UUIDGENPath echo %SystemDrive% 盘没找到文件 UUIDGEN.exe, 按任意键打开下载链接... &(pause>nul)&(
  start iexplore http://www.filediag.com/down.php?file_id=6813
  start iexplore http://www.filediag.com/download.php?file_id=6813^&downid=1
  start iexplore http://www.filediag.com/download.php?file_id=6813^&downid=2
  start iexplore http://www.filediag.com/download.php?file_id=6813^&downid=3
)&(echo 若文件已下载到 %SystemDrive% 盘, 请按任意键继续...)&(pause>nul)&call :downloadUUIDGEN
exit /b
复制代码

neorobin

现在包含空格的路径拖入后 解析错误 的问题已 修正

lxzzr

能否兼容IE7、8？

neorobin

没及时回复你, 没用 IE 7,8 真不知道