aloha20200628

楼主的几轮帖子把纯P的for/f切割器开出刃来了...

@echo off &setlocal enabledelayedexpansion
(for /f tokens^=1-10^ delims^=^	^=^<^" %%a in (' findstr "=" "1.xml" ') do (
	if /i "%%a"=="skillTree type" (set "v1=%%d")
	if /i "%%a"=="skill skillName" (
		if defined v (echo,)
		set "v=!v1!	%%b	%%d	%%f	%%h"
		if /i "%%j" neq "true" (set "v=!v!	%%j")
		set/p="!v!"<nul)
	if /i "%%a"=="item id" (echo,	%%b	%%d&set "v=")
))>"sour.csv"
endlocal&exit/b
复制代码

aloha20200628

再换一种纯P老刀的切法，顺便复习一遍 if 句式中如何比较双引号"的方法...

@echo off &setlocal enabledelayedexpansion
(for /f "tokens=1* delims=	< " %%a in (' findstr "=" "1.xml" ') do (
	if /i "%%~a"=="skillTree" for /f tokens^=1-4^ delims^=^" %%1 in ("%%~b") do (set "v1=%%4")
	if /i "%%~a"=="skill" (
		if defined v (echo,)
		set "v=!v1!" & for %%i in (%%~b) do (
			set i=%%i &set "c=!i:~,1!"
			if ^!c!==^" if /i "!i:~1,4!" neq "true" set "v=!v!	!i:~1,-2!")
		set/p="!v!"<nul
	)
	if /i "%%~a"=="item" for /f tokens^=1-4^ delims^=^" %%1 in ("%%~b") do (echo,	%%2	%%4&set "v=")
))>"sour.csv"
endlocal&exit/b
复制代码

aloha20200628

用jscript在纯P壳里跑一遍，处理大数据应会有明显效率差别
以下代码存为test.bat运行，结果生成与源文件 1.xml （一楼示例样本）对应的 sour.csv

@set @v=1 /* @echo off & type "1.xml"|cscript /e:jscript "%~f0">"sour.csv" &exit/b
*/
var lines = WSH.stdin.readall().split('\n');
var v1, v, tk, tk0, ltk, vLines = [];
for (var n=0,l=lines.length; n<l; n++) {
	if (lines[n].indexOf('=') == -1) continue;
	tk = lines[n].split(/[\t=<]+/); ltk = tk.length; tk0 = tk[0].toLowerCase();
	if (tk0 == 'skilltree type') v1 = tk[2].split(/"+/)[0];
	else if (tk0 == 'skill skillname') {
		v = v1;
		for (var k=1; k<ltk; k++)
			if (tk[k].slice(0,1) == '\"' && tk[k].slice(1,5).toLowerCase() != 'true')
				v += '\t'+tk[k].split(/"+/)[0];
		vLines.push(v);
	} else if (tk0 == 'item id') {
		v += '\t'+tk[1].split(/"+/)[0]+'\t'+tk[2].split(/"+/)[0]; vLines.pop(); vLines.push(v);
	}
}
WSH.echo(vLines.join('\n'));
复制代码