[文件操作] 批处理怎样拆分文件，补全序号位数与最大值位数相同？

qd2024

我经常会导出一些文件，以PDF为主，但不仅限于PDF，以“_”下划线为分界，前端为原文件文件名，后端为自然序号，对应原文件的页码，想统一导出文件，“_”下划线后端自然序号的位数，

当运行BAT时，先自动判断“_”下划线后序号的最大值，以确定序号的位数，如例图中是124，则所有“_”下划线后序号要补充为3位数，          若最大值为78则，所有“_”下划线后序号要补充为2位数，若最大值为1178则，所有“_”下划线后序号要补充为4位数，也就是最大值为几位，就把其他序号都补充到几位。

补充数位的结果是，在“_”下划线和原有序号之间插入相应个数的“0”.

谢谢
链接：https://pan.baidu.com/s/1o7aCmYyNIepGhqU0alKqfw?pwd=vt04
提取码：vt04
--来自百度网盘超级会员V10的分享


下面2张图片是 处理前 后的对比，
【处理前】


【处理后】

ppll2030

回复 29# qixiaobin0715


    感谢指导。又学到一招。

qixiaobin0715

回复 27# ppll2030
第8行代码有时会误伤。

set str=!str:%%i=!
复制代码

比如文件名前面序号是1，而文件名某处也包含1，就会出现问题。不如修改为：

set str=!str:*%%i=!
复制代码

这样更加严谨一些。

qixiaobin0715

回复 21# qd2024
前后数字都一样？不会出现“1.1 1.2 1.3...2.1 2.2...”等情况。

ppll2030

回复 21# qd2024


    如果楼主的文件规律如此整齐可寻。那还是可以用五楼的代码修改一下变量即可得到想要的结果。
五楼楼主的代码我感觉很经典。执行效率也快。
我稍微改了一下。测试结果正确。楼主也可测试一下。
ps：根据大大的指导，再次修改，效果更佳。:lol

@echo off
setlocal enabledelayedexpansion
for %%i in (1 10 100 1000 10000) do if exist %%i.*.pdf set n=%%i
echo %n%
set /a n*=10
for /f "tokens=1-3 delims=." %%i in ('dir /b /a-d *.*.pdf') do (
    set m=%%i
    set str=%%j&set str=!str:*%%i=!
    set /a m+=n
    REM 执行更名请去除echo
    echo ren "%%i.%%j.%%k" "!m:~1!!str!.%%k"
)
pause&exit
复制代码

WHY

假设最大数字位数不超过30位，事实上，30位已经是天文数字。

用 Test-Path 速度太慢，改用正则判断。

$srcPath = 'D:\Test\';
$max = 0;
$files = dir -Path $srcPath -Filter *_*.pdf;

for ($i = 30; $i -ge 1; $i--) {
    $reg = '_[0-9]{' + $i + '}$';
    if (($files.BaseName -match $reg).Count -gt 0) {$max = $i; break;}
}

$reg = '_[0-9]{1,' + ($max-1) + '}$';
$files | ?{$_.BaseName -match $reg} | ren -NewName {
    $arr = $_.BaseName.Split('_');
    $arr[-1] = $arr[-1].PadLeft($max, '0');
    ($arr -join '_') + $_.Extension;
} -whatIf
pause
复制代码

aloha20200628

24楼代码已从调试版订正为实用版，其中目标文件类型根据21楼示例中的文件类型已调整为*.mp4

aloha20200628

回复 21# qd2024

增加一个子过程/函数 cutP 用于截取文件名首部小数点后两个目标字段，以小数点后序号为准匹配最大长度。

@echo off &setlocal enabledelayedexpansion
dir /b/s/a-d "%~1\*.mp4">0.0 & (call :getMax 0.0 m)
(endlocal & set "max=%m%") & setlocal enabledelayedexpansion
for /L %%n in (1,1,%max%) do set "p=0!p!"
for /f "delims=" %%F in (0.0) do (
   set "xF=%%~xF" & for /f "tokens=1-2 delims=." %%1 in ("%%~nF") do (
     (call :cutP "%%~2" %max% s1 s2) & set "q=!p!!s1!" & ren "%%~F" "!q:~-%max%!!s2!!xF!")
)
del 0.0 & endlocal & exit/b

:getMax // %1=listF %2=digits
  :[loop]
  set/a "k+=1" & set "n=!n![0-9]" & findstr "\.!n![^0-9]" "%~1">nul && goto[loop] || (set/a "%~2=k" & exit/b)
:cutP // %1=nameF %2=max %3=s1 %4=s2
  (set "s=%~1" & for /L %%n in (%~2,-1,0) do if "!s:~%%n,1!" geq "0" if "!s:~%%n,1!" leq "9" (
     set/a "k=%%n+1" & for %%k in (!k!) do (set "%~3=!s:~,%%k!" & set "%~4=!s:~%%k!") & exit/b))
  exit/b
复制代码

newswan

关于 获取字符串长度，还有一个高效方法：
http://www.bathome.net/viewthrea ... AF%CA%FD&page=1

newswan

学习了大家的解法
批处理比较麻烦

不是从1到n情况下，

$folder = "1"
$file = Get-ChildItem -path $folder -Filter "*.pdf" | Sort-Object { ($_.BaseName -replace "^.+_") -as [int] }
$lenMax = ( ( $file | ForEach-Object { ( ($_.BaseName -replace "^.+_").tostring() ).length } ) | Sort-Object )[-1]
$file | ForEach-Object {
	$arr = $_.basename -split "_"
	if ( $arr[1].length -lt $lenMax ) {
		$newName = $arr[0] + "_" + ( "{0:d$lenmax}" -f [int]$arr[1] ) + $_.extension
		Rename-Item $_.fullname -newname $newName
	}
}
复制代码

qd2024

回复 9# aloha20200628


   

师兄 用第一种方法 怎样才能把文件名前面的序号补齐数位，文件名左端第1个“.”做为分界点，前后的序号，都依据文件总数在不足位的数的前面补“0” ，  使序号的位置与总数位数一致，最后删除“.”和前面的序号，如下图


谢谢

hfxiang

回复 1# qd2024
可借助第3方工具gawk（http://bcn.bathome.net/tool/4.1.0/gawk.exe）来解决

@rem 拆分文件补全序号位数，位数修改（-v"N=03"）即可，如4位则改为（-v"N=04"），类推...
@echo off&cd /d "%~dp0"
dir /b *.pdf|gawk -v"N=03" -F"[_.]" "{o=$0;$2=sprintf(\"%%\"N\"d\",$2);print \"move /Y \\\"\" o \"\\\" \\\"\" $1 \"_\" $2 \".\" $3 \"\\\"\"}"|cmd.exe
复制代码

qixiaobin0715

如果序号不连续也可以这样，不过要搜索2次文件，效率上稍差：

@echo off
set n=0
setlocal enabledelayedexpansion
for /f "tokens=2 delims=_" %%i in ('dir /b /a-d *_*.pdf') do (
    if %%~ni gtr !n! set n=%%~ni
)
for /l %%i in (1,1,9) do set n=!n:%%i=0!
set n=1!n!
for /f "tokens=1* delims=_" %%i in ('dir /b /a-d *_*.pdf') do (
    set m=%%~nj
    set /a m+=n
    ren "%%i_%%j" "%%i_!m:~1!%%~xj"
)
pause
复制代码

5楼代码有一处笔误，已修改。

WHY

回复 17# buyiyang
多翻一翻老帖：
http://www.bathome.net/viewthread.php?tid=7629

示例：
(echo test)|findstr /c:" "
效果：显示test，findstr认为前面的命令输出含有空格
注释：CMD的预处理在分析语句时，会在)和|这些有特殊意义的转义字符前后插入空格，同时剪除多余的空格。
        而当)和|一同出现时，CMD的预处理没有把这些空格从命令行中全部过滤掉，而会遗漏一个空格到echo命令中。
        而echo命令则把这个空格连通之前文本一同输出到管道后命令findstr中，所以导致findstr匹配出含空格行。
链接：http://www.bathome.net/viewthrea ... amp;page=3#pid50356
        http://www.bathome.net/viewthrea ... amp;page=4#pid28166

buyiyang

回复 15# WHY

看我12楼第四个例子，

(echo,a&echo,b)>1.txt
61 0D 0A 62 0D 0A
复制代码

虽然控制台显示

(echo,a & echo,b ) > 1.txt
复制代码

但输出并没有空格。

@echo off >&3 3>1.txt
echo,a&echo,b
复制代码

这样也是，只有通过管道才会有空格。