qixiaobin0715

考虑不是太成熟，代码应当还能简化，只是提供一种思路：

@echo off
setlocal enabledelayedexpansion
(for /f "tokens=1*" %%a in (a.csv) do (
    setlocal enabledelayedexpansion
    set FirstCol=%%a
    for %%j in (%%b) do (
        for /f "delims=0123456789." %%k in ("#%%j") do (
            if not "%%k"=="#" (
                if !x! equ 3 (
                    set /a y+=1
                    set _!y!=!str!
                ) else if !x! equ 4 (
                    if defined _!y! (
                        for /l %%l in (1,1,!y!) do (
                            if defined FourthCol (
                                echo,%%a	!_%%l!	!FourthCol!
                            ) else (
                                echo,%%a	!_%%l!
                            )
                            set _%%l=
                        )
                        set FourthCol=
                        set y=0
                    )
                    echo,%%a	!str!
                )
                set str=%%j
                set x=0
            ) else (
                set str=!str!	%%j
                set /a x+=1
                if !x! equ 4 set FourthCol=%%j
            )
        )
    )
    if defined _!y! (
        for /l %%l in (1,1,!y!) do (
            if defined FourthCol (
                echo,!FirstCol!	!_%%l!	!FourthCol!
            ) else (
                echo,!FirstCol!	!_%%l!
            )
        )
    )
    echo,!FirstCol!	!str!
    endlocal
))>out.csv
pause
复制代码

qixiaobin0715

主要是练练手。
将楼上代码修改如下：

@echo off
setlocal enabledelayedexpansion
(for /f "tokens=1*" %%a in (a.csv) do (
    setlocal enabledelayedexpansion
    for %%j in (%%b,x) do (
        for /f "delims=0123456789." %%k in ("#%%j") do (
            if not "%%k"=="#" (
                if !x! equ 3 (
                    set /a y+=1
                    set _!y!=!str!
                ) else if !x! equ 4 (
                    if defined _!y! (
                        for /l %%l in (1,1,!y!) do (
                            if defined FourthCol (
                                echo,%%a	!_%%l!	!FourthCol!
                            ) else (
                                echo,%%a	!_%%l!
                            )
                            set _%%l=
                        )
                        set FourthCol=
                        set y=0
                    )
                    echo,%%a	!str!
                )
                set str=%%j
                set x=0
            ) else (
                set str=!str!	%%j
                set /a x+=1
                if !x! equ 4 set FourthCol=%%j
            )
        )
    )
    endlocal
))>out.csv
pause
复制代码

qixiaobin0715

13、14楼提供代码好像不行，刚发现楼主提供的csv文件在599行中，英文名称含有空格，分割时会出现问题。以上代码作废。
使用不带参数的for循环，按水平制表符分割字符串时不能存在干扰字符，即要分割的字符串中不能存在空格、逗号、分号、等号等这类字符，这种情况应当也能解决，不过可能要在前面多几行代码处理一下字符串即可。

qixiaobin0715

修改14楼的代码，以便解决15楼的问题：

@echo off
setlocal enabledelayedexpansion
(for /f "tokens=1*" %%a in (a.csv) do (
    setlocal enabledelayedexpansion
    set Line="%%b"
    set Line=!Line:	="	"!
    set Line=!Line:""=!
    for %%j in (!line!,x) do (
        for /f "delims=0123456789." %%k in ("#%%~j") do (
            if not "%%k"=="#" (
                if !x! equ 3 (
                    set /a y+=1
                    set _!y!=!str!
                ) else if !x! equ 4 (
                    if defined _!y! (
                        for /l %%l in (1,1,!y!) do (
                            if defined FourthCol (
                                echo,%%a	!_%%l!	!FourthCol!
                            ) else (
                                echo,%%a	!_%%l!
                            )
                            set _%%l=
                        )
                        set FourthCol=
                        set y=0
                    )
                    echo,%%a	!str!
                )
                set str=%%~j
                set x=0
            ) else (
                set str=!str!	%%~j
                set /a x+=1
                if !x! equ 4 set FourthCol=%%~j
            )
        )
    )
    endlocal
))>out.csv
pause
复制代码

这种问题对于锻炼逻辑思维很有好处。顺便练习一下if及set命令的用法。