[文件操作] 批处理如何移动目录下文件到指定的文件夹？

小白来了

小白求助：
一、如何用bat命令移动本目录下的.rar文件到D盘的自定义目录呢？

二、如何用bat命令移动多个文件夹下的rar文件到D盘的自定义目录？


非常小白，向大哥们学习

Batcher

回复 1# 小白来了


1.bat

@echo off
set "NewFolder=D:\Test"
if not exist "%NewFolder%" (
    md "%NewFolder%"
)
cd /d "%~dp0"
move /y *.rar "%NewFolder%"
复制代码

小白来了

回复 2# Batcher


    真厉害啊老板！谢谢了！我在多个文件夹里面放了.bat代码，想一键运行所有文件夹里面的.bat，应该怎样写代码

Batcher

回复 1# 小白来了


假设 D:\ABC 文件夹下面有多个子文件夹，每个子文件夹下有rar文件。把 2.bat 放在 D:\ABC 文件夹下执行。

@echo off
set "NewFolder=D:\Test"
if not exist "%NewFolder%" (
    md "%NewFolder%"
)
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /s /a-d *.rar') do (
    move /y "%%i" "%NewFolder%"
)
复制代码

小白来了

回复 4# Batcher


    大哥，我想在一个bat里面运行，上面执行了一些代码，然后后面应该怎样把这个.rar命名成和文件夹一样的名字，然后移动到D盘指定的目录。

小白来了

回复 2# Batcher


写到一个里面，上面执行了一个bat命令了，到第二步不操作了。这段代码应该怎样修改呢？

    rem 第2步：名称修改为文件夹名
for /f "delims=" %%i in ('dir /b /s /a-d *.rar') do (
    for %%j in ("%%i\..") do (
        ren "%%i" "%%~nxj%%~xi"
		
rem 第3步：移动到D盘指定文件夹		
set "NewFolder=D:\test"
if not exist "%NewFolder%" (
    md "%NewFolder%"
)
cd /d "%~dp0"
move /y *.rar "%NewFolder%"
复制代码

Batcher

回复 5# 小白来了


3.bat

@echo off
set "NewFolder=D:\Test"
if not exist "%NewFolder%" (
    md "%NewFolder%"
)
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /s /a-d *.rar') do (
    for %%a in ("%%i\..") do (
        move /y "%%i" "%NewFolder%\%%~nxa%%~xi"
    )
)
复制代码

小白来了

回复 7# Batcher


   大哥，我是想在一个bat文件里面执行后面的命令，到这时没有了反应。应该怎样写呢？

Batcher

回复 8# 小白来了


    能否举例说明7楼代码和你想要的效果有何差异？我不知道你想要做什么

小白来了

回复 9# Batcher


    例如在一个bat文件代码中，第一步：把文件夹内的文件压缩为rar了。第二步把rar改成本文件夹名称然后移动到D盘。

小白来了

回复 9# Batcher


    7楼的代码单独执行是可以的，只是和第一步写到一个bat里面后，就没反应了。。

Batcher

回复 10# 小白来了


    请把你写的第一步：把文件夹内的文件压缩为rar的完整代码发出来，我帮你合并。

小白来了

回复 12# Batcher


    可以了大哥，刚才复制错了。。。然后重新copy的代码，可以了。感谢大哥！膜拜了！

Victorsean

回复 7# Batcher


    大佬，如果是不同分区可以移动么？ D:\OUT 文件夹里有多个文件夹，每个文件夹里有多个rar文件，能不能 移动到 E:\PPF 文件夹，保持原来的文件夹目录不变

ShowCode

回复 14# Victorsean

robocopy "D:\OUT" "E:\PPF" *.rar /s /move
复制代码