- 帖子
- 754
- 积分
- 973
- 技术
- 4
- 捐助
- 0
- 注册时间
- 2021-8-30
|
[文本处理] 【已解决】求:bat修改文本内容(第三方也行)。谢谢!
本帖最后由 yyz219 于 2023-10-10 14:53 编辑
完美解决了
@echo off
::【导出注册表为:需修改.reg】
set /p 注册表路径=【右键】粘贴注册表路径:
reg query "%注册表路径%" /s >需修改.reg
::***************************************
::【修改:需修改.reg 变成:有路径.reg】
>有路径.reg (
echo Windows Registry Editor Version 5.00
echo=
)
for /f "tokens=1 delims=[]" %%a in ('find /n "默认" ^<"需修改.reg"') do (
set _"%%a"=1
)
(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<"需修改.reg"') do (
if "%%b" equ "" (
echo=
) else if not defined _"%%a" (
echo [%%b]
) else (
for /f "tokens=1-2*" %%c in ("%%b") do (
set str=%%e
setlocal enabledelayedexpansion
echo=@="!str:\=\\!"
endlocal
)
)
))>>有路径.reg
del 需修改.reg
_________________________________________________________________________________________
原来的问题:
需要修改的1.reg(蓝色内容不是固定的):
HKEY_CLASSES_ROOT\Imagine.PNG\shell\888
(默认) REG_SZ 888
HKEY_CLASSES_ROOT\Imagine.PNG\shell\888\command
(默认) REG_EXPAND_SZ D:\1绿色软件\多媒体\抓图抓滚动\抓滚动FSCapture97\FSCapture.exe %1
————————————————————————————
希望运行.bat后,得到“修改以后2.reg”:
Windows Registry Editor Version 5.00
[HKEY_CLASSES_ROOT\Imagine.PNG\shell\888]
@="888"
[HKEY_CLASSES_ROOT\Imagine.PNG\shell\888\command]
@="D:\\1绿色软件\\多媒体\\抓图抓滚动\\抓滚动FSCapture97\\FSCapture.exe %1" |
|