[日期时间] 【已解决】求批处理：查看文件修改时间，谢谢

yyz219

问题完美解决了：
::【判断火绒今天是否已更新】
@echo off
::【判断火绒今天是否已更新】（原理：查“HRUpdate.exe.log”文件今天有无修改）
for %%i in ("C:\Program Files (x86)\Huorong\Sysdiag\bin\HRUpdate.exe.log") do (set "FileTS=%%~ti")
if "%FileTS:~0,10%" equ "%date:~0,10%" (goto :A) else (goto :B)
:A
::【今天已更新】
exit
:B
::【今天未更新】
start "" "火绒15秒后更新.vbs"
exit
**************************************************
原来的问题：
需求：

查看文件 "C:\Program Files (x86)\Huorong\Sysdiag\VERSION" 修改时间（VERSION是没有后缀的文件）
如果修改时间是今天，跳到   :A
如果修改时间不是今天，跳到   :B

谢谢

Batcher

回复 1# yyz219

@echo off
for %%i in ("C:\Program Files (x86)\Huorong\Sysdiag\VERSION") do (
    set "FileTS=%%~ti"
)
if "%FileTS:~0,10%" equ "%date:~0,10%" (
    goto :A
) else (
    goto :B
)
goto :End

:A
echo hello A
goto :End

:B
echo hello B
goto :End

:End
pause
复制代码

yyz219

回复  yyz219
Batcher 发表于 2023-9-14 10:11

    我试一试先 谢谢

Batcher

回复 1# yyz219

@echo off
for /f "tokens=2 delims==" %%i in ('wmic DataFile where "Name='C:\\Program Files (x86)\\Huorong\\Sysdiag\\VERSION'" get LastModified /value') do (
    set "FileTS=%%i"
)
for /f "tokens=2 delims==" %%i in ('wmic Path Win32_OperatingSystem get LocalDateTime /value') do (
    set "SysTS=%%i"
)
if "%FileTS:~0,8%" equ "%SysTS:~0,8%" (
    goto :A
) else (
    goto :B
)
goto :End

:A
echo hello A
goto :End

:B
echo hello B
goto :End

:End
pause
复制代码

yyz219

回复  yyz219
Batcher 发表于 2023-9-14 10:11

    问题解决了 再次感谢