77七

备份，文件大小大于n则记录文件大小，否则记录md5，不考虑大文件大小相同。

@echo off
set /a n=10*1024*1204
(for /r %%i in (*) do (
	if "%%i" neq "%~f0" (
		if %%~zi gtr %n% (
			echo %%~zi^|%%~nxi
		) else (
			for /f "delims=" %%a in ('certutil -hashfile "%%i" MD5 ^| find /v ":"') do echo %%a^|%%~nxi
		)
	)
))>back.txt
pause
复制代码

恢复

@echo off
set /a n=10*1024*1204
for /r %%i in (*) do (
	if "%%i" neq "%~f0" if "%%i" neq "%~dp0back.txt" (ren "%%i" "%%~nxi.$")
)
for /r %%i in (*.$) do (
	if %%~zi gtr %n% (
		for /f "tokens=1* delims=|" %%f in ('find "%%~zi|" ^<back.txt') do ren "%%i" "%%g"
	) else (
		for /f "delims=" %%a in ('certutil -hashfile "%%i" MD5 ^| find /v ":"') do (
			for /f "tokens=1* delims=|" %%f in ('find "%%a|" ^<back.txt') do ren "%%i" "%%g"
		)
	)
)
pause
复制代码

77七

回复 4# thp2008

@echo off
rem cmd 窗口执行 bh.bat back
rem cmd 窗口执行 bh.bat huifi
set /a n=10*1024*1204
echo %~1
goto :%~1
exit /b
:back
(for /r %%i in (*) do (
	if /i not "%%~xi" equ ".bat" (
		if %%~zi gtr %n% (
			echo %%~zi^|%%~nxi
		) else (
			for /f "delims=" %%a in ('certutil -hashfile "%%i" MD5 ^| find /v ":"') do echo %%a^|%%~nxi
		)
	)
))>"%temp%\back.txt"
echo done
"%temp%\back.txt"
exit /b

:huifu
if not exist "%temp%\back.txt" (
	exit /b
)
for /r %%i in (*) do (
	if /i not "%%~xi" equ ".bat" (
		ren "%%i" "%%~nxi.$"
	)
)
for /r %%i in (*.$) do (
	if %%~zi gtr %n% (
		for /f "tokens=1* delims=|" %%f in ('find "%%~zi|" ^<"%temp%\back.txt"') do ren "%%i" "%%g"
	) else (
		for /f "delims=" %%a in ('certutil -hashfile "%%i" MD5 ^| find /v ":"') do (
			for /f "tokens=1* delims=|" %%f in ('find "%%a|" ^<"%temp%\back.txt"') do ren "%%i" "%%g"
		)
	)
)
echo done
exit /b
复制代码

恢复之后不会删除back.txt，备份一次，可以多次恢复。不考虑 ”大文件“ 大小相同，不考虑0字节文件。

77七

加上一个什么 pushd  %~dp0 什么的

站内搜一下，给鼠标右键菜单添加 打开cmd，直接在需要的目录下打开cmd窗口执行就行了。