Batcher

回复 1# szmsys


请参考Q-04把bat文件保存为ANSI编码放在C:\sample文件夹下：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

@echo off
cd /d "%~dp0"
REM 指定天数
set "DaysAgo=1"
for /f %%i in ('powershell -c "Get-Date (Get-Date).AddDays(-%DaysAgo%) -uformat "%%Y-%%m-%%d""') do (
    set "DstDate=%%i"
)
if not exist "%DstDate%" (
    md "%DstDate%"
)
move "%DstDate%-*.txt" "%DstDate%"
复制代码

每天定时执行请参考：批处理系统管理之4 - 任务计划篇
https://mp.weixin.qq.com/s/LKTmJuq45bZbxoGVTfla1w

Batcher

【新需求】
第一步：在 C:\sample 下 生成一个以昨天的日期命名的文件夹：YYYY-MM-DD
第二步：把 C:\sample 下 生成日期不是今天的文件，全部移动到这个新建文件夹里

【新方案】

@echo off
cd /d "%~dp0"
REM 指定天数
set "DaysAgo=1"
for /f %%i in ('powershell -c "Get-Date (Get-Date).AddDays(-%DaysAgo%) -uformat "%%Y-%%m-%%d""') do (
    set "DstDate=%%i"
)
if not exist "%DstDate%" (
    md "%DstDate%"
)
for /f %%i in ('powershell "Get-Date -uformat '%%Y-%%m-%%d'"') do (
    set "Today=%%i"
)
for /f "delims=" %%i in ('dir /b /a-d *.txt ^| findstr /v /b "%Today%"') do (
    move "%%i" "%DstDate%"
)
pause
复制代码