Batcher

回复 1# 7758234


请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

@echo off
REM 设置待排除的目录（注意以\结尾）
set "ExFolder=C:\Users\Administrator\Desktop\"
for %%a in (C D E) do (
    if exist %%a:\ (
        echo 正在搜索%%a:\
        pushd %%a:\
        for /f "delims=" %%b in ('dir /b /s /a-d *.pdf *.doc *.xls 2^>nul ^| find /v /i "%ExFolder%"') do (
            REM 如果显示的结果没有问题，把下面的echo去掉再次执行即可删除文件
            echo del /f /q "%%b"
        )
        popd
    )
)
pause
复制代码

Batcher

回复 2# 77七


    如果待排除的文件较多，可能超出变量上限。

Batcher

回复 10# 7758234


方法1.bat

@echo off
REM 设置待排除的目录（注意以\结尾）
set "ExFolder1=C:\Users\Administrator\Desktop\"
set "ExFolder2=C:\Program Files\"
for %%a in (C D E) do (
    if exist %%a:\ (
        echo 正在搜索%%a:\
        pushd %%a:\
        for /f "delims=" %%b in ('dir /b /s /a-d *.pdf *.doc *.xls 2^>nul ^| find /v /i "%ExFolder1%" ^| find /v /i "%ExFolder2%" ') do (
            REM 如果显示的结果没有问题，把下面的echo去掉再次执行即可删除文件
            echo del /f /q "%%b"
        )
        popd
    )
)
pause
复制代码

Batcher

回复 18# 7758234


备份.bat

@echo off
REM 设置待排除的目录（注意以\结尾）
set "ExFolder1=C:\Users\Administrator\Desktop\"
set "ExFolder2=C:\Program Files\"
REM 导出的文件列表
set "OutFile=%~dp0备份.csv"
REM 设置新的临时后缀名
set "NewExt=ttttt"
>"%OutFile%" echo OldName,NewName
for %%a in (C D E) do (
    if exist %%a:\ (
        echo 正在搜索%%a:\
        pushd %%a:\
        for /f "delims=" %%b in ('dir /b /s /a-d *.pdf *.doc *.xls 2^>nul ^| find /v /i "%ExFolder1%" ^| find /v /i "%ExFolder2%" ') do (
            echo 正在查找 %%b
            >>"%OutFile%" echo "%%b","%%b.%NewExt%"
            REM 如果显示的结果没有问题，把下面的echo去掉再次执行即可重命名文件
            echo ren "%%b","%%~nxb.%NewExt%"
        )
        popd
    )
)
pause
复制代码

恢复.bat

@echo off
set "InFile=%~dp0备份.csv"
for /f skip^=1^ tokens^=3^ delims^=^" %%a in ('type "%InFile%"') do (
    REM 如果显示的结果没有问题，把下面的echo去掉再次执行即可重命名文件
    echo ren "%%a" "%%~na"
)
pause
复制代码

Batcher

回复 20# 7758234


19楼代码已经更新，可以处理同一个文件夹下包含：
测试.doc
测试.pdf
测试.xls
这种情况

恢复的时候，就是要读取csv文件的NewName和OldName进行重命名。直接搜索.ttttt是不好的方法。

Batcher

回复 22# 7758234


    请参考19楼：恢复.bat