qixiaobin0715

换换另一个思路：

@echo off
set n=1
setlocal enabledelayedexpansion
(for /f "tokens=1* delims=>" %%i in (a.txt) do (
    for /f %%x in ("%%j") do (
        if "%%x"=="企业" (
            if not "%%j"=="!str!" (
                if !n! equ 0 (
                    echo,!Times!^>   退出
                    echo,
                )
            )
            set n=0
            set "str=%%j"
        ) else if "%%x"=="退出" (
            echo,%%i^>%%j
            echo,
            set m=0
            set n=1
        )
    )
    set "Times=%%i"
    if not defined m echo,%%i^>%%j
    set m=
)
if !n! equ 0 echo,!Times!^>   退出)>b.txt
pause
复制代码

娜美

回复 31# qixiaobin0715


对对对, 和18楼哥哥一样,  完全正确了, 哥哥你这思路就很好嘛,    给代码赋予了智慧, 就像Ai一样灵活地工作,,批处理还能很快不到5分钟

娜美

回复 31# qixiaobin0715


     检测发现会改变原本某些行内容, 特别是有 "!" 号行   问题是似乎不支持在 ">" 之后某些字符, 但无论如何, 与之没有关系的这些行不应该会受到影响或强制改变他原样

用符号测验原来会吃掉一大半字符
20:39:30 August 16 2023> ! ++
20:39:30 August 16 2023>   ` ~!@#$%^&*()_+=-{}|[]\:;'<>?,./ " 用符号测验出原因了, 原来是会吃掉在 ">" 之后的一大半字符,

qixiaobin0715

回复 33# 娜美
出现这种情况的原因见 http://www.bathome.net/thread-11193-1-1.html
但是我觉得在这里for循环体内使用setlocal和endlocal不适合，因为要兼顾到当前行上面的若干行，endlocal后，前面所有设置的变量都消失了。还是考虑其它程序或方法。

qixiaobin0715

其它变量还可以想办法解决，31楼代码第22行变量Times的设置不好处理，因为你要增加的“退出”那一行，要使用上一行的时间。

qixiaobin0715

想了想，楼上说的有点太绝对，好像可以在特定位置添加setlocal和endlocal组合来实现部分特殊字符显示原样输出的问题，代码未测试：

@echo off
(for /f "tokens=1* delims=>" %%i in (a.txt) do (
    for /f %%x in ("%%j") do (
        if "%%x"=="企业" (
            setlocal enabledelayedexpansion
            if not "%%j"=="!str!" (
                if "!n!"=="0" (
                    echo,!Times!^>   退出
                    echo,
                ) else if defined n (
                    echo,
                )
            )
            endlocal
            set n=0
            set "str=%%j"
        ) else if "%%x"=="退出" (
            set n=1
        )
    )
    echo,%%i^>%%j
    set "Times=%%i"
))>b.txt
if %n% equ 0 echo,%Times%^>   退出>>b.txt
pause
复制代码

请自行测试。

娜美

回复 36# qixiaobin0715


  确实可以解决原样输出的问题哦 但如果 名称 部分有特殊字符发现一律会当不相同处理, 会插入一行,   特别是含有 "!" 字符,    似乎是识别字符不够多

为了测验,  我偿试举了一些含有 "!" 字符 例试试
20:37:30 August 16 2023> 企业 名称:美!
20:37:30 August 16 2023> 企业 名称:美!


20:37:30 August 16 2023> 企业 名称:美
20:37:30 August 16 2023> 企业 名称:美


多特殊字符, 批处理不知道能够支持多少

20:37:30 August 16 2023>   企业 名称:美` ~!@#$%^&*()_+=-{}|[]\:;'<>?,./ "0123456789zxcvbnmasdfghjklqwertyuiopZXCVBNMASDFGHJKLQWERTYUIOP
20:39:30 August 16 2023> ! ` ~!@#$%^&*()_+=-{}|[]\:;'<>?,./ "0123456789zxcvbnmasdfghjklqwertyuiopZXCVBNMASDFGHJKLQWERTYUIOP
20:37:30 August 16 2023>   企业 名称:美` ~!@#$%^&*()_+=-{}|[]\:;'<>?,./ "0123456789zxcvbnmasdfghjklqwertyuiopZXCVBNMASDFGHJKLQWERTYUIOP
20:39:30 August 16 2023> ! ` ~!@#$%^&*()_+=-{}|[]\:;'<>?,./ "0123456789zxcvbnmasdfghjklqwertyuiopZXCVBNMASDFGHJKLQWERTYUIOP
20:37:30 August 16 2023>   企业 名称:美` ~!@#$%^&*()_+=-{}|[]\:;'<>?,./ "0123456789zxcvbnmasdfghjklqwertyuiopZXCVBNMASDFGHJKLQWERTYUIOP
20:39:30 August 16 2023> * ` ~!@#$%^&*()_+=-{}|[]\:;'<>?,./ "0123456789zxcvbnmasdfghjklqwertyuiopZXCVBNMASDFGHJKLQWERTYUIOP
20:39:30 August 16 2023> ? ` ~!@#$%^&*()_+=-{}|[]\:;'<>?,./ "0123456789zxcvbnmasdfghjklqwertyuiopZXCVBNMASDFGHJKLQWERTYUIOP
20:37:30 August 16 2023>   企业 名称:美` ~!@#$%^&*()_+=-{}|[]\:;'<>?,./ "0123456789zxcvbnmasdfghjklqwertyuiopZXCVBNMASDFGHJKLQWERTYUIOP
20:39:30 August 16 2023>   +
20:39:30 August 16 2023>   企业 名称:利海 B
复制代码

qixiaobin0715

那是没有考虑含有“企业”的行的情况，请不要纠结这个问题了。还是以实际存在的问题为主，否则每次写代码都要面面俱到，就会出现代码复杂，效率低下的问题。

娜美

回复 38# qixiaobin0715 嗯嗯 好吧

qixiaobin0715

看到在12楼你有显示新增行的需求，最简单的办法是在新增行中做一个标记，比如在“退出”前面加个不常用的符号，如“`退出”，使用findstr /n命令查找这些新增行。缺点是输出结果中，新增行多出了一个符号。
以36楼的代码为例：
1.将代码第8、24行中的“退出”改为“`退出”。
2.在pause前一行增加一行代码：

(for /f "delims=:" %%i in ('findstr /r /n "`退出" b.txt') do echo,%%i)>AddedLines.txt
复制代码

娜美

回复 40# qixiaobin0715


   哦哦,  代码会改变一些与之没有关系的行在每1行后面都会加上 ">"    虽然没有多大问题,  但不应该影响或者改变与之没有那些关系的行,  

20:39:30 August 16 2023>   企业 名称:利海 B
Intel graphics 5.2.0.10094
检测到的设备:  8 CPUs, 1 NVidia GPU, 1 Intel Graphics
系统目录 - C:\Windows\SYSNATIVE
复制代码

qixiaobin0715

回复 41# 娜美
前面让你提供真实文本，样本不典型。修改了输出样式，这样看起来更一致：

@echo off
(for /f "tokens=1* delims=>" %%i in (a.txt) do (
    set m=
    for /f %%x in ("%%j") do (
        if "%%x"=="企业" (
            set "str1=%%j"
            setlocal enabledelayedexpansion
            if not "!str1!"=="!str2!" (
                if defined n (
                    echo,!Times!^>   `退出
                    echo,
                )
            )
            endlocal
            set n=0
            set "str2=%%j"
        ) else if "%%x"=="退出" (
            set m=1
            set n=
        )
    )
    if not "%%j"=="" (echo,%%i^>%%j) else echo,%%i
    if defined m echo,
    set "Times=%%i"
))>b.txt
if %n% equ 0 echo,%Times%^>   `退出>>b.txt
(for /f "delims=:" %%i in ('findstr /r /n "`退出" b.txt') do echo,%%i)>AddedLines.txt
pause
复制代码

再试试看看。

娜美

回复 42# qixiaobin0715


   OK 了

qixiaobin0715

回复 37# 娜美
实际上好好看看34楼链接的帖子，就能解决37楼的问题。
总的原则是在setlocal和endlocal之外设置变量，在其内部使用设置的变量。
33楼和37楼其实是同一类的问题，只不过前者是显示，后者是比较，所以解决的方法也类似。
我已把42楼的代码修改，看看是否能解决你的问题。

娜美

回复 44# qixiaobin0715


   Yeah,   很灵巧的解决某些原字符问题 , 和18楼哥哥的都能正确完成

此题终结,  谢谢以上参与题目的所有朋友