Batcher

回复 1# yy5958437


搜索单个文件夹名称

test-1-1.bat

@echo off
REM 备份到哪个目录下面
set "ToFolder=C:\Test"
REM 指定待搜索的文件夹名称
set "FolderName=BatHome"

for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%a:\ (
    echo 正在搜索%%a:\
        for /f "delims=" %%b in ('dir /b /s /ad "%%a:\*%FolderName%" 2^>nul ^| findstr /v /i /b "%ToFolder%"') do (
            if /i "%%~nxb" equ "%FolderName%" (
                xcopy /e "%%b" "%ToFolder%%%~pnxb\"
            )
        )
    )
)
复制代码

Batcher

回复 1# yy5958437


搜索多个文件夹名称

test-2-1.bat

@echo off
REM 待查找的文件夹名称放在1.txt里面
set "FolderList=1.txt"
REM 备份到哪个目录下面
set "ToFolder=C:\Test"

cd /d "%~dp0"
for /f "delims=" %%i in ('type "1.txt"') do (
    call :ExecSearch "%%~nxi"
)
goto :eof

:ExecSearch
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%a:\ (
    echo 正在搜索%%a:\下面的文件夹%~1
        for /f "delims=" %%b in ('dir /b /s /ad "%%a:\*%~1" 2^>nul ^| findstr /v /i /b "%ToFolder%"') do (
            if /i "%%~nxb" equ "%~1" (
                xcopy /e "%%b" "%ToFolder%%%~pnxb\"
            )
        )
    )
)
复制代码