77七

文件夹和文件名是否含有空格？

77七

@echo off
rem 批处理保存为ansi编码格式
cd /d "C:\Users\Administrator\Desktop\test1\"
for /f "delims=" %%a in ('type "1.txt"') do (
        setlocal enabledelayedexpansion
        for %%b in (%%a) do (
                if defined folder (
                        if exist "D:\文件数据库\%%b" (
                                copy "D:\文件数据库\%%b" "!folder!"
                        ) else (
                                >>log.txt echo %%b
                        )
                ) else (
                        set "folder=%%b"
                        md "!folder!"
                )
        )
        endlocal
)
pause
复制代码

试试行吗

77七

回复 23# feiyan


  

@echo off
rem 文本格式 "A" "1.pdf" "2.pdf"
rem 批处理保存为ansi编码格式
cd /d "C:\Users\Administrator\Desktop\test1\"
for /f "delims=" %%a in ('type "1.txt"') do (
        setlocal enabledelayedexpansion
        for %%b in (%%a) do (
                if defined folder (
                        if exist "D:\文件数据库\%%~b" (
                                copy "D:\文件数据库\%%~b" "!folder!"
                        ) else (
                                >>log.txt echo %%~b
                        )
                ) else (
                        set "folder=%%~b"
                        md "!folder!"
                )
        )
        endlocal
)
pause
复制代码

77七

回复 28# feiyan

@echo off
rem 文本格式 a|1.pdf|2*.pdf
rem 批处理保存为ansi编码格式
cd /d "C:\Users\Administrator\Desktop\test1\"
for /f "tokens=1* delims=|" %%a in ('type "1.txt"') do (
	md "%%a" 2>nul
	set "folder=%%a"
	call :1 "%%b"
)
pause & exit

	:1
	for /f "tokens=1* delims=|" %%x in ("%~1") do (
		if exist "D:\文件数据库\%%x" (
			copy "D:\文件数据库\%%x" "%folder%"
		) else (
			>>log.txt echo %%x
		)
		if "%%y" neq "" (
			call :1 "%%y"
		) else (
			exit /b
		)
	)
复制代码

77七

回复 30# feiyan


   
我刚测试了一下，代码正常，1.txt是否是代码中要求的格式？

a|1.pdf|2*.pdf
复制代码

77七

回复 33# feiyan


  

A|1*|2*|3*|
复制代码

尽量不要修改格式，虽然这样也没错，就怕把代码也随意改了，格式中包括含有空格的文件名等等，不需要加引号了。
上一个代码，我用你的格式，测试也没发现问题，
可以试试点击上一个代码的 copy 按钮 复制代码，不要选中复制。
或者试试以下的

@echo off
rem 文本格式 a|1.pdf|2*.pdf
rem 批处理保存为ansi编码格式
cd /d "C:\Users\Administrator\Desktop\test1\"
for /f "tokens=1* delims=|" %%a in ('type "1.txt"') do (
	echo 创建文件夹 "%%a"
	md "%%a" 2>nul
	set "folder=%%a"
	set "str="
	call :1 "%%b"
	echo=
)
pause & exit

	:1
	if not defined str (
		set "str=%~1"
	)
	for /f "tokens=1* delims=|" %%x in ("%str%") do (
		echo 查找文件 "%%x"
		if exist "D:\文件数据库\%%x" (
			copy "D:\文件数据库\%%x" "%folder%"
		) else (
			>>log.txt echo %%x
		)
		if "%%y" neq "" (
			set "str=%%y"
			goto :1
		) else (
			exit /b
		)
	)
复制代码

77七

回复 36# feiyan




谢谢！请以你的名义捐助到论坛吧！
http://bbs.bathome.net/thread-10403-1-1.html

77七

回复 39# feiyan


  

@echo off
rem 文本格式 a|1.pdf|2*.pdf
rem 批处理保存为ansi编码格式
cd /d "C:\Users\Administrator\Desktop\test1\"
for /f "tokens=1* delims=|" %%a in ('type "1.txt"') do (
	echo 创建文件夹 "%%a"
	md "%%a" 2>nul
	set "folder=%%a"
	set "str="
	call :1 "%%b"
	echo=
)
pause & exit

	:1
	if not defined str (
		set "str=%~1"
	)
	for /f "tokens=1* delims=|" %%x in ("%str%") do (
		echo 查找文件 "%%x"
		(for /f "delims=" %%i in ('dir /b /s /a-d "d:\文件数据库\%%x" 2^>nul') do (
			copy "%%i" "%folder%"
		)) || (
			>>log.txt echo %%x
		)
		if "%%y" neq "" (
			set "str=%%y"
			goto :1
		) else (
			exit /b
		)
	)
复制代码