[文件操作] [已解决]批处理按文件列表删除未包含的文件

maghreb

背景：
在当前目录下分别有如下文件
aaa\111.txt
aaa\222.txt
aaa\bbb\333.xyz
aaa\bbb\ddd\444.txt

在当前目录下有list.txt内容如下：
111.txt
bbb\333.xyz

请教：
如何删除list.txt列表之外的aaa文件夹(含子文件夹)下的文件？即删除不包含在此列表中的所有文件，谢谢

qixiaobin0715

当前目录中也应当有list.txt吧：

@echo off
setlocal enabledelayedexpansion
set "_list.txt=true"
for /f "delims=" %%i in (list.txt) do set "_%%i=true"
for /f "delims=" %%i in ('dir /b /s /a-d *.txt') do (
    set "str=%%i"
    set "str=!str:%~dp0=!"
    if not defined _!str! del %%i
)
pause
复制代码

未测试

maghreb

回复 2# qixiaobin0715

是的，根据当前目录下的列表文件内容保留不删文件

大侠，测试了一下，结果是aaa文件夹下的文件全删了，没保留到LIST里应该保留的文件

qixiaobin0715

回复 3# maghreb
你把测试出问题的文件夹打包传到网盘上，帮你测试一下看。

buyiyang

回复 2# qixiaobin0715


    他说的当前目录可能不是指aaa目录

qixiaobin0715

非要靠猜不可？

me78777

@echo off
rem 此bat在当前目录下
for /f %%i in ( list.txt ) do (
dir /b /s | findstr %%i >>temp.txt
)
for /f %%j in ( temp.txt ) do attrib +r %%j
del /s /q aaa\
for /f %%j in ( temp.txt ) do attrib -r %%j

pause

maghreb

回复  maghreb
你把测试出问题的文件夹打包传到网盘上，帮你测试一下看。
qixiaobin0715 发表于 2023-4-27 12:56

    不好意思大侠，我这边无论是什么格式的文件都没办法上传上来，不知道论坛是怎么回事

大概是这样的：
1、在当前目录下，有N个文件夹(包含子文件夹)，但有一个aaa文件夹；
2、每个文件夹下的文件数量不明，文件格式不明；
3、当前目录下，也就是和aaa文件夹同目录下，放置批处理文件和list.txt文件;
4、list列表里内容格式如下：
aaa\111.txt
aaa\bbb\222.txt
aaa\bbb\333.xyz
...
5、删除aaa文件夹下(注意当前目录还有其他文件夹)，未列出在list列表里的所有文件;

简洁点说，就是按列表内容，删除指定文件夹里面未包含在列表里的所有文件
很多都是按列表删除文件，我这个刚好相反，是保留列表里所列的文件

maghreb

当前目录中也应当有list.txt吧：未测试
qixiaobin0715 发表于 2023-4-27 09:41

大佬，能帮我再看看不，非常感谢

czjt1234

回复 9# maghreb


    7楼发的试过没？

maghreb

回复  maghreb


    7楼发的试过没？
czjt1234 发表于 2023-4-27 18:37

感谢，试过了，没按列表保留下来文件，是全删了

我刚弄出来了，如下：

@echo on&setlocal enabledelayedexpansion
pushd %~dp0
for /f "delims=" %%a in ('dir/ad/s/b "%cd%\aaa\*"') do (find /i list.txt "!%%a!" || rd /s /q !%%a!) >nul 2>nul
for /r "%cd%\aaa" %%a in (*.*) do (find /i list.txt "!%%a!" || del /s /q !%%a!)
pause
复制代码

感谢各位大佬的帮忙

buyiyang

回复 11# maghreb


你确定你这个代码可行？
二楼代码第七行改一下试试

set "str=!str:%~dp0aaa\=!"
复制代码

77七

回复 11# maghreb


   试试这样吧

@echo off
pushd aaa
for /f "delims=" %%a in ('type "%~dp0list.txt"') do (
	set #"%%~fa"=1
)
for /f "delims=" %%a in ('dir /b /s /a-d') do (
	if not defined #"%%~fa" (
		del "%%a"
	)
)
pause
复制代码

77七

回复 7# me78777


   修改了一下

@echo off
for /f "delims=" %%i in (list.txt) do (
	dir /b /s /a-d "aaa\*"|findstr /ic:"%%i" >>temp.txt
)
for /f "delims=" %%j in (temp.txt) do attrib +r "%%j"
del /s /q /a:-r aaa\
for /f "delims=" %%j in (temp.txt) do attrib -r "%%j"
del temp.txt
pause
复制代码

Batcher

回复 8# maghreb


如果需要上传文件，可以用阿里云盘或百度网盘。

如果需要上传截图，可以找个图床，例如：
http://bbs.bathome.net/thread-60985-1-1.html