[文本处理] 求BAT脚本批量处理多个文件，分拣成多个文件夹

asy666

求BAT脚本批量处理多个文件，分拣成多个文件夹

用途：我想整理一些有声小说，一个文件夹里有1000-3000集的小说，想把文件夹里的小说分成多个文件夹，每个文件夹里500个音频，比如（0001-0500）（0501-1000）（1001-1500）

需要按顺序分文件夹，就是第1集和第500集必须在一个文件夹里。生成的文件夹最好带标号，如（0001-0499）（0500-0999）（1000-1499）这样的格式

求大神帮忙写个代码，本人小白一个，只能求助各位大神了

最好是把脚本放进去，双击直接运行的那种，先谢谢了。

Batcher

回复 1# asy666


请截图发出来看看现在的真实文件名是怎样的？

如果需要上传截图，可以找个图床，例如：
http://bbs.bathome.net/thread-60985-1-1.html

qixiaobin0715

假设有声小说是mp3格式，看看这样有无问题，bat保存为ANSI编码：

@echo off
set m=500
set Folder=0001-0500
md "%Folder%"
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /b /a-d *.mp3') do (
    set /a n+=1
    if !n! lss !m! (
        move "%%i" "!Folder!\"
    ) else (
        move "%%i" "!Folder!\"
        set /a m+=500
        set /a n1=n+1
        set /a n2=n+500
        set n1=000!n1!
        set n2=000!n2!
        set Folder=!n1:~-4!-!n2:~-4!
        md "!Folder!
    )
)
pause
复制代码

asy666

回复 2# Batcher

原文件




想要的效果

asy666

假设有声小说是mp3格式，看看这样有无问题，bat保存为ANSI编码：
qixiaobin0715 发表于 2023-3-30 08:48

是这样的大佬，如果我想把文件夹分成（0001-0499）（0500-0999）（1000-1499）（1500-1999）这样的排序 应该怎么改，能帮我改一下吗。

还有 分拣完能比能直接自动关闭，不需要按任意键关闭

buyiyang

set /a group=500
setlocal enabledelayedexpansion
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d *.mp3') do (
      set /a n+=1
      if !n! equ 1 (set "b=%%~ni")
      xcopy "%%i" "!b!\"
      if !n! equ %group% (
            ren "!b!" "!b!-%%~ni"
            set /a n=0
            )
set "last=%%~ni"
)
ren "!b!" "!b!-%last%"
复制代码

asy666

回复 7# buyiyang


    对就是这个效果，这个能计算出最后到多少集吗？比如一共1890个音频。最后一个文件夹输出（1500-1890（完））这个的格式

terse

@echo off&setlocal enabledelayedexpansion
set md=500
for /f "delims=" %%i in ('dir /b /a-d *.mp3') do (
     set /a "i=100%%~ni%%10000/md,n=10000+i*500+^!i,m=n+499-^!i"
     set "fd=!n:~1!-!m:~1!\"
     md !fd! 2>nul
     move %%i  !fd!
)
pause
复制代码

buyiyang

setlocal enabledelayedexpansion
cd /d "%~dp0"
set /a group=500
for /f "delims=" %%i in ('dir /b /a-d *.mp3') do (
      for /f "tokens=* delims=0" %%a in ("%%~ni") do (
            set /a n=%%a%%%group%
            if !n! equ 1 (set "b=%%~ni")
            xcopy "%%i" "!b!\"
            if !n! equ 0 (ren "!b!" "!b!-%%~ni")
            )
       set "last=%%~ni"
)
ren "!b!" "!b!-%last%（完）"
复制代码

asy666

buyiyang 发表于 2023-3-31 13:54

    这个是可以的，但是 是复制的那种，分拣好以后，源文件还在那里，还是感谢大佬帮助

asy666

小改3楼代码
xp3000 发表于 2023-3-31 17:43

    这个分拣完 是这样的

是什么原因，还有就是音频里有其他格式的，比如 m4a 格式，要怎么添加进去，

大佬能帮我完善一下吗

xp3000

@echo off
REM 保存为ANSI编码的BAT
set n=0
set m=499
set Folder=0001-0499
md "%Folder%"
setlocal enabledelayedexpansion
for /f "tokens=1,* delims=:" %%a in ('dir /b /a-d /on^|findstr /n /e "\.mp3 \.m4v"') do set x=%%a
set xx=000%x%
for /f "delims=" %%i in ('dir /b /a-d /on^|findstr /e "\.mp3 \.m4v"') do (
    set /a n+=1
    if !n! lss !m! (
       move "%%i" "!Folder!\"
    ) else (
        move "%%i" "!Folder!\"
        set /a m+=500
        set /a n1=n+1
        set /a n2=n+500
        set n1=000!n1!
        set n2=000!n2!
        if !m! geq !x! (
	set Folder=!n1:~-4!-!xx:~-4!^(完^)
	) else (
	set Folder=!n1:~-4!-!n2:~-4!
	)
        md "!Folder!
    )
)
复制代码

3楼代码小改，刚开始拿700个文件测试遗漏了后面的

@echo off
REM 移动子文件夹文件到批处理文件夹
for /f "delims=" %%a in ('dir /a:d /b') do (
pushd "%%a"
for /f "delims=" %%b in ('dir /b /a-d "*.*"') do (
move "%~dp0%%a\%%~nxb" "%~dp0%%~nxb"
)
popd
rd /s /q "%%a"
)
复制代码

qixiaobin0715

回复 12# xp3000
第8、9行中的dir的用法好像有时会出现问题，如果文件夹中mp3、m4v这2种格式的文件都有，会先显示mp3文件，后显示m4v文件，而不会按照文件名的顺序。第8行括号中的命令可以这样：

dir /b /a-d /on^|findstr /n /e "\.mp3 \.m4v"
复制代码

第9行同样如此这般修改。

asy666

回复 12# xp3000


    可以了，大佬，非常的感谢，这样节省我好多时间，大佬牛逼，同时也感谢楼上的几位大佬帮忙。

asy666

回复  xp3000
第8、9行中的dir的用法好像有时会出现问题，如果文件夹中mp3、m4v这2种格式的文件都有，会先 ...
qixiaobin0715 发表于 2023-4-1 13:54

@echo off
REM 保存为ANSI编码的BAT
set n=0
set m=499
set Folder=0001-0499
md "%Folder%"
setlocal enabledelayedexpansion
for /f "tokens=1,* delims=:" %%a in ('dir /b /a-d /on^|findstr /n /e "\.mp3 \.m4a"^|findstr /n .') do set x=%%a&set xx=000%%a
for /f "delims=" %%i in ('dir /b /a-d "*.mp3" "*.m4a"') do (
    set /a n+=1
    if !n! lss !m! (
        move "%%i" "!Folder!\"
    ) else (
        move "%%i" "!Folder!\"
        set /a m+=500
        set /a n1=n+1
        set /a n2=n+500
        set n1=000!n1!
        set n2=000!n2!
        if !m! geq !x! (
	set Folder=!n1:~-4!-!xx:~-4!^(完^)
	) else (
	set Folder=!n1:~-4!-!n2:~-4!
	)
        md "!Folder!
    )
)
复制代码

我这样改了，还是会出现你说的问题。



这样的，MP3的 分拣到第一个文件夹了