[文件操作] [已解决]批处理怎么把文件夹名+文件名追加在文件内容末尾？

小小问号

需要从多个文件夹里面查找多个文件，拷贝到指定文件夹A,文件名存在test.txt，已经实现查找和复制，现在想要把文件原来路径的上一级的文件夹名加文件名追加在指定文件夹A的文件内容的末尾，求大神帮忙
现在已经获取到文件夹名和文件名，存在filename.txt   一行存一条记录如：文件夹.文件名
原来文件路径：            想要追加的内容：     追加在指定文件夹A的文件内容末尾
..\文件夹a\文件1             文件夹a.文件1              ..文件夹A\文件1
..\文件夹a\文件2             文件夹a.文件2              ..文件夹A\文件2
..\文件夹a\文件3             文件夹a.文件3              ..文件夹A\文件3
..\文件夹b\文件4             文件夹b.文件4              ..文件夹A\文件4

尝试了2种查找和复制的方法，代码如下：

#方法一
@echo@echo off
setlocal enabledelayedexpansion
set outputDir=..\文件夹A
for /f "delims=" %%a in (test.txt) do set _"%%a"=true
for /f "delims=" %%i in ('dir /s /b /a-d') do if defined _"%%~nxi" copy "%%i" "%outputDir%"

#方法二
@echo off &set "outputDir=..\文件夹A"
for /f "delims=" %%F in ('dir/s/b/a-d^|findstr /g:"test.txt" ') do (copy /y "%%~F" "%outputDir%">nul)
复制代码

77七

"现在想要把文件原来路径的上一级的文件夹名加文件名追加在指定文件夹A的文件内容的末尾。"
简言之，把名加在文件内容末尾，这如何理解...
你直接 列举操作前，和操作后的效果，这样比较好理解...

Batcher

回复 1# 小小问号

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion
set "outputDir=..\文件夹A"
for /f "delims=" %%a in (test.txt) do set _"%%a"=true
for /f "delims=" %%i in ('dir /b /s /a-d') do (
    if defined _"%%~nxi" (
        copy "%%i" "%outputDir%"
        for %%j in ("%%i\..") do (
            >>"%outputDir%\%%~nxi" echo %%~nxj.%%~nxi
        )
    )
)
复制代码

小小问号

回复 3# Batcher


    非常感谢大佬，已经实现我的需求