[注册表类] 批处理如何删除某种扩展名文件的默认关联？

5i365

网上搜索了一下, 都是创建文件类型关联的批处理, 我想删除某文件类型的关联, 即图标变成白了那种, 双击后提示让选择用什么打开
估计可能要操作注册表, 求精通注册表批处理的大侠指引, 提前感谢

holley

回复 1# 5i365
cmd下 先用assoc看一看 里面有没有你说的扩展名的关联？

5i365

回复 2# holley


   有的, 扩展名 .ps1

lancer

@echo off
title 清除文件默认打开方式
set /p ext=请输入要清除的后缀（不加.）：
 
echo.希望清除的后缀默认值：.%ext%
pause
 
rem 使用命令清除
assoc .%ext%=
 
rem 清除相关注册表项
echo.Windows Registry Editor Version 5.00>edit.reg
echo.[-HKEY_CLASSES_ROOT\.%ext%]>>edit.reg
echo.[-HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%ext%]>>edit.reg
 
start edit.reg
echo.确认导入后按任意键继续……
pause >nul
del edit.reg
 
rem 重启资源管理器
taskkill /f /im explorer.exe
start explorer.exe
复制代码

5i365

回复 4# lancer

大侠牛X, 执行成功了, 能帮看一下, 如何添加关联吗? 下面批处理是在别处找的, 不能生效
程序的完整路径如下:
"C:\Program Files\SAPIEN Technologies, Inc\PowerShell Studio 2022\PowerShell Studio.exe"

@Echo off

set "CurDir=C:\Program Files\SAPIEN Technologies, Inc\PowerShell Studio 2022"
Set Ext=ps1
Set "ProductName=PowerShell Studio"
Set Icon=0

Assoc .%Ext%=%ProductName%File

REG ADD HKCR\%ProductName%File\DefaultIcon /ve /t REG_SZ /d "%CurDir%\%ProductName%.EXE,%Icon%" /f>NUL
REG ADD HKCR\%ProductName%File\shell\open\command /ve /t REG_SZ /d "\"%CurDir%\%ProductName%.EXE\" "\"%%1\" /f>NUL
复制代码

lancer

回复 5# 5i365


    添加关联哪用批处理解决啊，直接在打开方式里选择就行了。

holley

回复 6# lancer


    我在我这边的assoc列表里没看到任何带空格的关联名称，所以你的Assoc .%Ext%=%ProductName%File 肯定是有问题的。
按我自己的理解，assoc里有.ps1=Microsoft.PowerShellScript.1的话，你只需要修改下面这里即可：

ftype Microsoft.PowerShellScript.1="%SystemRoot%\system32\WindowsPowerShell\v1.0\powershell.exe" "%1"
复制代码

实际调用程序换成你自己的。

5i365

回复 7# holley

感谢大侠指导, 稍后我试试

lancer

在Windows系统中有这样2个概念
文件扩展名
例如.exe   .doc  .docx   .xlsx   .png等等，这些事文件扩展名。

在Windows中，文件扩展名都会关联相应的文件类型，通过assoc命令可以查看该扩展名关联的文件类型。

然后文件类型会关联默认的打开程序，用ftype命令可以查看文件类型关联的打开应用程序。

所以，如果你要设置扩展名默认的打开程序，可以先用assoc查看该扩展名关联的文件类型，然后用ftype命令设置该文件类型的默认打开程序。这样操作下来就可以关联扩展名的默认打开程序了。