[其他] [已解决]批处理列出非微软签名程序

luckboy45

问题已经解决，感谢斑竹的帮助！

希望用wmic datafile实现,先读取LIST.TXT内容,然后再过滤检测签名,列出非微软签名项目

  for /f "delims=,  tokens=1,2,3,4,5" %%a in (
'wmic datafile where "name='%%i'" get "creation date"^, lastmodified^,manufacturer^,version /format:csv.xsl'
        set mycdate=%%b >nul
        set mymdate=%%c >nul
        set mymanu=%%d >nul
        set myver=%%e >nul
        set mycdate=!mycdate:~0,8!
        set mymdate=!mymdate:~0,8!
    )
    if not "!mymanu!"=="Microsoft Corporation " (
        echo [!PathName!] [!myver!,!mymanu!,!mycdate!,!mymdate!]
)
)
pause

LIST.TXT内容如下:

C:\\WINDOWS\\system32\\DRIVERS\\ACPI.sys            
C:\\WINDOWS\\system32\\drivers\\ACPIEC.sys         
C:\\WINDOWS\\system32\\drivers\\aec.sys            
C:\\WINDOWS\\system32\\drivers\\afd.sys            
C:\\WINDOWS\\system32\\drivers\\Alidevice.sys      
C:\\WINDOWS\\system32\\DRIVERS\\amdide.sys         
C:\\WINDOWS\\system32\\DRIVERS\\AmdK8.sys           
C:\\WINDOWS\\system32\\DRIVERS\\AmdLLD.sys         
C:\\WINDOWS\\system32\\DRIVERS\\asyncmac.sys        
C:\\WINDOWS\\system32\\DRIVERS\\atapi.sys           
C:\\WINDOWS\\system32\\DRIVERS\\atmarpc.sys         
C:\\WINDOWS\\system32\\DRIVERS\\audstub.sys         
C:\\WINDOWS\\system32\\drivers\\Beep.sys            
C:\\WINDOWS\\system32\\drivers\\Cdaudio.sys

希望各位帮忙下!过滤后的效果如下:

[C:\WINDOWS\system32\DRIVERS\audstub.sys    ] [ 0 ,1 ,20070914,20070914]
[C:\WINDOWS\system32\DRIVERS\dstub.sys    ] [ , ,20080713,20080415]

[ 本帖最后由 luckboy45 于 2009-11-21 18:42 编辑 ]

lxzzr

你是不是想查询系统的驱动情况？？？

luckboy45

查询的是驱动，不过貌似没人能实现哈，呵呵。

我要实现的效果是过滤非微软签名的驱动

不依靠外部工具，用WMIC实现，希望各位帮忙下！~

luckboy45

C:\\WINDOWS\\system32\\DRIVERS\\ACPI.sys            
C:\\WINDOWS\\system32\\drivers\\ACPIEC.sys         
C:\\WINDOWS\\system32\\drivers\\aec.sys            
C:\\WINDOWS\\system32\\drivers\\afd.sys            
C:\\WINDOWS\\system32\\drivers\\Alidevice.sys      
C:\\WINDOWS\\system32\\DRIVERS\\amdide.sys         
C:\\WINDOWS\\system32\\DRIVERS\\AmdK8.sys           
C:\\WINDOWS\\system32\\DRIVERS\\AmdLLD.sys         
C:\\WINDOWS\\system32\\DRIVERS\\asyncmac.sys        
C:\\WINDOWS\\system32\\DRIVERS\\atapi.sys           
C:\\WINDOWS\\system32\\DRIVERS\\atmarpc.sys         
C:\\WINDOWS\\system32\\DRIVERS\\audstub.sys         
C:\\WINDOWS\\system32\\drivers\\Beep.sys            
C:\\WINDOWS\\system32\\drivers\\Cdaudio.sys         
C:\\WINDOWS\\system32\\drivers\\Cdfs.sys            
C:\\WINDOWS\\system32\\DRIVERS\\cdrom.sys           
C:\\WINDOWS\\system32\\DRIVERS\\disk.sys            
C:\\WINDOWS\\system32\\drivers\\dmboot.sys  

LIST.TXT内容如上
我希望用FOR命令能提取出LIST.TXT的内容,并赋值给ServPath

set ServPath=%%i
for /f "tokens=2 delims==" %%a in ('wmic datafile where "Name='%ServPath%'" get Manufacturer /value') do (
  set MadeBy=%%a
)
echo.%ServPath% %MadeBy%

期待各位帮忙,我试了很多代码,都无法成功提取,都显示关闭了回显......

lxzzr

发个给你，以前在本论坛发过，现在找不到了.....

不过速度有点慢......

 
@echo off
setlocal enabledelayedexpansion
title 系统驱动情况查询
echo 初始化 ...
regsvr32 %windir%\system32\wshom.ocx /s
set "wmic_registry=wmic /namespace:\\root\default path stdregprov call"
for /f "usebackq skip=4 tokens=3 delims= " %%a in (
       `"%wmic_registry% getDWORDValue ^&H80000001,"Console","ScreenBufferSize""`
       ) do (
       set Default_size=%%a
       set Default_size=!Default_size:~0,-1!
)
if not exist %temp%\Default_size.tmp echo !Default_size!>%temp%\Default_size.tmp
%wmic_registry% SetDWORDValue ^&H80000001,"Console","ScreenBufferSize","19661100" >nul
cls
if "%1" == "h" goto :loop
mshta vbscript:createobject("wscript.shell").run("""%~nx0"" h",3)(window.close)&&exit
:loop
cls
echo.
echo.
echo.
echo.                             系统驱动情况查询                    By:lxzzr     E-mail:lxzzr@21cn.com
echo.
echo.
echo.                    
echo.
echo.
set temp_m=
set temp_n=
set temp_l=
set /p x=Please enter the filter criteria [0.State 1.Startmode x.exit]:
if %x% == x (
       rem Default_size:19660880
       set /p Default_size=<%temp%\Default_size.tmp
       %wmic_registry% SetDWORDValue ^&H80000001,"Console","ScreenBufferSize","!Default_size!" >nul
       del %temp%\Default_size.tmp /q >nul 2>nul
       exit
)
if %x% == 0 (
       set name_a=State
       set /p a=                                 [0.Stopped 1.Running]:
       if !a! == 0 set name_b=Stopped
       if !a! == 1 set name_b=Running
       goto :start_
)
if %x% == 1 (
       set name_a=startmode
       set /p b=                                 [0.Auto 1.Manual 2.Disabled 3.Boot 4.System 5.unknown]:
       if !b! == 0 set name_b=Auto
       if !b! == 1 set name_b=Manual
       if !b! == 2 set name_b=Disabled
       if !b! == 3 set name_b=Boot
       if !b! == 4 set name_b=System
       if !b! == 5 set name_b=unknown
       goto :start_
)
goto :loop
:start_
echo.
echo.
(
       del %temp%\temp.tmp
       wmic sysdriver where %name_a%='%name_b%' get name>>%temp%\temp.tmp
) >nul 2>nul
for /f %%a in ("%temp%\temp.tmp") do (
       if %%~za lss 10 (
              echo No one.
              goto :start__
       )
)
for /f "usebackq delims=" %%a in (
       `"wmic sysdriver where %name_a%='%name_b%' get name,State,startmode,pathname,ServiceType"`
       ) do (
       set /a temp_l+=1
       if !temp_l! == 1 (
              call echo.%%a    LastModified        Size      Manufacturer and Version
              for /l %%i in (1,1,150) do set/p=━<nul
       )
       if !temp_l! gtr 1 (
              for /f "tokens=1,2 delims=:." %%m in ("%%a") do (
                     set temp_m=%%m
                     set temp_n=%%n
                     set temp_m=!temp_m:~-1!
                     set driver_path_m=!temp_m!:!temp_n!.sys
                     set driver_path_wmi=!driver_path_m:\=\\!
                     for /f "delims=" %%o in ("!driver_path_m!") do (
                             set time_=%%~to
                     )
                     if defined time_ (
                             for /f "skip=1 usebackq delims=" %%p in (
                                     `"wmic datafile where name="!driver_path_wmi!" get size,Manufacturer,Version"`
                                     ) do (
                                     set Manu_=%%p
                             )
                             ) else (
                             set time_=                
                             set Manu_=                 
                     )
                     call echo.%%a    !time_!    !Manu_!
              )
       )
)
:start__
for /l %%i in (1,1,150) do set/p=━<nul
echo Done,Press any key to continue.
pause>nul
goto :loop
复制代码

lxzzr

这样吗？

@echo off
for /f "delims= " %%p in (list.txt) do wmic datafile where name="%%p" get size,Manufacturer,Version
pause
复制代码