[文本处理] 不固定位置的文本字符串如何用批处理替换？

wjhgood

有两个TXT文件，A.txt和B.txt
A中内容如下：
33333333333333
22222222222222
44444444444444
55555555555555
.........

B中内容如下：
*11*11*000*11*
3*313*3*1**101

我想用B中的每一列的不为*号的数字替换A中所有行的对应列的数字，然后输入为：
B1文件：
31131130003113
21121120002112
41141140004114
51151150005115

B2文件：
33313333133101
32313232122101
34313434144101
35313535155101

这个该如何实现呢？？
用SET的话我如何判断到底哪个为*呢！

wjhgood

哪位仁兄帮帮忙呗！！！

Seter

A中一行的每个数字都一样么?就是说会不会有12311111?

wjhgood

不一样的呢，那个我只是举例方便而已！

Seter

@echo off&setlocal enabledelayedexpansion
for /f %%i in (a.txt) do set/an+=1&set s!n!=%%i
for /f %%i in (b.txt) do set/ai+=1&set t=%%i&(for /l %%a in (1,1,!n!) do set s=&(for /l %%j in (0,1,100) do if "!t:~%%j,1!"=="*" (set s=!s!!s%%a:~%%j,1!)else set s=!s!!t:~%%j,1!)&echo !s!)>>b!i!.txt
复制代码

突然想起来*是不能直接替换的..

batman

逐字符法在遇到大文本时效率会慢得让人无法忍受，本人的思路如下:
以a.txt b.txt第一行为例,设b.txt第一行字符串为str,a.txt第一行字符串为var
而str字符串可以分为n段:丢弃段 替换段 丢弃段 替换段...丢弃段
如此var字符串就可以依上也分为n段:保留段 被替换段 保留段 替换段...保留段
输出也是n段:保留段 替换段 保留段 替换段...保留段
其他行也就同样这样处理了
由于代码尽量从效率上予以考虑,所以显得复杂,中间用了一个call+lp循环,是因为字符数是不确实的,代码如下:

@echo off
for /f "delims=" %%a in (b.txt) do (
    set "strs=%%a"&set "str=%%a"&set /a n=-1,m=0
    setlocal enabledelayedexpansion&call :lp
    for /f "delims=" %%a in (a.txt) do (
        set "var=%%a"
        for /l %%a in (1,1,!m!) do (
            for /f "tokens=1-3 delims=-" %%a in ("!_%%a!") do set "code=!%%a!"&set /p=!code:~%%b,%%c!<nul
        )
        echo.
     )
     endlocal&echo.           
)
pause>nul&goto :eof
:lp
set /a n+=1
if %n% equ 0 (
   if "%strs:~,1%" equ "*" (
      set "flag="
      ) else (
      set "flag=a"
   )
)
if "%strs:~,1%" equ "*" (
   if not defined flag (
      set /a m+=1
      set /a _!m!_1=n&set "flag=a"&set "k=var"
   )
   ) else (
   if defined flag (
      set /a m+=1
      set /a _!m!_1=n&set "flag="&set "k=str"
   )
)
set /a _%m%_2+=1&set "_%m%=%k%-!_%m%_1!-!_%m%_2!"&set "strs=%strs:~1%"
if defined strs goto lp
复制代码

[ 本帖最后由 batman 于 2009-11-11 21:54 编辑 ]

batman

原帖由 Seter 于 2009-11-11 20:37 发表
@echo off&setlocal enabledelayedexpansion
for /f %%i in (a.txt) do set/an+=1&set s!n!=%%i
for /f %%i in (b.txt) do set/ai+=1&set t=%%i&(for /l %%a in (1,1,!n!) do set s=&(for /l %%j in (0,1,100) do  ...

要是每行的字符数超过100怎么办?

wjhgood

不会超过100个的，batman版主果然牛呢！！

wjhgood

原帖由 Seter 于 2009-11-11 20:37 发表
@echo off&setlocal enabledelayedexpansion
for /f %%i in (a.txt) do set/an+=1&set s!n!=%%i
for /f %%i in (b.txt) do set/ai+=1&set t=%%i&(for /l %%a in (1,1,!n!) do set s=&(for /l %%j in (0,1,100) do  ...

这个也实现了咧，只是有点看不明白！！

terse

A.txt和B.txt每行的固定字符数？

wjhgood

恩恩，每行就是这么多个数，14位！

wjhgood

我还是不是很理解batman版主的代码呢！！

wjhgood

Seter仁兄写的代码要行数很多的话要替换好久哦！！！

batman

原帖由 wjhgood 于 2009-11-12 13:03 发表
Seter仁兄写的代码要行数很多的话要替换好久哦！！！

他用的就是逐字符替换法，不适合大文本的，这个我在前面的贴子中说明了，如果你每行的字符数是固定的话，我的代码就还可以提速。

Seter

嘿嘿...在我的位面就只能想到这种了...BATMAN一级那是神的存在啊...写出来的代码当然效率比我高咯
BATMAN的解释我看了也不是很懂,代码更是一头雾水...能否解释下?