[注册表类] 【已解决】对指定的后缀（如jpg）--右键--打开方式--出现--指定程序（如小Q画笔.exe）

yyz219

求批处理：对指定的后缀（如jpg）--右键--打开方式--出现--指定程序（如小Q画笔.exe）

flashercs

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
@REM 文件类型
set ext=.png .jpg .jpeg .bmp .gif
@REM 打开程序
set app=notepad.exe
for %%A in (%ext%) do call :foo1 %%A
endlocal
pause
exit /b

:foo1
set alpha=abcdefghijklmnopqrstuvwxyz
set valueExist=
for /f "tokens=1-2*" %%A in ('reg query "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FileExts\%~1\OpenWithList"^|find /i "REG_SZ"') do (
  if /i "%%~C"=="%app%" (
    set valueExist=1
    goto break
  )
  if /i "%%~A"=="MRUList" (
    set MRUList=%%~C
  ) else (
    set alpha=!alpha:%%~A=!
  )
)
:break
if defined valueExist goto end
set key=%alpha:~0,1%
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FileExts\%~1\OpenWithList" /v %key% /t REG_SZ /d "%app%" /f
reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\FileExts\%~1\OpenWithList" /v MRUList /t REG_SZ /d "%MRUList%%key%" /f

:end
exit /b
复制代码

yyz219

回复 2# flashercs


    我试一试先，谢谢

yyz219

回复 2# flashercs


    运行以后，*.PNG---右键--打开方式---里面没有出现记事本

yyz219

回复 2# flashercs


    另外，怎样设置多个文件类型？如：.png   .jpg  ..bmp...  ...

谢谢

xczxczxcz

你的少了一个主程序调用的注册表引用，只写了扩展的标识而矣，所以看不到，也不可用。 写上主程序调用后：偶是全是PS脚本，对你可能没用。

yyz219

回复 6# xczxczxcz


    太复杂了  谢谢

flashercs

回复 5# yyz219


    2楼已修改了

yyz219

回复 8# flashercs

好的，我再试一试，辛苦了

yyz219

回复 8# flashercs

.png .jpg不成功，其它成功，不知道原因在哪里

yyz219

回复 10# yyz219


    .png .jpg不成功，其它成功——————原因找到了：.png .jpg————打开方式对应注册表里面有太多程序，清理以后就OK