[文件操作] 如何写ffmpeg批处理将一批每集1小时左右的aac文件分割为每集20分钟的文件

tmp05

有一批每集时长为1小时的aac音频文件，请问如何写ffmpeg批处理将它们分割为每集20分钟的mp3文件，用格式工厂似乎做不到。谢谢了！
找到了这篇，https://blog.csdn.net/iteye_19045/article/details/94879577，但这是去头去尾的，而不是等量分割

Batcher

回复 1# tmp05


先找一个文件试试：
test.bat
ffmpeg.exe
in.aac
放在同一个目录下

@echo off
cd /d "%~dp0"
ffmpeg -i "in.aac" -f segment -segment_time 1200 -c copy "out_%%03d.mp3"
复制代码

tmp05

运行后是这样的：

Batcher

回复 3# tmp05

@echo off
cd /d "%~dp0"
ffmpeg -i "in.aac" -acodec libmp3lame "temp.mp3"
ffmpeg -i "temp.mp3" -f segment -segment_time 60 -c copy "out_%%03d.mp3"
复制代码

tmp05

回复  tmp05
Batcher 发表于 2022-5-23 12:05

单个文件这样可以了，但如何批量？

Batcher

回复 5# tmp05

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d *.aac') do (
    ffmpeg -i "%%i" -acodec libmp3lame "temp.mp3"
    ffmpeg -i "temp.mp3" -f segment -segment_time 60 -c copy "%%~ni_%%03d.mp3"
)
复制代码

tmp05

回复  tmp05
Batcher 发表于 2022-5-23 14:11

每次还要确认下？能否再帮完善下，谢谢

Batcher

回复 7# tmp05

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /a-d *.aac') do (
    ffmpeg -i "%%i" -acodec libmp3lame "temp.mp3" -y
    ffmpeg -i "temp.mp3" -f segment -segment_time 60 -c copy "%%~ni_%%03d.mp3"
)
复制代码

tmp05

回复 8# Batcher


    可以了，谢谢版主！另外，请问如何将每个文件三等分，而不是分成20分钟一个文件？要求有点多

tmp05

请问如何将每个文件三等分？

tmp05

有劳版主方便时帮改下语句，谢谢

flashercs

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
set splitCount=3
for /f "delims=" %%i in ('dir /b /a-d *.aac') do (
    ffmpeg -y -i "%%i" -acodec libmp3lame "temp.mp3"
    for /f "delims=" %%B in ('ffprobe -show_format -i "temp.mp3" 2^>nul^|findstr /lbic:"duration="') do (
    set %%B
  )
  set /a d=duration/splitCount+1
  ffmpeg -i "temp.mp3" -f segment -segment_time !d! -c copy "%%~ni_%%03d.mp3"
)
endlocal
复制代码

tmp05

回复 12# flashercs
执行了下，是这样的：

flashercs

回复 13# tmp05


    下载ffprobe http://bcn.bathome.net/tool/ffmpeg,4.3/ffprobe.exe

Batcher

回复 9# tmp05

@echo off
cd /d "%~dp0"
setlocal enabledelayedexpansion

set "SplitCount=3"
for /f "delims=" %%i in ('dir /b /a-d *.aac') do (
    ffmpeg -i "%%i" -acodec libmp3lame "temp.mp3" -y
    for /f "tokens=2-4 delims=:. " %%a in ('ffmpeg -i "temp.mp3" 2^>^&1 ^| find "Duration:"') do (
        call :Time2SS %%a %%b %%c
    )
    set /a SegTime=SS/SplitCount+1
    ffmpeg -i "temp.mp3" -f segment -segment_time !SegTime! -c copy "%%~ni_%%03d.mp3"
)
goto :eof

:Time2SS
set /a HH=1%1-100
set /a MM=1%2-100
set /a SS=1%3-100
set /a HH2MM=HH*60
set /a MM+=HH2MM
set /a MM2SS=MM*60
set /a SS+=MM2SS
goto :eof
复制代码