qixiaobin0715

你提的条件太多了，一次性解决不是不行，还不如分开实现。一次性解决可用：

for /f ... ('dir /b') do (
这里用if进行判断
...
)
pause
复制代码

qixiaobin0715

回复 1# smatenchen
文件和文件夹分别处理，未测试，del/rd慎用：

@echo off
for /f "delims=" %%a in ('dir /b /ad ^|findstr /vb "111 222"') do rd %%a
for /f "delims=" %%b in ('dir /b /a-d ^|findstr /ev ".ini .exe .bat"^|findstr /bv "333 444"') do del %%b
pause
复制代码

qixiaobin0715

回复 12# newswan
表达单词的起始位置和结束位置，少了一个反斜杠。
还是用^和$要严谨些，如果文件名是“abc 333.txt” 哪？

qixiaobin0715

回复 8# smatenchen
具体可以看看http://bbs.bathome.net/thread-14682-1-1.html

qixiaobin0715

回复 16# smatenchen
在代码上面已经做过说明了，未经测试。已修改，未测试。

qixiaobin0715

findstr看不明白，用if吧，这样应当看得懂吧，未测试：

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b') do (
    set "str=%%a"
    set "str1=!str:~,3!"
    set "str2=!str:~-3!"
    if "%%~xa"=="" (
        if not !str1!==111 (
            if not !str1!==222 rd "%%a"
        )
    )

    if not "%%~xa"=="" (
        if not !str2!==ini (
            if not !str2!==exe (
                if not !str2!==bat (
                    if not !str1!==333 (
                        if not !str1!==444 del %%a
                    )
                )
            )
        )
    )

)
pause
复制代码

qixiaobin0715

回复 28# smatenchen
变量参数%%a增强
扩充到一个文件扩展名：%%~xa（.txt/.doc ...等）

qixiaobin0715

回复 30# smatenchen
在引号内需转义

qixiaobin0715

回复 37# smatenchen
有时 简洁≠效率高。
5楼代码在循环体中使用了管道命令，效率就会降低。从楼上代码中受到启示，弃用管道命令，全部使用判断语句，这样效率可能要高一些：

@echo off
setlocal enabledelayed
for %%i in (333 444 .ini .exe .bat) do set _%%i=true
for %%i in (111 222) do set #%%i=true
for /f "delims=" %%i in ('dir /b /ad') do (
    set str=%%i
    if not defined #!str:~,3! rd /q /s "%%i"
)
for /f "delims=" %%i in ('dir /b /a-d') do (
    set str=%%i
    if not defined _%%~xi (
        if not defined _!str:~,3! del "%%i"
    )
)
pause
复制代码

qixiaobin0715

效率是个复杂的问题：
1.单独使用管道、单独使用命令及单独使用for循环，在效率上都没有问题，组合起来就有可能影响效率；
2.实际上40楼后2个for循环与命令dir连用也会影响效率；
40楼代码可以这样改写：

@echo off
setlocal enabledelayed
for %%i in (333 444 .ini .exe .bat) do set _%%i=true
for %%i in (111 222) do set #%%i=true
for /d %%i in (*) do (
    set str=%%i
    if not defined #!str:~,3! rd /q /s "%%i"
)
for %%i in (*) do (
    set str=%%i
    if not defined _%%~xi (
        if not defined _!str:~,3! del "%%i"
    )
)
pause
复制代码

qixiaobin0715

for /r %%a in (.,*) do（还是那句话，试试即知）
不必研究这个了。我认为是为了在一个for循环里同时得到当前文件夹下的所有文件及文件夹（包括子文件夹和其中的文件），这种用法是有缺陷的，后续处理麻烦。推荐使用：

for /f "delims=" %%a in ('dir /b /s') do ...
复制代码