[文本处理] 如何判断一个超大文本的最后一行是否为空行

随风

比如a.txt文件很大，假设有几万行，如何比较快速的判断最后一行是否是空行？

[ 本帖最后由 随风 于 2009-8-25 17:07 编辑 ]

tireless

@echo off
for /f %%a in ('^(type a.txt^&echo.^)^|find /c /v ""') do (
    for /f %%b in ('find /c /v "" ^< a.txt') do (
        if "%%a"=="%%b" (echo 不是空行) else echo 空行
    )
)
pause
复制代码

用临时文件速度快一点：

((type a.txt&echo.)|find /c /v "" & find /c /v ""<a.txt)>.temp
set /p line=<.temp
for /f "skip=1" %%a in (.temp) do (
    if "%%a"=="%line%" (echo 不是空行) else echo 空行
)
del .temp
pause
复制代码

terse

tireless兄 出手真快

@echo off
for /f %%a in ('find/c /v "" ^< a.txt') do (
   for /f %%b in ('"(type a.txt&set/p= <nul)|find/c /v """') do (
   if "%%a" neq "%%b" (echo 最后行是空行)else echo 最后行不是空行
))
pause
复制代码

随风

呵呵，对于上万行文本，速度仍是不敢恭维，继续。。。。。

zqz0012005

@echo off
more a.txt>b.txt
fc /l a.txt b.txt >nul && echo 是空行。
for %%a in (a.txt) do for %%i in (b.txt) do if %%~za==%%~zi echo 是空行
rem 可能for速度快点。
复制代码

terse

这样笨点可以不

@echo off
findstr /n .* y1.txt>b1.txt
(type y1.txt&set/p= <nul)>b2.txt
findstr /n .* b2.txt>b3.txt
for %%a in (b3.txt) do for %%b in (b1.txt) do set /a n=%%~za-%%~zb
if %n% gtr 1 (echo 空行)else echo 不是空行
del b1.txt b2.txt b3.txt
pause
复制代码

rat

@echo off
copy /b a.txt a.tmp>nul
echo a>>a.tmp
for /f %%a in ('find /c /v "" ^<a.txt') do ^
for /f %%b in ('find /c /v "" ^<a.tmp') do ^
if %%a==%%b (echo 非空行) else echo 空行
del a.tmp
pause
复制代码

随风

more 处理6万行以上的文本好像会卡住，需要按空格继续。
find /c /v "" 处理太多的行速度其实也并不快。
继续。。。继续。。。

Batcher

由空格、tab等空白字符组成的行算不算空行？

terse

SORT 好用不？

@echo off
sort a.txt>b.txt
for %%a in (a.txt) do for %%b in (b.txt) do if %%~za equ %%~zb (echo 空行)else echo 不是空行
pause
复制代码

随风

不算，

处理2百17万行文本46M，2秒。

。

[ 本帖最后由 随风 于 2009-8-26 03:01 编辑 ]

pusofalse

@echo off
findstr /v $ test.txt>nul || echo 空行
pause
复制代码

[ 本帖最后由 pusofalse 于 2009-8-26 04:52 编辑 ]

Lumiere

看代码的意思回车是不是也算行尾？

pusofalse

这是findstr的一个很实用的技巧。例如如果要计算某文本的行数可以用：

findstr /n /v $ test.txt
复制代码

但这并不适用于最后一行是空行的文本，如何判断最后一行是否为空行，思路就是这样来的。我想随风兄的代码应该也是类似于这句的吧？

随风

呵呵，不是类似，是一模一样。。。
又一次证明了findstr如果匹配的结果很少时，速度是很快的。