WHY

@echo off
setlocal enabledelayedexpansion
REM 查找png文件，其上上一级目录名为单个数字
for /f "delims=" %%i in ('dir /b /a-d /s *.png ^| findstr "\\[0-9]\\[^\\]*\\[^\\]*$"') do (
    REM 当前png所在目录
    set "curPath=%%~dpi"
    if /i "!prePath!" NEQ "!curPath!" (
        REM png文件的上上一级目录名
        for %%j in ("%%i\..\..") do set /a n = "(%%~nj + 1) * 1000 + 100001"
        if defined prePath (
            for %%j in ("!prePath!.") do (
                md "!prePath!..\..\%%~nxj" 2>nul
                move "!prePath!*.png" "!prePath!..\..\%%~nxj\"
            )
        )
    ) else (
        set /a n+=1
    )
    REM 前一个png所在目录
    set "prePath=%%~dpi"
    ren "%%i" "!n:~1!%%~xi"
)
if defined prePath (
    for %%j in ("!prePath!.") do (
        md "!prePath!..\..\%%~nxj" 2>nul
        move "!prePath!*.png" "!prePath!..\..\%%~nxj\"
    )
)
REM 删除空目录
for /f "delims=" %%i in ('dir /b /ad /s ^| sort /r') do rd "%%i" 2>nul
pause
复制代码

WHY

@echo off
setlocal enabledelayedexpansion
set /a x=0
for %%i in (attack dead hit run stand) do set  "_!x!=%%i" & set /a x+=1
REM 查找png文件，其上一级目录名为a、d、h、r、s，上上一级目录名为数字0-4
for /f "delims=" %%i in ('dir /b /a-d /s *.png ^| findstr /i "\\[0-4]\\[adhrs]\\[^\\]*$"') do (
    REM 当前png文件的上上一级目录
    for %%j in ("%%i\..\..") do set "curPath=%%~fj"
    if /i "!prePath!" NEQ "!curPath!" (
        for %%j in ("%%i\..\..") do (
            set /a n = "(%%~nj + 1) * 1000 + 1"
            set "newFolder=!_%%~nj!"
            md "%%i\..\..\..\!newFolder!" 2>nul
        )
    ) else (
        set /a n+=1
    )
    REM 前一个png文件的上上一级目录
    set "prePath=!curPath!"
    move "%%i" "%%i\..\..\..\!newFolder!\0!n!%%~xi"
)
REM 删除空目录
for /f "delims=" %%i in ('dir /b /ad /s ^| sort /r') do rd "%%i" 2>nul
pause
复制代码

WHY

描述得模模糊糊，看了好几遍才搞明白。

WHY

回复 21# miss_sokuber


    哪一条命令没正确？
脚本保存为 test.bat，编码格式选 ansi，test.bat 与 1001、1002 文件夹存放在同一级目录里面。
我测试没有问题。

WHY

回复 23# miss_sokuber


    这样试试，如果仍然不行，我放弃。

@echo off
setlocal enabledelayedexpansion
set /a x=0
for %%i in (attack dead hit run stand) do (
    set "s=%%i" & set "s=!s:~0,1!"
    set "_!x!=%%i"
    set /a x+=1, #!s!=x
)
REM 查找png文件，其上一级目录名为a、d、h、r、s，上上一级目录名为数字0-4
for /f "delims=" %%i in ('dir /b /a-d /s *.png ^| findstr /i "\\[0-4]\\[adhrs]\\[^\\]*$"') do (
    REM 当前png文件所在的目录
    set "curPath=%%~dpi"
    if /i "!prePath!" NEQ "!curPath!" (
        for %%j in ("%%i\..") do set /a n = !#%%~nj! * 1000
        REM png文件的上上一级目录
        for %%j in ("%%i\..\..") do (
            set "newFolder=!_%%~nj!"
            md "%%i\..\..\..\!newFolder!" 2>nul
        )
    ) else (
        set /a n+=1
    )
    REM 前一个png文件所在的目录
    set "prePath=%%~dpi"
    move "%%i" "%%i\..\..\..\!newFolder!\0!n!%%~xi"
)
REM 删除空目录
for /f "delims=" %%i in ('dir /b /ad /s ^| sort /r') do rd "%%i" 2>nul
pause
复制代码

WHY

回复 31# miss_sokuber


    图片命名规则：第一个字符是0，第二个字符是0,1,2,3,4这五个文件夹其中一个的名称+1，然后接3个0，最后一个字符是从0开始顺延的自然数，结果是：0（数字文件夹名称+1）0000，0（数字文件夹名称+1）0001...，
新创建文件夹命名：attack，dead，hit，run，stand，
attack包括0,1,2,3,4下面的a
dead包括0,1,2,3,4下面的d
hit包括0,1,2,3,4下面的h
run包括0,1,2,3,4下面的r
stand包括0,1,2,3,4下面的s

@echo off
setlocal enabledelayedexpansion
for %%i in (attack dead hit run stand) do (
    set "s=%%i" & set "s=!s:~0,1!"
    set "_!s!=%%i"
)
REM 查找png文件，其上一级目录名为a、d、h、r、s，上上一级目录名为数字0-4
for /f "delims=" %%i in ('dir /b /a-d /s *.png ^| findstr /i "\\[0-4]\\[adhrs]\\[^\\]*$"') do (
    REM 当前png文件所在的目录
    set "curPath=%%~dpi"
    if /i "!prePath!" NEQ "!curPath!" (
        REM png文件的上上一级目录
        for %%j in ("%%i\..\..") do set /a n = "(%%~nj + 1) * 10000"
        for %%j in ("%%i\..") do (
            set "newFolder=!_%%~nj!"
            md "%%i\..\..\..\!newFolder!" 2>nul
        )
    ) else (
        set /a n+=1
    )
    REM 前一个png文件所在的目录
    set "prePath=%%~dpi"
    move "%%i" "%%i\..\..\..\!newFolder!\0!n!%%~xi"
)
REM 删除空目录
for /f "delims=" %%i in ('dir /b /ad /s ^| sort /r') do rd "%%i" 2>nul
pause
复制代码