[注册表类] 怎么从右往左提取特定字符出现后接下来的字符串

857185187

set var=HKLM\SYSTEM\CurrentControlSet\Services\FltMgr
echo %var:*\=%
复制代码

这样能提取出从左往右出现第一个\字符后接下来的字符串SYSTEM\CurrentControlSet\Services\FltMgr
那么如果要从右往左 比如我想要得到HKLM\SYSTEM\CurrentControlSet\Services应该怎么实现？

wxyz0001

参考
http://bbs.bathome.net/viewthrea ... mp;page=1#pid203585

set var=HKLM\SYSTEM\CurrentControlSet\Services\FltMgr
for /f "tokens=1-4 delims=\" %%a in ("%var%") do (
	echo %%a\%%b\%%c\%%d
)
复制代码

pause

857185187

回复 2# wxyz0001


    如果事先不知道有几个\字符呢？

terse

@echo off
set "var=HKLM\SYSTEM\CurrentControlSet\Services\FltMgr"
for /f "delims=" %%i in ("z:%var%") do  set v=%%~pi
echo;%v:*\=%
pause
复制代码

@echo off
set "var=HKLM\SYSTEM\CurrentControlSet\Services\FltMgr"
call :s "x:%var%" v
echo;%a:*\=%
pause & exit
:s
set %2=%~p1
复制代码

857185187

回复 4# terse


    这是把字符串当作路径处理了吧,有没有纯文本的处理方法？ 比如当var=HKLM\SYSTEM\Current/ControlSet\Services\FltMgr就不能当作路径处理了

went

回复 5# 857185187

@echo off
set "key=HKLM\SYSTEM\CurrentControlSet\Services\FltMgr"
setlocal enabledelayedexpansion
set index=0
set num=0
:loop
if not "!key:~%num%,1!"=="" (
if "!key:~%num%,1!"=="\" set index=%num%
	set /a num+=1
	goto :loop
)
echo !key:~0,%index%!
pause
复制代码

terse

回复 5# 857185187

@echo off
set "key=HKLM\SYSTEM\CurrentControlSet\Services\FltMgr"
setlocal enabledelayedexpansion
set "s=!key!" & set "l=0"
for %%i in (128 64 32 16 8 4 2 1) do if "!s:~%%i!" neq "" set /a l+=%%i & set "s=!s:~%%i!"
for /l %%i in (0,1,!l!) do if "!key:~%%i,1!" == "\" set "str=!key:~,%%i!"
echo;!str!
pause
复制代码