amwfjhh

正则处理由sed来完成，故运行时请确保系统内有sed命令。

@if (0)==(0) echo off
setlocal enabledelayedexpansion

pushd %~dp0
REM 取得名称列表
set "strDict="
set "nCount=0"

set /p "strFile=请拖入处理文本:"
set "strFile=!strFile:"=!"

set "strFilter1=name=.[^^\"]*."
set "strFilter2=.*name=\"\([^^\"]*\)\".*$"
for /f "tokens=*" %%i in ('sed -n "/!strFilter1!/{s/!strFilter2!/\1/;p}" "!strFile!"') do (
	set "strTmpName=%%i"
	echo,!strDict! | findstr /i "!strTmpName!" >nul 2>nul && (
		REM 有字典存在，跳过
	) || (
		REM 无字典，添加记录
		set /a "nCount+=1"
		set "strDict=!strDict!(!strTmpName!)"
	)
)
echo,总共存在变量 !nCount! 个
set "nChar=64"
set "strRegExp="
for /l %%i in (1 1 !nCount!) do (
	set /a "nChar+=1"
	for /f "tokens=*" %%j in ('cscript -nologo -e:jscript %~s0 GetCharFromCode !nChar!') do set "strChar=%%j"
	call :_GetParm %%i
)
echo,替换变量正则表达式为 :
echo,!strRegExp!
echo,&echo,

REM 进行关键内容替换
for /f "tokens=*" %%i in ('echo,!strFile!') do set "strNewFile=%%~dpni_rep%%~xi"
>"!strNewFile!" sed "!strRegExp!" "!strFile!"
type "!strNewFile!"


pause
goto :EOF

:_GetParm
(
	for /f "tokens=%~1 delims=()" %%a in ('echo,!strDict!') do (
		echo,第 %%i 个变量 : %%a ==^> !strChar!
		set "strRegExp=!strRegExp!s/%%a/!strChar!/g;"
	)
	goto :EOF
)
@end 

var fun = WScript.Arguments(0);

switch (fun) {
	case "GetCharFromCode":
		var nChar = parseInt(WScript.Arguments(1));
		GetCharFromCode(nChar);
		break;

	default:;
}

function GetCharFromCode(nChar) {
	WScript.Echo(String.fromCharCode(nChar));
}
复制代码

amwfjhh

回复 8# smss


    就是单个sed.exe程序，论坛也能搜得到。很好下载的。玩批处理的或多或少都要用到正则表达式，各种语言中也有支持的，不过支持的程度不一样，sed是对正则支持比较全面的一个工具了。
下载下来后直接放到批处理同级目录即可调用，或者将其拷到系统PATH路径下（比如c:\windows)，则任意目录下都可以调用它。

amwfjhh

回复 11# smss


    嗯，无所谓，不同的实现方式，WHY兄用powershell，本身对各种对象支持就要好些，写出的代码也更简捷，而且代码中正则表达式过滤条件也要好些，没毛病。

amwfjhh

回复 14# 523066680


    python?

amwfjhh

回复 56# netbenton


    代码风格看着舒服…