Batcher

回复 3# Wedy


    在你给的这段样本数据里面哪几位数字表示年份？

Batcher

回复 5# Wedy

@echo off
setlocal enabledelayedexpansion
set "NewFolder=处理结果"
if not exist "%NewFolder%" (
    md "%NewFolder%"
)
for %%x in (*.txt) do (
    (for /f "tokens=1* delims==" %%a in ('type "%%x"') do (
        set "RawKey=%%a"
        set "TrimKey=!RawKey: =!"
        if "!TrimKey!" equ "birth" (
            call :ChangeYear "%%~a" "%%~b"
        ) else if "!TrimKey!" equ "death" (
            call :ChangeYear "%%~a" "%%~b"
        ) else if "x%%b" neq "x" (
            echo %%a=%%b
        ) else (
            echo %%a
        )
    ))>"%NewFolder%\%%x.txt"
)
goto :eof

:ChangeYear
for /f "tokens=1* delims=." %%h in ("%~2") do (
    set /a CalcYear=%%h+2697
    echo %~1="!CalcYear!.%%i"
)
goto :eof
复制代码

Batcher

回复 8# Wedy


编码问题稍后再说，先试试能否处理人物的时间格式：

@echo off
setlocal enabledelayedexpansion
set "NewFolder=处理结果"
if not exist "%NewFolder%" (
    md "%NewFolder%"
)
for %%x in (*.txt) do (
    (for /f "tokens=1* delims==" %%a in ('type "%%x"') do (
        set "RawKey=%%a"
        set "TrimKey=!RawKey: =!"
        if "%%b" equ "{" (
            for /f "tokens=1* delims=." %%e in ("%%a") do (
                if "x%%f" neq "x" (
                    call :ChangeKey %%a
                ) else (
                    echo %%a=%%b
                )
            )
        ) else if "!TrimKey!" equ "birth" (
            call :ChangeValue "%%~a" "%%~b"
        ) else if "!TrimKey!" equ "death" (
            call :ChangeValue "%%~a" "%%~b"
        ) else if "x%%b" neq "x" (
            echo %%a=%%b
        ) else (
            echo %%a
        )
    ))>"%NewFolder%\%%x"
)
goto :eof

:ChangeKey
for /f "tokens=1* delims=." %%h in ("%~1") do (
    set /a CalcYear=%%h+2697
    echo   !CalcYear!.%%i={
)
goto :eof

:ChangeValue
for /f "tokens=1* delims=." %%h in ("%~2") do (
    set /a CalcYear=%%h+2697
    echo %~1="!CalcYear!.%%i"
)
goto :eof
复制代码

Batcher

回复 10# Wedy


    你先试试手工把原始文件转成ANSI编码格式，再执行批处理，还会出现这个乱码问题吗？

Batcher

回复 13# Wedy

@echo off
setlocal enabledelayedexpansion
set "NewFolder=处理结果"
if not exist "%NewFolder%" (
    md "%NewFolder%"
)
for %%x in (*.txt) do (
    (for /f "tokens=1* delims==" %%a in ('type "%%x"') do (
        set "RawKey=%%a"
        set "TrimKey=!RawKey: =!"
        set "CheckCurly=%%b"
        if "!CheckCurly:~0,1!" equ "{" (
            for /f "tokens=1* delims=." %%e in ("%%a") do (
                if "x%%f" neq "x" (
                    call :ChangeKey "%%a" "%%b"
                ) else (
                    echo %%a=%%b
                )
            )
        ) else if "!TrimKey!" equ "birth" (
            call :ChangeValue "%%~a" "%%~b"
        ) else if "!TrimKey!" equ "death" (
            call :ChangeValue "%%~a" "%%~b"
        ) else if "x%%b" neq "x" (
            echo %%a=%%b
        ) else (
            echo %%a
        )
    ))>"%NewFolder%\%%x"
)
goto :eof

:ChangeKey
for /f "tokens=1* delims=." %%h in ("%~1") do (
    set /a CalcYear=%%h+2697
    echo   !CalcYear!.%%i=%~2
)
goto :eof

:ChangeValue
for /f "tokens=1* delims=." %%h in ("%~2") do (
    set /a CalcYear=%%h+2697
    echo %~1="!CalcYear!.%%i"
)
goto :eof
复制代码

Batcher

回复 14# Wedy

公元1年的时间貌似都没转成功

你给个测试用例，我试试看。

(我来问之前特别去看了下正则表达式"[-]{0,1}[0-9]{3}[1-9]|[0-9]{2}[1-9][0-9]{1}|[0-9]{1}[1-9][0-9]{2}|[1-9][0-9]{3}"，不知道这个不能用在批处理中吗？

findstr命令不支持这种复杂的正则，需要引入第三方命令才行。