批处理产生001到999之间的数字

novaa

如下
001
002
003
...
999

唯尘

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 999) do (
        set var=00%%i
        set var=!var:~-3!
        echo !var!
)
pause>nul

唯尘

for /l %%i in (1 1 999) do (set var=000%%i&call echo %%var:~-3%%)

唯尘

@echo off
for /l %%i in (1 1 999) do (set var=00%%i && call echo %%var:~-4%%)
pause

唯尘

@echo off
for /l %%i in (1 1 999) do (
        set "var=00%%i"
        call echo %%var:~-3%%
)
pause>nul

唯尘

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1 1 999) do (
        set var=00%%i
        echo !var:~-3!
)
pause>nul

唯尘

@echo off
setlocal enabledelayedexpansion
for /l %%i in (1001,1,1999) do (
        set var=%%i
        echo !var:~1!
)
pause

cmderr

回复 1# novaa

@echo off
set a=1
set b=10
set c=100
:loop1
echo 00%a%
set /a a=%a%+1
if "%a%"=="9" goto loop2
:loop2
echo 0%b%
set /a b=%b%+1
if "b"=="99" goto loop3
:loop3
echo %c%
set /a c=%c%+1
if "%c%"=="999" goto pause
:pause
pause>nul
复制代码

Gin_Q

@ECHO OFf&title by author Gan&rem 9:37 2019/9/29

setlocal enabledelayedexpansion
(for /l %%a in (0,1,999) do (set nu1=%%a
if !nu1! lss 100 ( set nu1=00!nu1!&echo !nu1:~-3!)else echo %%a
))>result.txt
pause

impk

@echo off
for /l %%i in ( 001 1 999 ) do echo %%i
复制代码

懒虫阿布

@echo off
for /l %%i in (1, 1, 999) do (
	if %%i LSS 10 (
		echo 00%%i
	) else if %%i LSS 100 (
		echo 0%%i
	) else (
		echo %%i
	)
)
复制代码

wtuldn

@echo off
setlocal enabledelayedexpansion
for /l %%a in (1,1,999) do (
set n=%%a
if !n! lss 10 (
set n=0!n!
  )
if !n! lss 100 (
set n=0!n!
)
echo !n!
)
pause

yhcfsr

@echo off
:eo
cls
echo %random:~-1%%random:~-1%%random:~-1%
pause
goto :eo
复制代码

不记得参考论坛哪位大神思维了。

老刘1号

@Echo off
for /l %%a in (0 1 9) do ^
for /l %%b in (0 1 9) do ^
for /l %%c in (0 1 9) do ^
Echo %%a%%b%%c
Pause
复制代码

/zhqsystem/zhq

低语言代码优化:

@echo off
call:1 999
pause
exit
:1
set "n=-1"
:2
set/a "n+=1"
set "m=0000000000%n%"
echo,%m:~-3%
if %n%==%* goto:eof
goto:2
复制代码