[文本处理] 批处理如何去掉字符串两边的空格

胡子轩

想写一个可以去掉字符串两边空格的批处理,做为函数调用,可是却不知从何下手
请诸位帮忙.......
如 set "str=    abc d  "
结果为
"str=abc d"

[ 本帖最后由 胡子轩 于 2008-1-3 09:55 编辑 ]

youxi01

当然，可以用if来检测。
但是因为受 联盟里 3742版主的影响，不太喜欢if，所以尽量不用...
测试代码：

@echo off
set "str=    abc   df  fd       d     "
for /f "tokens=* delims= " %%i in ("%str%") do set "str=%%i"
set str=%str: = # %
call :Rev "%str%"
for /f "tokens=* delims=#" %%i in ("%Res%") do set "str=%%i"
set "str=%str:#= # %"
call :Rev "%str%"
echo "%Res:#= %"
pause>nul
:Rev str
set "Res="
for %%i in (%~1) do call set Res=%%i%%Res%%
复制代码

ieutk

我来一个if的

@echo off
set "str=    abc d  "
for /f "tokens=* delims= " %%a in ("%str%") do (
        set "var=%%a"
        call :ie
    )
echo.
echo  去除空格前:  [%str%]
echo.
echo  去除空格后:  [%var%]
echo.
pause&goto :eof


:ie
if "%var:~-1%"==" " (set "var=%var:~0,-1%"&goto ie) else goto :eof
复制代码

youxi01

呵呵，楼上的不错，先通过for循环消除开头的 空格，然后用if来检测(个人不太喜欢)...
也有几点建议：
1、标签中的变量设置不甚恰当。
程序中的var变量在这里最好放到标签:ie里，特别是比较长的程序的话，你就知道好处了。
2、那个else似乎没什么用处。
改成以下代码是否好点呢？

@echo off
set "str=    abc d  "
for /f "tokens=* delims= " %%a in ("%str%") do call :ie "%%a"
echo.
echo  去除空格前:  [%str%]
echo.
echo  去除空格后:  [%var%]
echo.
pause&goto :eof

:ie str 
set "var=%~1"
if "%var:~-1%"==" "  call :ie "%var:~0,-1%"
复制代码

ieutk

呵呵，楼上的不错，先通过for循环消除开头的 空格，然后用if来检测(个人不太喜欢)...
也有几点建议：
1、标签中的变量设置不甚恰当。
程序中的var变量在这里最好放到标签:ie里，特别是比较长的程序的话，你就知道好处了。
2、那个else似乎没什么用处。
改成以下代码是否好点呢？

谢谢提点,确实,那个变量var放在子标签中很好,"程序"归"程序","函数"归"函数".

我个人也很喜欢用"函数"的方式来编写代码,再者水平有限,编写不出什么大型

的脚本,所以在这些方面有所忽略.

if "%var:~-1%"==" "  call :ie "%var:~0,-1%"
复制代码

你这一行代码以前没有看到这种用法,现在才知道,学习ing. . .

novaa

学习了。
@echo off
set "str=    abc   df  fd       d     "
for /f "tokens=* delims= " %%i in ("%str%") do set "str=%%i"
echo %str%
这里的是abc   df  fd       d  
不是去掉空格了吗？

youxi01

呵呵，你这个其实 还没去掉d后面的空格的///

ieutk

No,非也,6楼请仔细看咯,d后面还有空格呢,只是看不到而己,看下面代码,用括号括起来就方便看了

@echo off
set "str=    abc   df  fd       d     "
for /f "tokens=* delims= " %%i in ("%str%") do set "str=%%i"
echo [%str%]
pause
复制代码

[ 本帖最后由 ieutk 于 2008-1-2 23:09 编辑 ]

namejm

　　转一下以前写的代码：

　　去掉左侧空格1：

@echo off
set "str=   ab c&>!   " 
for /f "tokens=*" %%i in ("%str%") do echo "☆%%i☆"
pause
复制代码

　　去掉左侧空格2：

@echo off
set "str=   ab c&>!   " 
:intercept
if "%str:~0,1%"==" " set "str=%str:~1%"&goto intercept
echo "☆%str%☆"
pause
复制代码

　　去掉右侧空格1：

@echo off
set "str=   ab c&>!   " 
for /f "delims=" %%i in ("%str%") do echo "☆%%~nxi☆"
pause
复制代码

　　去掉右侧空格2：

@echo off
set "str=   ab c&>!   " 
:intercept
if "%str:~-1%"==" " set "str=%str:~0,-1%"&goto intercept
echo "☆%str%☆"
pause
复制代码

　　去掉首尾空格1：

@echo off
set "str=   ab c&>!   " 
for /f "tokens=*" %%i in ("%str%") do echo "☆%%~nxi☆"
pause
复制代码

　　去掉首尾空格2：

@echo off
set "str=   ab c&>!   " 

:intercept_left
if "%str:~0,1%"==" " set "str=%str:~1%"&goto intercept_left

:intercept_right
if "%str:~-1%"==" " set "str=%str:~0,-1%"&goto intercept_right
echo "☆%str%☆"
pause
复制代码

　　去掉所有空格：

@echo off
set "str=   ab c&>!   " 
set "str=%str: =%"
echo "☆%str%☆"
pause
复制代码

　　以上代码能兼容除双引号外的其他特殊字符。

youxi01

呵呵，这个以前就拜读过了,只是当初没太注意，也没去想原理；原来蛮有应用价值的嘛！
精品就是精品啊，哈哈!!

ieutk

namejm出手必属精品

随风

也来个不能显示特殊字符,
去除首尾空格
:

@echo off
set "str=   ab     c    "
call :lis %str%
pause
:lis
echo ☆%*☆
goto :eof
复制代码

youxi01

好,值得加分!!
在联盟qw版主写的 数字排序 程序里出现过这种用法:%*

youxi01

对于楼上的 namejm 和 随风 兄弟的代码,应该来说，可以比较好的解决楼主的问题,但是也有瑕疵:
1、随风兄弟的现行代码 无法处理 特殊字符；
2、namejm的代码：

@echo off
set "str=   ab c&>!   " 
for /f "tokens=*" %%i in ("%str%") do echo "☆%%~nxi☆"
pause
复制代码

namejm的代码是利用了CMD对文件路径、文件名的“解析漏洞”很好的去掉了字符串首尾两端的空格，但是还存在一些小问题，测试代码：

@echo off
set "str=   ab\ c&>!  .  " 
for /f "tokens=*" %%i in ("%str%") do echo "☆%%~nxi☆"
pause
复制代码

运行结果会抛弃"ab"和"."
呵呵，欢迎大家继续讨论！

随风

极其臃肿.
:

@echo off
set "str=   a\b c&>! .  "
call :lis
set flag=1
:lis
set var=
for /l %%i in (1 1 100) do (
   if defined str (
   call set "var=%%var%%%%str:~-1%%"
   call set "str=%%str:~0,-1%%"
))
set "str=%var%"
for /f "tokens=*" %%a in ("%str%") do set "str=%%a"
if not defined flag goto :eof
echo "%str%"
pause
复制代码

...