batman

效率不高，先发了：

@echo off&setlocal enabledelayedexpansion
set /p a=请输入一个大于6的偶数：
for /l %%a in (2,1,%a%) do set /a b=%%a/2+1&call :lp %%a
set "str=#2#%str%"
echo 1-%a%中所有的素数为：%str:#=%
for %%a in (%str%) do (
    set "var=!str: %%a=!"
    for %%b in (!var!) do (
        set "d=%%a"&set "d=!d:#=!"
        set "e=%%b"&set "e=!e:#=!"
        set /a num=d+e
        if %a% equ !num! echo %a%=!d!+!e!&goto next
    )
)
:next
pause>nul&goto :eof
:lp
for /l %%a in (2,1,%b%) do (
    set /a c=%1%%%%a
    if !c! equ 0 goto :eof
)
set str=%str% #%1#
复制代码

思路：
    先获取2-输入的偶数中的所有素数，然后再对素数进行两两相加，如和等于输入数就输出结果。

[ 本帖最后由 batman 于 2009-4-24 22:41 编辑 ]

batman

来个高效点的：

@echo off&setlocal enabledelayedexpansion
set /p a=请输入一个大于6的偶数：
for /l %%a in (3,1,%a%) do (
    set /a b=a-%%a,n=0&call :lp %%a !b!
    if !n! equ 2 echo %a%=%%a+!b!&goto next
)
:next
pause>nul&goto :eof 
:lp
set /a c=%1/2+1
for /l %%a in (2,1,%c%) do (
    set /a d=%1%%%%a
    if !d! equ 0 goto :eof
)
set /a n+=1
if "%2" neq "" shift&goto lp
复制代码

batman

修改我楼上的，用位运算取得数的平方根近似值，以减少循环次数：

@echo off&setlocal enabledelayedexpansion
rem write by batman on 2009-4-25 15:51 of bbs.bathome.net
set /p a=请输入一个大于6的偶数：
set "t=%time:~,-3%"
for /l %%a in (3,2,%a%) do (
    set /a b=a-%%a,n=0&call :lp %%a !b!
    if !n! equ 2 (
       echo 开始时间：%t% 结束时间：!time:~,-3!
       echo %a%=%%a+!b!&goto next
    )
)
:next
pause>nul&goto :eof 
:lp
for /l %%a in (1,1,30) do (
     set /a "num=2<<%%a",yu=%%a%%2
     if %%a equ 30 set /a "num=~num"
     if !num! geq %1 set /a "c=2<<%%a/2+yu"&goto loop
)
:loop
for /l %%a in (3,2,%c%) do (
     if %%a neq %1 set /a d=%1%%%%a
     if !d! equ 0 goto :eof
)
set /a n+=1
if "%2" neq "" shift&goto lp
复制代码

batman

应该我楼上的效率到了极限了。。。。如此我认为，再怎么高效地构建素数表，都只是做了无用功。

[ 本帖最后由 batman 于 2009-4-25 17:55 编辑 ]

batman

回lhjoanna版主，可能是我的言语没有注意，还请兄弟原谅。但对于超大数来讲，要构建素数表，永远都会存在效率问题，这就
是我的本意。

batman

思路：利用牛顿迭代法快速求出数的平方根近似值，从而最大程度上减少循环次数，算法如下：
    首先我们设要求的这个数为a，它的平方根为x；然后我们一开始令x=a；然后我们进入一个
循环，不断的令x=(x+a/x)/2，就是令x等于 x和a/x的平均值，这样迭代了10次左右就可以得到a
的平方根x的近似值。
因此将本人12楼的代码再次提速如下：

@echo off&setlocal enabledelayedexpansion
rem write by batman on 2009-4-26 3:20 of bbs.bathome.net
set /p a=请输入一个大于6的偶数：
set "t=%time:~,-3%"
for /l %%a in (3,2,%a%) do (
    set /a b=a-%%a,n=0,c=a&call :lp %%a !b!
    if !n! equ 2 (
       echo 开始时间：%t% 结束时间：!time:~,-3!
       echo %a%=%%a+!b!&goto next
    )
)
:next
pause>nul&goto :eof 
:lp
for /l %%a in (1,1,10) do set /a c=(c+a/c)/2
for /l %%a in (3,2,%c%) do (
     if %%a neq %1 set /a d=%1%%%%a
     if !d! equ 0 goto :eof
)
set /a n+=1
if "%2" neq "" shift&goto lp
复制代码

[ 本帖最后由 batman 于 2009-4-26 03:29 编辑 ]