aa77dd@163.com

回复 3# CrLf

大冬天的, 木太阳, 更难看到彩虹啊



.................................................................................................................................................................
.................................................................................................................................................................................
..........................................................................................................................................................................................
....................................................................................................................................................................................................
.........................................................................................................................................................................................................
................................................................................................................................................................................................................
.....................................................................................................................................................................................................................
...........................................................................................................................................................................................................................
...............................................................................................................................................................................................................................
...................................................................................................................................................................................................................................
.......................................................................................................................................................................................................................................
...........................................................................................................................................................................................................................................
..............................................................................................................................................................................................................................................
.................................................................................................................................................................................................................................................
....................................................................................................................................................................................................................................................
.......................................................................................................................................................................................................................................................
.........................................................................................................................................................................................................................................................
............................................................................................................................................................................................................................................................
.............................................................................................................................................................................................................................................................




无聊弄一 cmd 生成 Discuz 彩虹代码

@echo off & title discuz_RAINBOW_CODE_gen_彩虹代码生成器.cmd
setlocal enableDelayedExpansion

set "pnt="
set /a "sum=0"
for %%a in (00 2A 54 7E A8 D2 FC) do (
    if not "!pnt!"=="" (
        set "P!pnt!=%%a"
        set "N%%a=!pnt!"
    )
    set "pnt=%%a"
    set /a "sum+=1"
)
set /a "sumColor = (sum - 1) * 5 + 1"

set        "R=FC"
set        "G=00"
set        "B=00"

set       "co=RGB"
set  "ALLMODE=PN"
set     "mode=P"
set    "bound=PFCN00"
set   "act_ci=1"

set   "act_ci=2"
set        "B=2A"
set     "mode=N"

REM 行,列间距比
set "r_R2C=14 / 4"
set "r_C2R=4 / 14"

set /a "top_compensation = 0"
set /a "thick = sumColor * %r_R2C%, rad = thick * 2 / 8, t = (rad_max = thick + rad) + 1, r_sq_max = t * t + top_compensation"
set /a "margin = 2, wid = (rad_max + margin) * 2, hei = rad_max * 1 / 2, L_hei = hei * %r_C2R%, xc = wid / 2, yc = rad_max + margin"

>discuz_RAINBOW_CODE_彩虹代码.txt cd.

set /a "radius=rad_max"
for /L %%i in (1 1 %sumColor%) do (

    for %%j in (!act_ci!) do set "act_c=!co:~%%j,1!"
    for %%c in (!act_c!)  do set "cv=!%%c!"

    for %%m in (!mode!!cv!) do if /i not "!bound:%%m=!"=="%bound%" (

        for %%n in (!mode!) do set "mode=!ALLMODE:%%n=!"
        set /a "act_ci = (act_ci - 1) %% 3"
        for %%j in (!act_ci!) do set "act_c=!co:~%%j,1!"
        for %%c in (!act_c!) do set "cv=!%%c!"
    )

    for /f "tokens=1-2" %%a in ("!mode! !cv!") do set "!act_c!=!%%a%%b!"

    set /a "@%%i = r_sq_min = radius * radius, radius -= 1"

    if %%i equ 15 set /a "@15 += 0" & rem 紫区补偿

    set "C_!@%%i!=!R!!G!!B!"
)

set r_sq
set C_
set @

set "exp=0"
for /L %%i in (%sumColor% -1 1) do (
    set "exp=t=x-@%%i>>31,~t&@%%i|t&(!exp!)"
)
set exp

for /L %%y in (0 1 !L_hei!) do (

    set "wh="

    for /L %%x in (0 1 !wid!) do (

        set /a "dx = %%x - xc, dy = (%%y * %r_R2C%) - yc, sq_d = dx * dx + dy * dy"

        set "c="
        if !sq_d! lss !r_sq_min! (
            set "c=white"
        ) else if !sq_d! geq !r_sq_max! (
            set "c=white"
        )

        if not "!c!"=="white" (
            set /a "x=sq_d,cpnt=(%exp%)"
            for %%p in (!cpnt!) do set "c=#!C_%%p!"

            if not "!wh!"=="" (
                >>discuz_RAINBOW_CODE_彩虹代码.txt <nul set /p "=[color=white]!wh![/color]"
            )
            >>discuz_RAINBOW_CODE_彩虹代码.txt <nul set /p "=[color=!c!].[/color]"

            REM >>discuz_RAINBOW_CODE_彩虹代码.txt <nul set /p "=!sq_d!/!c! "

            set "wh="
        ) else (
            set "wh=!wh!."
        )
    )

    REM if not "!wh!"=="" (
        REM 最后的空白可省略
        REM >>discuz_RAINBOW_CODE_彩虹代码.txt <nul set /p "=[color=white]!wh![/color]"
    REM )

    >>discuz_RAINBOW_CODE_彩虹代码.txt echo;
)

start "" discuz_RAINBOW_CODE_彩虹代码.txt
pause

exit
复制代码