WHY

@echo off
set "s=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
for /f "tokens=2*" %%i in ('reg query "%s%" /v Desktop') do (
    set "Desktop=%%j"
)
for /f %%i in ('wmic os get LocalDateTime^|findstr /b [0-9]') do (
    set "Today=%%i"
)

set "Today=%Today:~0,8%"
md "%Desktop%\归档\%Today%\" 2>nul

set "MyPath=%Desktop:~2%\"
set wql=where "drive='%Desktop:~0,2%' and path='%MyPath:\=\\%'"
for /f "tokens=1*" %%i in ('wmic datafile %wql% get creationdate^,name^|findstr /b %Today%')do (
    for /f "delims=" %%j in ("%%j") do (
        if /i not "%%~fj" == "%~f0" move "%%~fj" "%Desktop%\归档\%Today%\"
    )
)
pause
复制代码

WHY

回复 15# erjnasrtnws


    把14行改成

set wql=where "drive='%Desktop:~0,2%' and path='%MyPath:\=\\%' and extension!='LNK'"
复制代码

WHY

回复 17# erjnasrtnws


    顶楼并没有这种要求啊，3楼的代码我没有试，以下代码不知道是不是你想要的：

@echo off
set "s=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
for /f "tokens=2*" %%i in ('reg query "%s%" /v Desktop') do (
    set "Desktop=%%j"
)

set "MyPath=%Desktop:~2%\"
set wql=where "drive='%Desktop:~0,2%' and path='%MyPath:\=\\%' and extension!='LNK'"
(for /f "tokens=1*" %%i in ('wmic datafile %wql% get creationdate^,name^|find "\"') do (
    set "D=%%i"
    setlocal enabledelayedexpansion
    for %%k in ("%Desktop%\归档\!D:~0,8!") do (
        endlocal
        for /f "delims=" %%j in ("%%j") do (
            if /i not "%%~fj" == "%~f0" (
                md "%%~k\"
                move "%%~fj" "%%~k\"
            )
        )
    )
)) 2>nul
复制代码

WHY

回复 20# erjnasrtnws


    14楼的意思是，把桌面上今天（2015/11/26）创建的文件移动到 桌面\归档\20151126 文件夹中，这也是你在顶楼要求的

18楼的意思是，把桌面上除LNK快捷方式和批处理自身以外的文件移动到“桌面\归档\以文件创建日期命名”的文件夹中。之所以出现两个以日期命名的文件夹，是因为有两种不同日期创建的文件