尘丶

回复 15# 228630386

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b /s *.jpg') do (
    if not %%~na equ 1 if not %%~na equ 2 if not %%~na equ 3 if not %%~na equ 4 if not %%~na equ 5 if not %%~na 

equ 7 if not %%~na equ 15 if not %%~na equ 16 (
    set "str=%%~dpa"
    set "str=!str:~0,-1!"
    for /f "delims=" %%b in ("!str!") do set str2=%%~nb
    md e:\描述图读取\测试文件\!str2! >nul 2>nul
    copy "%%a" e:\描述图读取\测试文件\!str2!
 )
)
pause
复制代码

这样？ 不是的话你把文件和要求一起存起来 发个链接出来。

228630386

回复 16# 尘丶


    "测试文件" 只是一个文件夹名，能否换成其它文件夹名也能自动生成，这个文件名不是固定的，可能我表达得不太好。

尘丶

文件名随机吗？ 随机的话有没啥规律举个例子看看可以做不
发效果图

228630386

回复 18# 尘丶


    就是假如这些文件里面，我把命令放到这些文件夹中提取，这些文件中还有多个子文件夹，我需要提取有除了1、2、3、4、5、7、15、16图以外的图片
　 我就是想保留主目录的名称。

228630386

回复 18# 尘丶


就好像这个命令，可以保留文件夹名称的，但我又知道怎么改才行，显示命令错误的。前面的命令可以无视，这只是个例子。

pcl_test

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ("%cd%") do set "f=%%~na"
set "t=\\1.jpg \\2.jpg \\3.jpg \\4.jpg \\5.jpg \\7.jpg \\15.jpg \\16.jpg"
for /f "delims=" %%b in ('dir /a-d /b /s *.jpg^|findstr /iev "%t%"') do (
    set "p=%%~dpb"
    set "p=!p:%cd%\=!"
    xcopy "%%b" "E:\描述图提取\%f%\!p!" /y
)
pause
复制代码

228630386

回复 21# pcl_test


    非常感谢，又一次帮到我了，真心谢谢各位大侠！！！

228630386

回复 21# pcl_test

亲，又遇到一个新问题了，因为文件名有日期排在前面的，但建出来的文件名只有 "9"，
是否类似以下格式的文件名不可以实现完整一模一样的命名？

9.16【图片】天线宝宝衣服专场 五区 192款 业务部 张三（合格98款）

pcl_test

回复 23# 228630386

修改for /f "delims=" %%a in ("%cd%") do set "f=%%~nxa"


另一种方式

@echo off
for /f "delims=" %%a in ("%cd%") do set "f=%%~nxa"
set "t=\\1.jpg \\2.jpg \\3.jpg \\4.jpg \\5.jpg \\7.jpg \\15.jpg \\16.jpg"
for /f "delims=" %%b in ('findstr /ms .* *.jpg^|findstr /iev "%t%"') do (
    echo;f|xcopy "%cd%\%%b" "E:\描述图提取\%f%\%%b" /y
)
pause
复制代码

228630386

回复 24# pcl_test


    命令真的很多变，好强大，可以了，非常感谢！

terse

加个参数呢
另 用 FINDSTR   ”\ “ 要转义

@echo off
for /f "delims=" %%a in ("%cd%") do set "f=%%~na"
(for %%i in (1,2,3,4,5,7,15,16) do echo;\%%i.jpg)>"$"
xcopy *.jpg "E:\描述图提取\%f%\" /e /y /s /EXCLUDE:$
del $
pause
复制代码

flyinnet9

/EXCLUDE参数会排除所有包含字符串的文件，

例如$中含字符串1.jpg，则1.jpg、11.jpg、21.jpg等等都在排除之列

pcl_test

回复 27# flyinnet9

echo;\%%i.jpg)>"$" 已做了限定

flyinnet9

回复 28# pcl_test


    哈哈，我还是不够仔细