pcl_test

VBS

Dim fso,File1,File2,File3,MyArray(),arr
Set fso = CreateObject("Scripting.FileSystemObject")
Set File1= fso.OpenTextFile(".\$DG.txt", 1 , True)
Set File2= fso.OpenTextFile(".\NEW_DG.txt", 1 , True)
Set File3 = fso.CreateTextFile(".\结果.txt", 2 ,False) 
i=0
s=""
Do While File1.AtEndOfStream <> True 
ReDim Preserve MyArray(i)
MyArray(i)=File1.ReadLine
i=i+1
Loop
File1.Close
Do While File2.AtEndOfStream <> True
t=File2.ReadLine
For j=0 To UBound(MyArray)
arr=Split(MyArray(j),"	")
If t = arr(0) Then
s=s&MyArray(j)&vbCrLf
End If
Next
Loop
File3.WriteLine s
File2.Close
File3.Close
Msgbox "完成"
复制代码

pcl_test

回复 6# 回家路上

你的思路跟我之前的vbs代码的是一样的，用NEW_DG.txt每行去遍历匹配$DG.txt，这样效率自然是慢的，批处理的话有个灵活好用的“变量表”机制，可充当“临时文件”来储存数据，要取某个数据时只要扩展相应的变量名即可，这样就可以避免多次的重复动作，看你新发的帖子里的代码，群友们提供的思路就是如此，通过后期学习也可了解到vbs中也可以用Scripting.Dictionary组件实现快速索引访问的机制

Dim fso,File1,File2,File3,objDict,arr
Set objDict = CreateObject("Scripting.Dictionary")
Set fso = CreateObject("Scripting.FileSystemObject")
Set File1 = fso.OpenTextFile(".\$DG.txt", 1)
Set File2 = fso.OpenTextFile(".\NEW_DG.txt", 1)
Set File3 = fso.CreateTextFile(".\结果.txt", 2)
Do While File1.AtEndOfStream <> True 
    arr = Split(File1.ReadLine,"	")
    objDict.Add arr(0), arr(1)
Loop
File1.Close
Do While File2.AtEndOfStream <> True
    t = File2.ReadLine
    If objDict.Exists(t) Then 
       File3.WriteLine t&"	"&objDict.Item(t)
    End If
Loop
File2.Close
File3.Close
Msgbox "完成"
复制代码