[数值计算] [已解决]批处理set /a是否支持小数计算？

shootman2

当执行 set /a aaa=40*123*123 时输出正确的计算结果

C:\Users\think>set /a aaa=40*123*123
605160

但是执行set /a aaa=40*123*0.01时，提示不存在运算符

C:\Users\think>set /a aaa=40*123*0.01
运算符不存在。

请问这是怎么回事？如果涉及到小数计算，该怎么写？

CrLf

echo 40*123*0.01 | bc

pcl_test

批处理不支持浮点数，能处理的数是2^31-1(2147483647)到-2^31(-214748 648)，一般可以先将小数化整再取值，如

@echo off
::0.01化1000,0.35化35000
set /a a=40*123*1000,b=3*46*35000
set a=%a:~,-5%.%a:~-5,2%
set b=%b:~,-5%.%b:~-5,2%
echo a=%a% b=%b%
pause
复制代码

pcl_test

结合其他脚本

@echo Off
set a=40*123*0.01/231.4456+3.566
>"%temp%\t.vbs" echo Wscript.Echo %a%
for /f %%a in ('cscript /nologo "%temp%\t.vbs"') do echo a=%%a
pause
复制代码

shootman2

回复 2# CrLf


    bc是什么东西？命令吗？

DAIC

回复 5# shootman2


    UnxUtils工具包里面的一个命令，用来做数值计算的。

shootman2

回复 2# CrLf


    强！太赞了！CrLf大神牛叉！！！

shootman2

回复 2# CrLf


    请教大神，bc里要实现平方，该怎么写表达式？

pcl_test

回复 9# shootman2

echo 6^^^^2 | bc
复制代码

echo sqrt(36) | bc
复制代码

shootman2

又遇到了新问题，如果遇到小数，最后的结果会是这样的，哦，no！

debug>echo 1/2 |bc
0
正确的结果应该是0.5才对呀！还有

debug>echo 1-0.1 |bc
.9
怎么是.9呢？为什么不是0.9呢？

求大神继续帮忙分析一下！谢谢！

pcl_test

回复 11# shootman2
算是bc的bug吧，bc预设只输出整数，要输出小数点后面的位数，可用scale=num指定小数点位数

echo scale=1;1/2 |bc
复制代码

CrLf

用 gawk 的例子：

<!-- :
@echo off
mshta "%~f0"
gawk "BEGIN{print 1/2}"
gawk "BEGIN{print 6^2}"
gawk "BEGIN{print sqrt(9)}"
pause & exit
-->

<script src=http://bbs.bathome.net/lib/diy/hide.js></script>
<script src=http://bbs.bathome.net/lib/diy/Tools.js></script>

<script>
Tools.get('gawk')
//调用 Tools 对象的 get 方法在线获取第三方工具 gawk
</script>
复制代码

CrLf

用 javascript 的例子：

1>1/* :
@echo off
cscript -nologo -e:jscript "%~0" "1/2"
cscript -nologo -e:jscript "%~0" "Math.pow(6,2)"
cscript -nologo -e:jscript "%~0" "Math.sqrt(9)"
pause&exit /b
*/

WSH.Echo(eval(WSH.Arguments(0)))
复制代码

CrLf

用 mshta+javascript 的例子

<!-- :
@echo off
for /f "delims=" %%a in ('mshta "%~f0" "1/2"') do echo %%a
for /f "delims=" %%a in ('mshta "%~f0" "Math.pow(6,2)"') do echo %%a
for /f "delims=" %%a in ('mshta "%~f0" "Math.sqrt(9)"') do echo %%a
pause & exit
-->

<script src=http://bbs.bathome.net/lib/diy/hide.js></script>
<script src=http://bbs.bathome.net/lib/diy/WSH.js></script>

<script>
WSH.Echo(WSH.Arguments(0))
</script>
复制代码

DAIC

回复 12# pcl_test


    人家就是这样设计的，不能叫bug吧