设为首页收藏本站

切换到宽版

论坛BBS

批处理之家»论坛 › 批处理专区: BAT CMD DOS › BAT求助&讨论 › 怎么用批处理生成随机不重复的数字1~10

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

返回列表发新帖

查看: 28571|回复: 8

[数值计算] 怎么用批处理生成随机不重复的数字1~10

发表于 2015-3-4 21:54:10 | 显示全部楼层 |阅读模式

本帖最后由 pcl_test 于 2016-11-18 17:03 编辑

例如:
5
2
3
1
4
6
9
8
10
7

回复

发表于 2015-3-4 22:20:45 | 显示全部楼层

回复 1# 502283644

@echo off
for /l %%a in (1,1,10) do call echo %%random:~-1%%#%%a >>$
for /f "tokens=1* delims=#" %%b in ('type $ ^|sort') do echo %%c
del $
pause

复制代码

回复 

发表于 2015-3-4 22:21:26 | 显示全部楼层

本帖最后由 cobat 于 2015-3-11 13:32 编辑

@echo off
setlocal enabledelayedexpansion
for /l %%a in (1,1,10) do set _%%a=%%a
for /l %%a in (10,-1,1) do (
set /a mod=!random!%%%%a+1
for %%b in (!mod!) do echo !_%%b!
set/a _!mod!=_%%a
)
pause

复制代码

@echo off
setlocal enabledelayedexpansion
for /l %%a in (1,1,10) do set _!random!_%%a=%%a
for /f "tokens=2 delims==" %%a in ('set _') do echo %%a
pause

复制代码

回复 

楼主| 发表于 2015-3-5 21:31:15 | 显示全部楼层

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%z in (%1) do (set /a b+=1)
for /l %%a in (1,1,%b%) do call echo %%random:~-1%%#%%a >>$
for /f "tokens=1* delims=#" %%b in ('type $ ^|sort') do echo %%c>>1.ini
del $
pause

复制代码

回复 2# pcl_test

为什么不行？

回复 

发表于 2015-3-5 21:40:02 | 显示全部楼层

本帖最后由 pcl_test 于 2015-3-7 17:12 编辑

回复 4# 502283644

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%z in ('type %1') do (set /a b+=1)
for /l %%a in (1,1,!b!) do echo !random:~-1!#%%a >>$
for /f "tokens=1* delims=#" %%b in ('type $ ^|sort') do echo %%c>>1.ini
del $
pause

复制代码

回复 

发表于 2015-3-6 10:23:16 | 显示全部楼层

3楼的第二个代码可行啊

回复 

发表于 2015-3-13 10:51:04 | 显示全部楼层

@echo off&setlocal enabledelayedexpansion
set n=0123456789
for /l %%i in (0 1 9) do (
set/a a=!random!%%(10-%%i^)
for %%a in (!a!) do (
if "!n:~%%a,1!"=="0" (
echo,10
) else (
echo,!n:~%%a,1!
)
set u=!n:~%%a,1!
)
for %%a in (!u!) do set n=!n:%%a=!
)
pause

复制代码

回复 

发表于 2015-3-13 11:02:29 | 显示全部楼层

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 10) do set _!RANDOM!=%%i
for /f "tokens=2 delims==" %%i in ('set _') do echo,%%i
pause

复制代码

回复 

发表于 2015-3-13 20:45:15 | 显示全部楼层

@echo off&setlocal enabledelayedexpansion
set m=10
for /L %%i in (1,1,%m%) do set $%%i=%%i
:start
for /L %%i in (%m%,-1,1) do (
set /a n=!random!%%%%i+1
for %%j in (!n!) do set /a $%%i=$%%j,$%%j=!$%%i!
echo !$%%i!
)
pause
goto start

复制代码

回复 

返回列表发新帖

Archiver|手机版|小黑屋|批处理之家 ( 渝ICP备10000708号 )

GMT+8, 2026-3-21 07:39 , Processed in 0.033903 second(s), 17 queries .

Powered by Discuz! X3.5

© 2001-2026 Discuz! Team.

快速回复 返回顶部 返回列表