SandraRusso

回复 14# 慕夜蓝化


    移动到厂家的文件为1-1.JPG,2-2.JPG,3-3.JPG,4-1.JPG,5-1.JPG，其他的.JPG照片都移动到型号里面

慕夜蓝化

@echo off&setlocal enabledelayedexpansion
for /d %%i in (g:\h\*) do (
    md "%%~fsi\厂家" "%%~fsi\型号" 2>nul
    pushd "%%~fsi"
    for %%a in (*.*) do (
        set "str=%%a"&set "n=!str:~,1!" 
        if !n! leq 5 (
            move "%%a" 厂家
        ) else (
            move "%%a" 型号
        )      
    )
    popd
)
pause
复制代码

这样应该可以了。

SandraRusso

回复 15# 慕夜蓝化


    对啊！而且有的照片不是1-1.JPG的样式，而是1.JPG或是没有命名直接是.JPG,所以还得麻烦您帮我把这个条件添加进去!再次感谢~

慕夜蓝化

回复 18# SandraRusso

你试下17楼的行不行，我这里测试是通过的。

SandraRusso

回复 19# 慕夜蓝化

刚刚试了一下您给的代码，发现20-1，20-2等首位数字大于5的照片也被移动到厂家中去了，不过只有6-1照片在型号中，这个有点奇怪！

慕夜蓝化

回复 20# SandraRusso

这不奇怪，那不是首位数字了，那是前两位数字，我知道该怎么办了，你等下。

慕夜蓝化

@echo off&setlocal enabledelayedexpansion
for /d %%i in (g:\h\*) do (
    md "%%~fsi\厂家" "%%~fsi\型号" 2>nul
    pushd "%%~fsi"
    for %%a in (*.*) do (
        for /f "delims=-" %%b in ("%%~nxa") do (
        if %%b leq 5 (
            move "%%a" 厂家
        ) else (
            move "%%a" 型号
        ))      
    )
    popd
)
pause
复制代码

你试下。

SandraRusso

回复 9# pcl_test


    您看要是图片有命名成1.JPG的也要移动到厂家中去，怎么修改代码呢？

pcl_test

回复 15# SandraRusso

@echo off
set "filesdir=G:\H\"
for /f %%i in ('dir /ad /b "%filesdir%"') do (
pushd "%filesdir%%%i"
md "厂家\" "型号\"
for /l %%a in (1,1,5) do (
move %%a-*.* "厂家\"
move %%a.* "厂家\"
)
move *.* "型号\"
popd
)
pause
复制代码

SandraRusso

回复 22# 慕夜蓝化


    哈哈！完美解决了~太感谢您了！我刚刚接触这个，是个菜鸟！还请您多多指教呀！不知道您可不可以帮我把您这段代码每句的含义备注解释下？另外希望能加下您的QQ，以后好好向您学习！

SandraRusso

回复 16# pcl_test

哈哈！真是高手呀！长见识了，另外还想问您下，如果要建立3个文件夹，然后把首位数字为1到5、6-10、11-之后的图片分别移动到3个文件夹内，您能在给做下指导吗？

pcl_test

回复 17# SandraRusso

@echo off
set "filesdir=G:\H\"
for /f %%i in ('dir /ad /b "%filesdir%"') do (
pushd "%filesdir%%%i"
md "1-5\" "6-10\" "其他\" 2>nul
for /l %%a in (1,1,5) do (
move %%a-*.* "1-5\"
move %%a.* "1-5\"
)
for /l %%a in (6,1,10) do (
move %%a-*.* "6-10\"
move %%a.* "6-10\"
)
move *.* "其他\"
popd
)
pause
复制代码

SandraRusso

回复 18# pcl_test


    厉害呀！以后有类似的我就知道怎么变换的运用了！ 这个2>nul语句的含义是啥意思啊？对了如果问题解决了，我应该怎么在主题上标注已解决呢？我刚找了半天没找到，还请您见谅！

pcl_test

回复 19# SandraRusso

2>nul表示如果有错误不提示

你点击你问题1楼的“编辑”，直接在标题最前面输入[已解决]，再点击“编辑帖子”即可

SandraRusso

回复 22# 慕夜蓝化


    真是高手呀！长见识了，另外还想问您下，如果要建立3个文件夹，然后把首位数字为1到5、6-10、11-之后的图片分别移动到3个文件夹内，您能在给做下指导吗？