pcl_test

回复 1# kuishilova

1、临时vbs的代码一样吧，除了ip不同外？
2、把临时vbs的代码发出来

pcl_test

回复 3# kuishilova
你没懂我问的意思，从你发的代码看，不知是不是你省略了一些字符，因为telnet_tmp.vbs的生成是有问题的，所以才问你要telnet_tmp.vbs的完整代码，至于1.vbs，自然是了解只是调用，所以我根本就没问它里面是什么内容

pcl_test

回复 6# kuishilova
那就是省略了一些字符啦，因为你的代码最后一个“echo WScript.Sleep 1000 ”有什么用呢？

pcl_test

回复 8# kuishilova

你就单独把这段写进批处理运行下，看看生成的vbs有没缺失代码

echo set sh=WScript.CreateObject("WScript.Shell") >telnet_tmp.vbs && echo WScript.Sleep 300 >>telnet_tmp.vbs && echo sh.SendKeys "open %%i" >>telnet_tmp.vbs && echo WScript.Sleep 1000 …… && echo sh.SendKeys "{ENTER}">>telnet_tmp.vbs && echo WScript.Sleep 1000 ……
复制代码

pcl_test

回复 10# kuishilova
呵呵，其实你的问题很好解决，我跟你说的那些，都跟解决问题有关的

pcl_test

回复 11# kuishilova
那么为什么没在telnet_tmp.vbs生成？是否多余呢？

pcl_test

回复 15# kuishilova
把1.vbs、2.vbs……以相应的ip重命名

@echo off
setlocal enabledelayedexpansion
color a
:wait
cls
echo 1、进行配置
echo 2、退出
set a=0
set/p a=请选择:
if %a%==1 goto :startconf
if %a%==2 exit
goto :wait
:startconf
echo 交换机配置结果:>>配置结果.txt
set count=0
for /f "delims=" %%i in (ip.txt) do (
set temp=0
echo 正在扫描 %%i
echo 请等待........
ping -n 1 -w 2 %%i|find "TTL" >nul&&set temp=1
if "!temp!" equ "1" (
echo 扫描%%i完成，正在执行配置工作...
>telnet_tmp.vbs echo set sh=WScript.CreateObject^("WScript.Shell"^)
>>telnet_tmp.vbs echo WScript.Sleep 300
>>telnet_tmp.vbs echo sh.SendKeys "open %%i"
>>telnet_tmp.vbs echo WScript.Sleep 1000
>>telnet_tmp.vbs echo sh.SendKeys "{ENTER}"
>>telnet_tmp.vbs echo WScript.Sleep 1000
start telnet
ping -n 2 127.1 >nul
cscript //nologo telnet_tmp.vbs
ping -n 2 127.1 >nul
cscript //nologo %%i.vbs
del telnet_tmp.vbs
set /a count+=1
echo %%i配置成功
echo %%i配置成功>>配置结果.txt
) else (
echo %%i无法ping通！
echo %%i配置失败>>配置结果.txt
)
)
echo ----------------结果说明---------------
echo 配置完毕!
echo 共配置可以联通的交换机：%count%台。
echo 配置的结果保存在当前目录的“配置结果.txt”中。
echo ---------------------------------------
echo 按任意键返回主菜单
pause>nul
goto :wait
复制代码

pcl_test

回复 17# kuishilova
重命名什么的很容易的，自己试着把重命名批处理写出来，不要总想着吃现成的